* [gentoo-commits] gentoo-x86 commit in app-misc/tracker: ChangeLog tracker-9999.ebuild tracker-0.9.37.ebuild
@ 2011-02-08 22:53 Gilles Dartiguelongue (eva)
0 siblings, 0 replies; only message in thread
From: Gilles Dartiguelongue (eva) @ 2011-02-08 22:53 UTC (permalink / raw
To: gentoo-commits
eva 11/02/08 22:53:33
Modified: ChangeLog tracker-9999.ebuild
Added: tracker-0.9.37.ebuild
Log:
Version bump. bonobo dependency dropped, tracker-status merged into tracker-control.
(Portage version: 2.2.0_alpha21/cvs/Linux x86_64)
Revision Changes Path
1.95 app-misc/tracker/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?r1=1.94&r2=1.95
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog 2 Feb 2011 15:59:25 -0000 1.94
+++ ChangeLog 8 Feb 2011 22:53:33 -0000 1.95
@@ -1,6 +1,13 @@
# ChangeLog for app-misc/tracker
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.94 2011/02/02 15:59:25 halcy0n Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.95 2011/02/08 22:53:33 eva Exp $
+
+*tracker-0.9.37 (08 Feb 2011)
+
+ 08 Feb 2011; Gilles Dartiguelongue <eva@gentoo.org> +tracker-0.9.37.ebuild,
+ tracker-9999.ebuild:
+ Version bump. bonobo dependency dropped, tracker-status merged into
+ tracker-control.
02 Feb 2011; Mark Loeser <halcy0n@gentoo.org> tracker-0.8.17.ebuild:
Mark ~ppc64; bug #296794
1.34 app-misc/tracker/tracker-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?r1=1.33&r2=1.34
Index: tracker-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- tracker-9999.ebuild 23 Jan 2011 23:06:19 -0000 1.33
+++ tracker-9999.ebuild 8 Feb 2011 22:53:33 -0000 1.34
@@ -1,6 +1,6 @@
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.33 2011/01/23 23:06:19 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.34 2011/02/08 22:53:33 eva Exp $
EAPI="3"
GCONF_DEBUG="no"
@@ -33,7 +33,7 @@
sys-apps/util-linux
applet? (
- || ( gnome-base/gnome-panel[bonobo] <gnome-base/gnome-panel-2.32 )
+ >=gnome-base/gnome-panel-2.32
>=x11-libs/gtk+-2.18:2 )
eds? (
>=mail-client/evolution-2.29.1
1.1 app-misc/tracker/tracker-0.9.37.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.9.37.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.9.37.ebuild?rev=1.1&content-type=text/plain
Index: tracker-0.9.37.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.9.37.ebuild,v 1.1 2011/02/08 22:53:33 eva Exp $
EAPI="3"
GCONF_DEBUG="no"
PYTHON_DEPEND="2:2.6"
inherit eutils gnome2 linux-info python virtualx
DESCRIPTION="A tagging metadata database, search tool and indexer"
HOMEPAGE="http://www.tracker-project.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~x86"
# USE="doc" is managed by eclass.
IUSE="applet doc eds exif flac gif gnome-keyring gsf gstreamer gtk hal iptc +jpeg laptop mp3 nautilus networkmanager pdf playlist rss strigi test +tiff upnp +vorbis xine +xml xmp"
# Test suite highly disfunctional, loops forever
# putting aside for now
RESTRICT="test"
# TODO: rest -> flickr, qt vs. gdk
# vala is built with debug by default (see VALAFLAGS)
RDEPEND="
>=app-i18n/enca-1.9
>=dev-db/sqlite-3.7[threadsafe]
>=dev-libs/glib-2.26:2
|| (
>=media-gfx/imagemagick-5.2.1[png,jpeg=]
media-gfx/graphicsmagick[imagemagick,png,jpeg=] )
>=media-libs/libpng-1.2
>=x11-libs/pango-1
sys-apps/util-linux
applet? (
>=gnome-base/gnome-panel-2.32
>=x11-libs/gtk+-2.18:2 )
eds? (
>=mail-client/evolution-2.29.1
>=gnome-extra/evolution-data-server-2.29.1 )
exif? ( >=media-libs/libexif-0.6 )
flac? ( >=media-libs/flac-1.2.1 )
gif? ( media-libs/giflib )
gnome-keyring? ( >=gnome-base/gnome-keyring-2.26 )
gsf? (
app-text/odt2txt
>=gnome-extra/libgsf-1.13 )
upnp? ( >=media-libs/gupnp-dlna-0.5 )
!upnp? (
gstreamer? ( >=media-libs/gstreamer-0.10.12 )
!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
)
gtk? (
>=dev-libs/libgee-0.3
>=x11-libs/gtk+-2.18:2 )
iptc? ( media-libs/libiptcdata )
jpeg? ( virtual/jpeg:0 )
laptop? (
hal? ( >=sys-apps/hal-0.5 )
!hal? ( >=sys-power/upower-0.9 ) )
mp3? ( >=media-libs/taglib-1.6 )
nautilus? (
gnome-base/nautilus
>=x11-libs/gtk+-2.18:2 )
networkmanager? ( >=net-misc/networkmanager-0.8 )
pdf? (
>=x11-libs/cairo-1
>=app-text/poppler-0.12.3-r3[cairo,utils]
>=x11-libs/gtk+-2.12:2 )
playlist? ( dev-libs/totem-pl-parser )
rss? ( net-libs/libgrss )
strigi? ( >=app-misc/strigi-0.7 )
tiff? ( media-libs/tiff )
vorbis? ( >=media-libs/libvorbis-0.22 )
xine? ( >=media-libs/xine-lib-1 )
xml? ( >=dev-libs/libxml2-2.6 )
xmp? ( >=media-libs/exempi-2.1 )"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.40
>=sys-devel/gettext-0.17
>=dev-util/pkgconfig-0.20
applet? ( >=dev-lang/vala-0.11.4:0.12 )
gtk? (
app-office/dia
>=dev-lang/vala-0.11.4:0.12
>=dev-libs/libgee-0.3 )
doc? (
>=dev-util/gtk-doc-1.8
media-gfx/graphviz )
test? (
>=dev-libs/dbus-glib-0.82-r1
>=sys-apps/dbus-1.3.1[X] )
"
function inotify_enabled() {
if linux_config_exists; then
if ! linux_chkconfig_present INOTIFY_USER; then
ewarn "You should enable the INOTIFY support in your kernel."
ewarn "Check the 'Inotify support for userland' under the 'File systems'"
ewarn "option. It is marked as CONFIG_INOTIFY_USER in the config"
die 'missing CONFIG_INOTIFY'
fi
else
einfo "Could not check for INOTIFY support in your kernel."
fi
}
pkg_setup() {
linux-info_pkg_setup
inotify_enabled
if use upnp ; then
G2CONF="${G2CONF} --enable-video-extractor=gupnp-dlna"
elif use gstreamer ; then
G2CONF="${G2CONF}
--enable-video-extractor=gstreamer
--enable-gstreamer-tagreadbin"
# --enable-gstreamer-helix (real media)
elif use xine ; then
G2CONF="${G2CONF} --enable-video-extractor=xine"
else
G2CONF="${G2CONF} --enable-video-extractor=external"
fi
# hal and upower are used for AC power detection
if use laptop; then
G2CONF="${G2CONF} $(use_enable hal) $(use_enable !hal upower)"
else
G2CONF="${G2CONF} --disable-hal --disable-upower"
fi
if use applet || use gtk; then
G2CONF="${G2CONF} VALAC=$(type -P valac-0.12)"
fi
# unicode-support: libunistring, libicu or glib ?
G2CONF="${G2CONF}
--enable-tracker-fts
--with-enca
--with-unicode-support=glib
--enable-guarantee-metadata
$(use_enable applet tracker-status-icon)
$(use_enable applet tracker-search-bar)
$(use_enable eds miner-evolution)
$(use_enable exif libexif)
$(use_enable flac libflac)
$(use_enable gnome-keyring)
$(use_enable gsf libgsf)
$(use_enable gtk tracker-explorer)
$(use_enable gtk tracker-preferences)
$(use_enable gtk tracker-needle)
$(use_enable iptc libiptcdata)
$(use_enable jpeg libjpeg)
$(use_enable mp3 taglib)
$(use_enable nautilus nautilus-extension)
$(use_enable networkmanager network-manager)
$(use_enable pdf poppler)
$(use_enable playlist)
$(use_enable rss miner-rss)
$(use_enable strigi libstreamanalyzer)
$(use_enable test functional-tests)
$(use_enable test unit-tests)
$(use_enable tiff libtiff)
$(use_enable vorbis libvorbis)
$(use_enable xml libxml2)
$(use_enable xmp exempi)"
# FIXME: handle gdk vs qt for mp3 thumbnail extract
# $(use_enable gtk gdkpixbuf)
DOCS="AUTHORS ChangeLog NEWS README"
python_set_active_version 2
}
src_prepare() {
# Fix build failures with USE=strigi
epatch "${FILESDIR}/${PN}-0.8.0-strigi.patch"
# Fix functional tests scripts
find "${S}" -name "*.pyc" -delete
python_convert_shebangs 2 "${S}"/tests/tracker-writeback/*.py
python_convert_shebangs 2 "${S}"/tests/functional-tests/*.py
python_convert_shebangs 2 "${S}"/utils/data-generators/cc/{*.py,generate}
python_convert_shebangs 2 "${S}"/utils/gtk-sparql/*.py
python_convert_shebangs 2 "${S}"/examples/rss-reader/*.py
# FIXME: report broken tests
sed -e '/\/libtracker-miner\/tracker-password-provider\/setting/,+1 s:^\(.*\)$:/*\1*/:' \
-e '/\/libtracker-miner\/tracker-password-provider\/getting/,+1 s:^\(.*\)$:/*\1*/:' \
-i tests/libtracker-miner/tracker-password-provider-test.c || die
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
Xemake check XDG_DATA_HOME="${T}" XDG_CONFIG_HOME="${T}" || die "tests failed"
}
src_install() {
gnome2_src_install
# Tracker and none of the plugins it provides needs la files
find "${ED}" -name "*.la" -delete || die
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-02-08 22:53 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-02-08 22:53 [gentoo-commits] gentoo-x86 commit in app-misc/tracker: ChangeLog tracker-9999.ebuild tracker-0.9.37.ebuild Gilles Dartiguelongue (eva)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox