[gentoo-commits] gentoo-x86 commit in app-text/djview4: ChangeLog djview4-4.6-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/djview4: ChangeLog djview4-4.6-r1.ebuild

[Peter Volkov (pva)]

pva         11/03/01 21:53:28

  Modified:             ChangeLog
  Added:                djview4-4.6-r1.ebuild
  Log:
  Upstream patch to fix occasional segfault when flipping pages very quickly.
  
  (Portage version: 2.1.9.41/cvs/Linux x86_64)

Revision  Changes    Path
1.32                 app-text/djview4/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview4/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview4/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview4/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/djview4/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	15 Oct 2010 14:08:07 -0000	1.31
+++ ChangeLog	1 Mar 2011 21:53:27 -0000	1.32
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/djview4
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/djview4/ChangeLog,v 1.31 2010/10/15 14:08:07 pva Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/djview4/ChangeLog,v 1.32 2011/03/01 21:53:27 pva Exp $
+
+*djview4-4.6-r1 (01 Mar 2011)
+
+  01 Mar 2011; Peter Volkov <pva@gentoo.org> +djview4-4.6-r1.ebuild,
+  +files/djview4-4.6-segfault.patch:
+  Upstream patch to fix occasional segfault when flipping pages very quickly.
 
 *djview4-4.6 (15 Oct 2010)
 



1.1                  app-text/djview4/djview4-4.6-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview4/djview4-4.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview4/djview4-4.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: djview4-4.6-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/djview4/djview4-4.6-r1.ebuild,v 1.1 2011/03/01 21:53:28 pva Exp $

EAPI="3"

inherit eutils autotools versionator toolchain-funcs multilib nsplugins fdo-mime flag-o-matic

MY_P=${PN}-$(replace_version_separator 2 '-')

DESCRIPTION="Portable DjVu viewer using Qt4"
HOMEPAGE="http://djvu.sourceforge.net/djview4.html"
SRC_URI="mirror://sourceforge/djvu/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
IUSE="debug nsplugin"

RDEPEND="
	>=app-text/djvu-3.5.22-r1
	x11-libs/qt-gui:4"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nsplugin? ( dev-libs/glib:2 )"

S=${WORKDIR}/${PN}-$(get_version_component_range 1-2)

src_prepare() {
	epatch "${FILESDIR}/djview4-4.6-segfault.patch"
	# Force XEmbed instead of Xt-based mainloop (disable Xt autodep)
	sed -e 's:\(ac_xt=\)yes:\1no:' -i configure* || die
	sed 's/AC_CXX_OPTIMIZE/OPTS=;AC_SUBST(OPTS)/' -i configure.ac || die #263688
	rm aclocal.m4 config/{libtool.m4,install-sh,ltmain.sh,lt*.m4}
	AT_M4DIR="config" eautoreconf
}

src_configure() {
	# See config/acinclude.m4
	use debug || append-cppflags "-DNDEBUG"

	# QTDIR is needed because of kde3
	QTDIR=/usr \
	econf \
		--with-x \
		$(use_enable nsplugin nsdejavu) \
		--disable-desktopfiles
}

src_compile() {
	emake CC=$(tc-getCC) CXX=$(tc-getCXX) || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" \
		plugindir=/usr/$(get_libdir)/${PLUGINS_DIR} \
			install || die "emake install failed"

	dodoc README TODO NEWS || die "dodoc failed"

	cd desktopfiles
	insinto /usr/share/icons/hicolor/32x32/apps
	newins hi32-djview4.png djvulibre-djview4.png
	insinto /usr/share/icons/hicolor/scalable/apps
	newins djview.svg djvulibre-djview4.svg
	domenu djvulibre-djview4.desktop
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}