[gentoo-commits] gentoo-x86 commit in www-apps/eyeos: ChangeLog eyeos-2.4.ebuild eyeos-1.9.0.1.ebuild

[gentoo-commits] gentoo-x86 commit in www-apps/eyeos: ChangeLog eyeos-2.4.ebuild eyeos-1.9.0.1.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    11/04/12 15:15:40

  Modified:             ChangeLog
  Added:                eyeos-2.4.ebuild
  Removed:              eyeos-1.9.0.1.ebuild
  Log:
  Version bump for 2.x releases, closes bug #319233
  
  (Portage version: 2.2.0_alpha29/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  www-apps/eyeos/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/eyeos/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/eyeos/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/eyeos/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/eyeos/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	3 Jan 2011 13:14:12 -0000	1.7
+++ ChangeLog	12 Apr 2011 15:15:40 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/eyeos
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/eyeos/ChangeLog,v 1.7 2011/01/03 13:14:12 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/eyeos/ChangeLog,v 1.8 2011/04/12 15:15:40 voyageur Exp $
+
+*eyeos-2.4 (12 Apr 2011)
+
+  12 Apr 2011; Bernard Cafarelli <voyageur@gentoo.org> -eyeos-1.9.0.1.ebuild,
+  +eyeos-2.4.ebuild:
+  Version bump for 2.x releases, closes bug #319233
 
 *eyeos-1.9.0.2 (03 Jan 2011)
 



1.1                  www-apps/eyeos/eyeos-2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/eyeos/eyeos-2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/eyeos/eyeos-2.4.ebuild?rev=1.1&content-type=text/plain

Index: eyeos-2.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/eyeos/eyeos-2.4.ebuild,v 1.1 2011/04/12 15:15:40 voyageur Exp $

EAPI="4"
inherit depend.php webapp eutils

DESCRIPTION="AJAX web-based desktop environment"
HOMEPAGE="http://www.eyeos.org"
SRC_URI="mirror://sourceforge/eyeos/eyeos2/${P}.tar.gz"

LICENSE="AGPL-3"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
need_httpd_cgi
need_php_httpd

# http://wiki.eyeos.org/EyeOS_Requirements
RDEPEND="dev-lang/php[curl,crypt,gd,json,mysql,mysqli,pdo,sharedmem,sqlite]"

S=${WORKDIR}

src_install() {
	webapp_src_preinst

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	# Placeholder for first install
	touch "${ED}/${MY_HTDOCSDIR}"/settings.php
	webapp_configfile "${MY_HTDOCSDIR}"/settings.php
	webapp_serverowned "${MY_HTDOCSDIR}"/settings.php

	# Ugly, but eyeos needs write access in too many places
	webapp_serverowned -R "${MY_HTDOCSDIR}"/eyeos/system
	webapp_serverowned -R "${MY_HTDOCSDIR}"/eyeos/tmp
	webapp_serverowned -R "${MY_HTDOCSDIR}"/eyeos/users

	webapp_src_install
}

pkg_postinst() {
	elog "To finish your install/upgrade, point your browser to the eyeOS installer at:"
	elog "	http://${VHOST_HOSTNAME}/${VHOST_APPDIR}:/install/"
	webapp_pkg_postinst
}