[gentoo-commits] gentoo-x86 commit in app-misc/geoclue: geoclue-0.12.0_p20110307.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in app-misc/geoclue: geoclue-0.12.0_p20110307.ebuild metadata.xml ChangeLog

[Kevin McCarthy (signals)]

signals     11/03/07 20:29:50

  Added:                geoclue-0.12.0_p20110307.ebuild metadata.xml
                        ChangeLog
  Log:
  New ebuild for Geoclue. Ebuild by signals@gentoo.org.
  
  (Portage version: 2.2.0_alpha26/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-misc/geoclue/geoclue-0.12.0_p20110307.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/geoclue/geoclue-0.12.0_p20110307.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/geoclue/geoclue-0.12.0_p20110307.ebuild?rev=1.1&content-type=text/plain

Index: geoclue-0.12.0_p20110307.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/geoclue/geoclue-0.12.0_p20110307.ebuild,v 1.1 2011/03/07 20:29:50 signals Exp $

EAPI=4
inherit autotools eutils

DESCRIPTION="A geoinformation D-Bus service"
HOMEPAGE="http://freedesktop.org/wiki/Software/GeoClue"
SRC_URI="http://dev.gentoo.org/~signals/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="geonames gpsd gsmloc gtk hostip manual networkmanager nominatim plazes
	skyhook yahoo-geo"

REQUIRED_USE="skyhook? ( networkmanager )"

RDEPEND="dev-libs/dbus-glib
	dev-libs/glib:2
	dev-libs/libxml2
	gnome-base/gconf
	skyhook? ( net-libs/libsoup )
	sys-apps/dbus
	gtk? ( x11-libs/gtk+:2 )
	gpsd? ( sci-geosciences/gpsd )
	networkmanager? ( net-misc/networkmanager )"
DEPEND="${RDEPEND}
	dev-util/gtk-doc
	dev-util/gtk-doc-am"

src_prepare() {
	epatch "${FILESDIR}"/${P}-use-flag.patch \
		"${FILESDIR}"/${P}-use-fallback-mac.patch
	gtkdocize || die
	eautoreconf
}

src_configure() {
	# Conic is only for Maemo. Don't enable.
	# Gypsy has multiple vulnerabilities:
	# https://bugs.freedesktop.org/show_bug.cgi?id=33431
	econf \
		--disable-conic \
		--disable-gypsy \
		$(use_enable geonames) \
		$(use_enable gpsd) \
		$(use_enable gsmloc) \
		$(use_enable gtk) \
		$(use_enable hostip) \
		$(use_enable manual) \
		$(use_enable networkmanager) \
		$(use_enable nominatim) \
		$(use_enable plazes) \
		$(use_enable skyhook) \
		$(use_enable yahoo-geo yahoo)
}

src_install() {
	emake DESTDIR="${D}" install
	use gtk && dobin test/.libs/geoclue-test-gui
}



1.1                  app-misc/geoclue/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/geoclue/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/geoclue/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>desktop-misc</herd>
  <maintainer>
    <email>signals@gentoo.org</email>
    <name>Kevin McCarthy</name>
  </maintainer>
  <use>
    <flag name="geonames">Install geonames.org provider</flag>
    <flag name="gpsd">Install sci-geosciences/gpsd provider</flag>
    <flag name="gsmloc">Install GSM location provider</flag>
    <flag name="gtk">Install gtk-based geoclue-test-gui</flag>
    <flag name="hostip">Install hostip.info provder</flag>
    <flag name="manual">Install manual provider</flag>
    <flag name="nominatim">Install openstreetmap.org provider</flag>
    <flag name="plazes">Install plazes.com provider</flag>
    <flag name="skyhook">Install skyhookwireless.com provider</flag>
    <flag name="yahoo-geo">Install Yahoo geolocation provider</flag>
  </use>
</pkgmetadata>




1.1                  app-misc/geoclue/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/geoclue/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/geoclue/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-misc/geoclue
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/geoclue/ChangeLog,v 1.1 2011/03/07 20:29:50 signals Exp $

*geoclue-0.12.0_p20110307 (07 Mar 2011)

  07 Mar 2011; Kevin McCarthy <signals@gentoo.org>
  +geoclue-0.12.0_p20110307.ebuild,
  +files/geoclue-0.12.0_p20110307-use-fallback-mac.patch,
  +files/geoclue-0.12.0_p20110307-use-flag.patch, +metadata.xml:
  New ebuild for Geoclue. Ebuild by signals@gentoo.org.