[gentoo-commits] gentoo-x86 commit in app-misc/task: task-1.9.4.ebuild ChangeLog

["Tim Harder (radhermit)" <radhermit@gentoo.org>]

radhermit    11/03/07 07:56:17

  Modified:             ChangeLog
  Added:                task-1.9.4.ebuild
  Log:
  Version bump. Use new cmake-based build system.
  
  (Portage version: 2.2.0_alpha26/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 app-misc/task/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	11 Feb 2011 10:27:32 -0000	1.11
+++ ChangeLog	7 Mar 2011 07:56:17 -0000	1.12
@@ -1,6 +1,13 @@
 # ChangeLog for app-misc/task
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.11 2011/02/11 10:27:32 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.12 2011/03/07 07:56:17 radhermit Exp $
+
+*task-1.9.4 (07 Mar 2011)
+
+  07 Mar 2011; Tim Harder <radhermit@gentoo.org> +task-1.9.4.ebuild,
+  +files/task-1.9.4-lua-automagic.patch, +files/task-1.9.4-rcdir.patch,
+  +files/task-1.9.4-remove-ncurses.patch:
+  Version bump. Use new cmake-based build system.
 
   11 Feb 2011; Tim Harder <radhermit@gentoo.org> -task-1.9.2-r1.ebuild:
   Remove old



1.1                  app-misc/task/task-1.9.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/task-1.9.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/task/task-1.9.4.ebuild?rev=1.1&content-type=text/plain

Index: task-1.9.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-1.9.4.ebuild,v 1.1 2011/03/07 07:56:16 radhermit Exp $

EAPI=3

inherit eutils cmake-utils

DESCRIPTION="A task management tool with a command-line interface"
HOMEPAGE="http://taskwarrior.org/projects/show/taskwarrior/"
SRC_URI="http://taskwarrior.org/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bash-completion lua vim-syntax zsh-completion"

DEPEND="lua? ( dev-lang/lua )"
RDEPEND="${DEPEND}"

src_prepare() {
	# Use the correct directory locations
	sed -i -e "s:/usr/local/share/doc/task/rc:/usr/share/task/rc:" src/Config.cpp \
		doc/man/taskrc.5.in doc/man/task-tutorial.5.in doc/man/task-color.5.in
	sed -i -e "s:/usr/local/bin:/usr/bin:" doc/man/task-faq.5.in scripts/add-ons/*

	# Don't automatically install scripts
	sed -i -e '/scripts/d' CMakeLists.txt

	epatch "${FILESDIR}"/${P}-rcdir.patch
	epatch "${FILESDIR}"/${P}-lua-automagic.patch
	epatch "${FILESDIR}"/${P}-remove-ncurses.patch
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_enable lua LUA)
		-DTASK_DOCDIR=/usr/share/doc/${PF}
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use bash-completion ; then
		insinto /usr/share/bash-completion
		doins scripts/bash/*
	fi

	if use vim-syntax ; then
		rm scripts/vim/README
		insinto /usr/share/vim/vimfiles
		doins -r scripts/vim/*
	fi

	if use zsh-completion ; then
		insinto /usr/share/zsh/site-functions
		doins scripts/zsh/*
	fi

	insinto /usr/share/doc/${PF}/scripts
	doins scripts/add-ons/*
}