[gentoo-commits] gentoo-x86 commit in dev-util/meld: ChangeLog meld-1.5.1.ebuild meld-1.4.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/meld: ChangeLog meld-1.5.1.ebuild meld-1.4.0.ebuild

[Pacho Ramos (pacho)]

pacho       11/03/20 12:02:44

  Modified:             ChangeLog
  Added:                meld-1.5.1.ebuild
  Removed:              meld-1.4.0.ebuild
  Log:
  Version bump, remove old.
  
  (Portage version: 2.1.9.43/cvs/Linux x86_64)

Revision  Changes    Path
1.121                dev-util/meld/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/ChangeLog?rev=1.121&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/ChangeLog?rev=1.121&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/ChangeLog?r1=1.120&r2=1.121

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v
retrieving revision 1.120
retrieving revision 1.121
diff -u -r1.120 -r1.121
--- ChangeLog	12 Mar 2011 16:04:20 -0000	1.120
+++ ChangeLog	20 Mar 2011 12:02:44 -0000	1.121
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/meld
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.120 2011/03/12 16:04:20 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.121 2011/03/20 12:02:44 pacho Exp $
+
+*meld-1.5.1 (20 Mar 2011)
+
+  20 Mar 2011; Pacho Ramos <pacho@gentoo.org> -meld-1.4.0.ebuild,
+  +meld-1.5.1.ebuild:
+  Version bump, remove old.
 
   12 Mar 2011; Raúl Porcel <armin76@gentoo.org> meld-1.5.0.ebuild:
   alpha/arm/ia64/sparc stable wrt #353436



1.1                  dev-util/meld/meld-1.5.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/meld-1.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/meld-1.5.1.ebuild?rev=1.1&content-type=text/plain

Index: meld-1.5.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/meld-1.5.1.ebuild,v 1.1 2011/03/20 12:02:44 pacho Exp $

EAPI="3"
GCONF_DEBUG="no"
PYTHON_DEPEND="2:2.5"

inherit python gnome2 eutils multilib

DESCRIPTION="A graphical (GNOME 2) diff and merge tool"
HOMEPAGE="http://meld.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="doc gnome"

RDEPEND="
	>=gnome-base/libglade-2:2.0
	>=dev-python/pygtk-2.14:2
	>=dev-python/pygobject-2.8:2
	gnome? ( >=dev-python/gconf-python-2.22:2 )
"
DEPEND="${RDEPEND}
	dev-util/intltool
	app-text/scrollkeeper"

pkg_setup() {
	DOCS="AUTHORS NEWS help/ChangeLog"
	# Needed for optimizing python modules against proper interpreter
	python_set_active_version 2
}

src_prepare() {
	gnome2_src_prepare

	# fix the prefix so its not in */local/*
	sed -e "s:/usr/local:${EPREFIX}/usr:" \
		-e "s:\$(prefix)/lib:\$(prefix)/$(get_libdir):" \
		-i INSTALL || die "sed 1 failed"

	# don't install anything to /usr/share/doc/meld
	sed -e "s:\$(docdir)/meld:\$(docdir)/${PF}:" \
		-i INSTALL || die "sed 2 failed"

	# let the python eclass handle python objects
	sed -e '/$(PYTHON) .* .import compileall;/s/\t/&#/g' \
		-i Makefile || die "sed 3 failed"

	# don't run scrollkeeper (with the wrong path),
	# leave that to gnome2.eclass #145833
	sed -e '/scrollkeeper-update/s/\t/&#/' \
		-i help/*/Makefile || die "sed 4 failed"

	# fix test suite
	sed -e 's,\(for file in \["\)\(meld"\]\),\1bin/\2,' \
		-e 's,\(open("\)\(meldapp.py")\),\1meld/\2,' \
		-i tools/check_release || die "sed 5 failed"

	# replace all calls to python by specific major version
	sed -e "s/\(PYTHON ?= \).*/\1$(PYTHON -2)/" \
		-i INSTALL || die "sed 6 failed"
	python_convert_shebangs 2 "${S}"/tools/*

	strip-linguas -i "${S}/po"
	local mylinguas=""
	for x in ${LINGUAS}; do
		mylinguas="${mylinguas} ${x}.po"
	done

	if [ -n "${mylinguas}" ]; then
		sed -e "s/PO:=.*/PO:=${mylinguas}/" \
			-i po/Makefile || die "sed 5 failed"
	fi
}

src_configure() {
	:
}

src_install() {
	gnome2_src_install
	python_convert_shebangs 2 "${ED}"usr/bin/meld
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_mod_optimize /usr/$(get_libdir)/meld
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/meld
}