* [gentoo-commits] gentoo-x86 commit in sys-auth/polkit: ChangeLog polkit-0.101.ebuild
@ 2011-03-11 19:07 Samuli Suominen (ssuominen)
0 siblings, 0 replies; 2+ messages in thread
From: Samuli Suominen (ssuominen) @ 2011-03-11 19:07 UTC (permalink / raw
To: gentoo-commits
ssuominen 11/03/11 19:07:32
Modified: ChangeLog
Added: polkit-0.101.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha26/cvs/Linux x86_64)
Revision Changes Path
1.38 sys-auth/polkit/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?r1=1.37&r2=1.38
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog 7 Mar 2011 20:08:34 -0000 1.37
+++ ChangeLog 11 Mar 2011 19:07:32 -0000 1.38
@@ -1,6 +1,11 @@
# ChangeLog for sys-auth/polkit
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.37 2011/03/07 20:08:34 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.38 2011/03/11 19:07:32 ssuominen Exp $
+
+*polkit-0.101 (11 Mar 2011)
+
+ 11 Mar 2011; Samuli Suominen <ssuominen@gentoo.org> +polkit-0.101.ebuild:
+ Version bump.
07 Mar 2011; Jeroen Roovers <jer@gentoo.org> polkit-0.99-r1.ebuild:
Stable for HPPA (bug #354509).
1.1 sys-auth/polkit/polkit-0.101.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild?rev=1.1&content-type=text/plain
Index: polkit-0.101.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild,v 1.1 2011/03/11 19:07:32 ssuominen Exp $
EAPI=3
inherit pam
DESCRIPTION="Policy framework for controlling privileges for system-wide services"
HOMEPAGE="http://hal.freedesktop.org/docs/polkit/"
SRC_URI="http://hal.freedesktop.org/releases/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples gtk +introspection kde nls pam"
RDEPEND=">=dev-libs/glib-2.28
dev-libs/expat
introspection? ( >=dev-libs/gobject-introspection-0.6.2 )
pam? ( virtual/pam )"
DEPEND="${RDEPEND}
!!sys-auth/policykit
dev-libs/libxslt
app-text/docbook-xsl-stylesheets
dev-util/pkgconfig
>=dev-util/intltool-0.36
doc? ( >=dev-util/gtk-doc-1.13 )"
PDEPEND=">=sys-auth/consolekit-0.4[policykit]
gtk? ( || ( >=gnome-extra/polkit-gnome-0.96-r1 lxde-base/lxpolkit ) )
kde? ( || ( sys-auth/polkit-kde-agent sys-auth/polkit-kde ) )"
src_configure() {
local myauth="--with-authfw=shadow"
use pam && myauth="--with-authfw=pam --with-pam-module-dir=$(getpam_mod_dir)"
econf \
--localstatedir="${EPREFIX}"/var \
--disable-dependency-tracking \
--disable-static \
$(use_enable debug verbose-mode) \
--enable-man-pages \
$(use_enable doc gtk-doc) \
$(use_enable introspection) \
--disable-examples \
$(use_enable nls) \
--with-os-type=gentoo \
${myauth}
}
src_install() {
emake DESTDIR="${D}" install || die
dodoc docs/TODO HACKING NEWS README
find "${D}" -name '*.la' -exec rm -f {} +
# We disable example compilation above, and handle it here
if use examples; then
insinto /usr/share/doc/${PF}/examples
doins src/examples/{*.c,*.policy*}
fi
# Need to keep a few directories around...
diropts -m0700 -o root -g root
keepdir /var/run/polkit-1
keepdir /var/lib/polkit-1
}
pkg_postinst() {
# Make sure that the user has consolekit sessions working so that the
# 'allow_active' directive in polkit action policies works
if has_version 'gnome-base/gdm' && ! has_version 'gnome-base/gdm[consolekit]'; then
# If user has GDM installed, but USE=-consolekit, warn them
ewarn "You have GDM installed, but it does not have USE=consolekit"
ewarn "If you login using GDM, polkit authorizations will not work"
ewarn "unless you enable USE=consolekit"
einfo
fi
if has_version 'kde-base/kdm' && ! has_version 'kde-base/kdm[consolekit]'; then
# If user has KDM installed, but USE=-consolekit, warn them
ewarn "You have KDM installed, but it does not have USE=consolekit"
ewarn "If you login using KDM, polkit authorizations will not work"
ewarn "unless you enable USE=consolekit"
einfo
fi
if ! has_version 'gnome-base/gdm[consolekit]' && \
! has_version 'kde-base/kdm[consolekit]'; then
# Inform user about the alternative method
ewarn "If you don't use GDM or KDM for logging in,"
ewarn "you must start your desktop environment (DE) as follows:"
ewarn " ck-launch-session \$STARTGUI"
ewarn "Where \$STARTGUI is a DE-starting command such as 'gnome-session'."
ewarn "You should add this to your ~/.xinitrc if you use startx."
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sys-auth/polkit: ChangeLog polkit-0.101.ebuild
@ 2011-03-15 18:02 Nirbheek Chauhan (nirbheek)
0 siblings, 0 replies; 2+ messages in thread
From: Nirbheek Chauhan (nirbheek) @ 2011-03-15 18:02 UTC (permalink / raw
To: gentoo-commits
nirbheek 11/03/15 18:02:39
Modified: ChangeLog polkit-0.101.ebuild
Log:
PDEPEND on 0.101 version of polkit-gnome
(Portage version: 2.1.9.42/cvs/Linux x86_64)
Revision Changes Path
1.40 sys-auth/polkit/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?r1=1.39&r2=1.40
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog 13 Mar 2011 20:22:36 -0000 1.39
+++ ChangeLog 15 Mar 2011 18:02:39 -0000 1.40
@@ -1,6 +1,9 @@
# ChangeLog for sys-auth/polkit
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.39 2011/03/13 20:22:36 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.40 2011/03/15 18:02:39 nirbheek Exp $
+
+ 15 Mar 2011; Nirbheek Chauhan <nirbheek@gentoo.org> polkit-0.101.ebuild:
+ PDEPEND on 0.101 version of polkit-gnome
13 Mar 2011; Markus Meier <maekke@gentoo.org> polkit-0.99-r1.ebuild:
arm stable, bug #354509
1.2 sys-auth/polkit/polkit-0.101.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild?r1=1.1&r2=1.2
Index: polkit-0.101.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- polkit-0.101.ebuild 11 Mar 2011 19:07:32 -0000 1.1
+++ polkit-0.101.ebuild 15 Mar 2011 18:02:39 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild,v 1.1 2011/03/11 19:07:32 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/polkit-0.101.ebuild,v 1.2 2011/03/15 18:02:39 nirbheek Exp $
EAPI=3
inherit pam
@@ -26,7 +26,7 @@
>=dev-util/intltool-0.36
doc? ( >=dev-util/gtk-doc-1.13 )"
PDEPEND=">=sys-auth/consolekit-0.4[policykit]
- gtk? ( || ( >=gnome-extra/polkit-gnome-0.96-r1 lxde-base/lxpolkit ) )
+ gtk? ( || ( >=gnome-extra/polkit-gnome-0.101 lxde-base/lxpolkit ) )
kde? ( || ( sys-auth/polkit-kde-agent sys-auth/polkit-kde ) )"
src_configure() {
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2011-03-15 18:03 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-03-11 19:07 [gentoo-commits] gentoo-x86 commit in sys-auth/polkit: ChangeLog polkit-0.101.ebuild Samuli Suominen (ssuominen)
-- strict thread matches above, loose matches on Subject: below --
2011-03-15 18:02 Nirbheek Chauhan (nirbheek)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox