[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-burn: ChangeLog vdr-burn-0.2.0_beta5-r1.ebuild vdr-burn-0.2.0_beta5.ebuild

[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-burn: ChangeLog vdr-burn-0.2.0_beta5-r1.ebuild vdr-burn-0.2.0_beta5.ebuild

[Joerg Bornkessel (hd_brummy)]

hd_brummy    11/02/13 13:16:00

  Modified:             ChangeLog
  Added:                vdr-burn-0.2.0_beta5-r1.ebuild
  Removed:              vdr-burn-0.2.0_beta5.ebuild
  Log:
  added missing ldflags.diff bug #339328
  
  (Portage version: 2.1.9.25/cvs/Linux i686)

Revision  Changes    Path
1.50                 media-plugins/vdr-burn/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-burn/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-burn/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-burn/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-burn/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	2 Feb 2011 19:59:18 -0000	1.49
+++ ChangeLog	13 Feb 2011 13:16:00 -0000	1.50
@@ -1,6 +1,13 @@
 # ChangeLog for media-plugins/vdr-burn
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-burn/ChangeLog,v 1.49 2011/02/02 19:59:18 hd_brummy Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-burn/ChangeLog,v 1.50 2011/02/13 13:16:00 hd_brummy Exp $
+
+*vdr-burn-0.2.0_beta5-r1 (13 Feb 2011)
+
+  13 Feb 2011; Joerg Bornkessel <hd_brummy@gentoo.org>
+  -vdr-burn-0.2.0_beta5.ebuild, +vdr-burn-0.2.0_beta5-r1.ebuild,
+  +files/vdr-burn-0.2.0_beta5_ldflags.diff:
+  added missing ldflags.diff bug #339328
 
 *vdr-burn-0.2.0_beta5 (02 Feb 2011)
 



1.1                  media-plugins/vdr-burn/vdr-burn-0.2.0_beta5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-burn/vdr-burn-0.2.0_beta5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-burn/vdr-burn-0.2.0_beta5-r1.ebuild?rev=1.1&content-type=text/plain

Index: vdr-burn-0.2.0_beta5-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-burn/vdr-burn-0.2.0_beta5-r1.ebuild,v 1.1 2011/02/13 13:16:00 hd_brummy Exp $

EAPI="3"

inherit vdr-plugin versionator

VERSION="437" # every bump, new version!

RESTRICT="test"

MY_P="${PN}-$(replace_version_separator 3 -)"

DESCRIPTION="VDR Plugin: burn records on DVD"
HOMEPAGE="http://projects.vdr-developer.org/projects/show/plg-burn"
SRC_URI="http://projects.vdr-developer.org/attachments/download/${VERSION}/${MY_P}.tgz"

KEYWORDS="~amd64 ~x86"
SLOT="0"
LICENSE="GPL-2"
IUSE="dvdarchive"

DEPEND=">=media-video/vdr-1.6
		media-libs/gd[png,truetype,jpeg]"
RDEPEND="${DEPEND}
		>=dev-libs/libcdio-0.71
		>=media-video/dvdauthor-0.6.10
		>=media-video/mjpegtools-1.6.2[png]
		media-video/transcode
		media-fonts/ttf-bitstream-vera
		virtual/eject
		>=app-cdr/dvd+rw-tools-5.21
		>=media-video/projectx-0.90.4.00_p32
		dvdarchive? ( media-video/vdrtools-genindex )"

# depends that are not rdepend
DEPEND="${DEPEND}
		>=dev-libs/boost-1.32.0"

S="${WORKDIR}/${MY_P#vdr-}"

src_prepare() {
	vdr-plugin_src_prepare

	epatch "${FILESDIR}/${P}_gentoo-path.diff"
	epatch "${FILESDIR}/${P}_setdefaults.diff"
	epatch "${FILESDIR}/${P}_makefile.diff"
	epatch "${FILESDIR}/${P}_ldflags.diff"

	use dvdarchive && sed -i Makefile \
		-e "s:#ENABLE_DMH_ARCHIVE:ENABLE_DMH_ARCHIVE:"

	sed -i Makefile \
		-e 's:^TMPDIR = .*$:TMPDIR = /tmp:' \
		-e 's:^ISODIR=.*$:ISODIR=/var/vdr/video/dvd-images:'

	fix_vdr_libsi_include scanner.c
}

src_install() {
	vdr-plugin_src_install

	dobin "${S}"/burn-buffers
	dobin "${S}"/*.sh

	insinto /usr/share/vdr/burn
	doins "${S}"/burn/menu-silence.mp2
	newins "${S}"/burn/menu-button.png menu-button-default.png
	newins "${S}"/burn/menu-bg.png menu-bg-default.png
	dosym menu-bg-default.png /usr/share/vdr/burn/menu-bg.png
	dosym menu-button-default.png /usr/share/vdr/burn/menu-button.png

	newins "${S}"/burn/ProjectX.ini projectx-vdr.ini

	fowners -R vdr:vdr /usr/share/vdr/burn

	(
		diropts -ovdr -gvdr
		keepdir /usr/share/vdr/burn/counters
	)
}

pkg_preinst() {
	if [[ -d ${ROOT}/etc/vdr/plugins/burn && ( ! -L ${ROOT}/etc/vdr/plugins/burn ) ]]; then
		einfo "Moving /etc/vdr/plugins/burn away"
		mv "${ROOT}"/etc/vdr/plugins/burn "${ROOT}"/etc/vdr/plugins/burn_old
	fi
}

pkg_postinst() {

	local DMH_FILE="${ROOT}/usr/share/vdr/burn/counters/standard"
	if [[ ! -e "${DMH_FILE}" ]]; then
		echo 0001 > "${DMH_FILE}"
		chown vdr:vdr "${DMH_FILE}"
	fi

	vdr-plugin_pkg_postinst

	einfo
	einfo "This ebuild comes only with the standard template"
	einfo "'emerge vdr-burn-templates' for more templates"
	einfo "To change the templates, use the vdr-image plugin"

	if [[ -e ${ROOT}/etc/vdr/reccmds/reccmds.burn.conf ]]; then
		eerror
		eerror "Please remove the following unneeded file:"
		eerror "\t/etc/vdr/reccmds/reccmds.burn.conf"
		eerror
	fi
}