[gentoo-commits] gentoo-x86 commit in net-misc/modemmanager: modemmanager-0.4_p20110205.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-misc/modemmanager: modemmanager-0.4_p20110205.ebuild ChangeLog

[Robert Piasek (dagger)]

dagger      11/02/05 00:00:36

  Modified:             ChangeLog
  Added:                modemmanager-0.4_p20110205.ebuild
  Log:
  Add new snapshot for modemmanager
  
  (Portage version: 2.1.9.35/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 net-misc/modemmanager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/modemmanager/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/modemmanager/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/modemmanager/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/modemmanager/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	11 Dec 2010 21:22:51 -0000	1.17
+++ ChangeLog	5 Feb 2011 00:00:36 -0000	1.18
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/modemmanager
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/modemmanager/ChangeLog,v 1.17 2010/12/11 21:22:51 dagger Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/modemmanager/ChangeLog,v 1.18 2011/02/05 00:00:36 dagger Exp $
+
+*modemmanager-0.4_p20110205 (04 Feb 2011)
+
+  04 Feb 2011; Robert Piasek <dagger@gentoo.org>
+  +modemmanager-0.4_p20110205.ebuild:
+  Add new snapshot of ModemManager
 
 *modemmanager-0.4_p20101211 (11 Dec 2010)
 



1.1                  net-misc/modemmanager/modemmanager-0.4_p20110205.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/modemmanager/modemmanager-0.4_p20110205.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/modemmanager/modemmanager-0.4_p20110205.ebuild?rev=1.1&content-type=text/plain

Index: modemmanager-0.4_p20110205.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/modemmanager/modemmanager-0.4_p20110205.ebuild,v 1.1 2011/02/05 00:00:36 dagger Exp $

EAPI="2"

inherit gnome.org eutils

# ModemManager likes itself with capital letters
MY_PN="${PN/modemmanager/ModemManager}"

DESCRIPTION="Modem and mobile broadband management libraries"
HOMEPAGE="http://mail.gnome.org/archives/networkmanager-list/2008-July/msg00274.html"
#SRC_URI="${SRC_URI//${PN}/${MY_PN}}"
SRC_URI="http://dev.gentoo.org/~dagger/files/${MY_PN}-${PV}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE="doc policykit test"

RDEPEND=">=dev-libs/glib-2.18
	>=sys-fs/udev-145[extras]
	>=dev-libs/dbus-glib-0.86
	net-dialup/ppp
	policykit? ( >=sys-auth/polkit-0.95 )"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.35.0
	sys-devel/gettext
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_PN}-${PV}"

src_configure() {
	# ppp-2.4.5 will change the plugin directory (not added to portage yet)
	if has_version '=net-dialup/ppp-2.4.4*'; then
		pppd_plugin_dir="pppd/2.4.4"
	elif has_version '=net-dialup/ppp-2.4.5*'; then
		pppd_plugin_dir="pppd/2.4.5"
	fi

	econf \
		--disable-more-warnings \
		--with-udev-base-dir=/etc/udev/ \
		--disable-static \
		--with-dist-version=${PVR} \
		--with-pppd-plugin-dir="/usr/$(get_libdir)/${pppd_plugin_dir}" \
		$(use_with doc docs) \
		$(use_with policykit polkit) \
		$(use_with test tests)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README
	# Remove useless .la files
	rm -vf "${D}"/usr/$(get_libdir)/{${MY_PN},${pppd_plugin_dir}}/*.la
}

pkg_postinst() {
	elog "If your USB modem shows up as a Flash drive when you plug it in,"
	elog "You should install sys-apps/usb_modeswitch which will automatically"
	elog "switch it over to USB modem mode whenever you plug it in."
}