[gentoo-commits] gentoo-x86 commit in net-irc/kvirc: ChangeLog kvirc-4.2_pre5704.ebuild

[gentoo-commits] gentoo-x86 commit in net-irc/kvirc: ChangeLog kvirc-4.2_pre5704.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    11/03/25 19:17:54

  Modified:             ChangeLog
  Added:                kvirc-4.2_pre5704.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha28_p7/cvs/Linux x86_64)

Revision  Changes    Path
1.128                net-irc/kvirc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/kvirc/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/kvirc/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/kvirc/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/kvirc/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	24 Mar 2011 22:30:28 -0000	1.127
+++ ChangeLog	25 Mar 2011 19:17:54 -0000	1.128
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/kvirc
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/kvirc/ChangeLog,v 1.127 2011/03/24 22:30:28 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/kvirc/ChangeLog,v 1.128 2011/03/25 19:17:54 arfrever Exp $
+
+*kvirc-4.2_pre5704 (25 Mar 2011)
+
+  25 Mar 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +kvirc-4.2_pre5704.ebuild:
+  Version bump.
 
   24 Mar 2011; Christoph Mende <angelos@gentoo.org> kvirc-4.2_pre5484.ebuild:
   Stable on amd64 wrt bug #360353



1.1                  net-irc/kvirc/kvirc-4.2_pre5704.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/kvirc/kvirc-4.2_pre5704.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/kvirc/kvirc-4.2_pre5704.ebuild?rev=1.1&content-type=text/plain

Index: kvirc-4.2_pre5704.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/kvirc/kvirc-4.2_pre5704.ebuild,v 1.1 2011/03/25 19:17:54 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="python? 2"

inherit cmake-utils multilib python

DESCRIPTION="Advanced IRC Client"
HOMEPAGE="http://www.kvirc.net/"
SRC_URI="mirror://gentoo/${P}.tar.xz"

LICENSE="kvirc"
SLOT="4"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86"
IUSE="audiofile dcc_video +dcc_voice debug doc gsm +ipc ipv6 kde +nls oss +perl +phonon profile +python +qt-dbus qt-webkit +ssl theora +transparency"

RDEPEND=">=dev-libs/crypto++-5.6.0-r1
	sys-libs/zlib
	x11-libs/libX11
	>=x11-libs/qt-core-4.6
	>=x11-libs/qt-gui-4.6
	>=x11-libs/qt-sql-4.6
	dcc_video? (
		media-libs/libv4l
		theora? ( media-libs/libogg media-libs/libtheora )
	)
	kde? ( >=kde-base/kdelibs-4 )
	oss? ( audiofile? ( media-libs/audiofile ) )
	perl? ( dev-lang/perl )
	phonon? ( || ( media-sound/phonon >=x11-libs/qt-phonon-4.6 ) )
	qt-dbus? ( >=x11-libs/qt-dbus-4.6 )
	qt-webkit? ( >=x11-libs/qt-webkit-4.6 )
	ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	>=dev-util/cmake-2.6.4
	dev-util/pkgconfig
	x11-proto/scrnsaverproto
	nls? ( sys-devel/gettext )
	doc? ( app-doc/doxygen )"
RDEPEND="${RDEPEND}
	gsm? ( media-sound/gsm )"

DOCS="ChangeLog doc/FAQ"

pkg_setup() {
	if use audiofile && ! use oss; then
		die "USE=\"audiofile\" requires USE=\"oss\""
	fi

	if use theora && ! use dcc_video; then
		die "USE=\"theora\" requires USE=\"dcc_video\""
	fi

	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	VERSIO_PRAESENS="${PV#*_pre}"
	einfo "Setting of revision number to ${VERSIO_PRAESENS}"
	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" r${VERSIO_PRAESENS}\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
}

src_configure() {
	local libdir="$(get_libdir)"
	local mycmakeargs=(
		-DLIB_SUFFIX=${libdir#lib}
		-DMANUAL_REVISION=${VERSIO_PRAESENS}
		-DWANT_COEXISTENCE=1
		-DWANT_CRYPT=1
		-DWANT_CRYPTOPP=1
		-DWANT_ENV_FLAGS=1
		-DWANT_VERBOSE=1
		$(cmake-utils_use_want audiofile AUDIOFILE)
		$(cmake-utils_use_want dcc_video DCC_VIDEO)
		$(cmake-utils_use_want dcc_voice DCC_VOICE)
		$(cmake-utils_use_want debug DEBUG)
		$(cmake-utils_use_want doc DOXYGEN)
		$(cmake-utils_use_want gsm GSM)
		$(cmake-utils_use_want ipc IPC)
		$(cmake-utils_use_want ipv6 IPV6)
		$(cmake-utils_use_want kde KDE4)
		$(cmake-utils_use_want nls GETTEXT)
		$(cmake-utils_use_want oss OSS)
		$(cmake-utils_use_want perl PERL)
		$(cmake-utils_use_want phonon PHONON)
		$(cmake-utils_use_want profile MEMORY_PROFILE)
		$(cmake-utils_use_want python PYTHON)
		$(cmake-utils_use_want qt-dbus QTDBUS)
		$(cmake-utils_use_want qt-webkit QTWEBKIT)
		$(cmake-utils_use_want ssl OPENSSL)
		$(cmake-utils_use_want theora OGG_THEORA)
		$(cmake-utils_use_want transparency TRANSPARENCY)
	)

	cmake-utils_src_configure
}