[gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-9999.ebuild chromium-10.0.642.2.ebuild

["PaweA Hajdan (phajdan.jr)" <phajdan.jr@gentoo.org>]

phajdan.jr    11/01/21 07:51:23

  Modified:             ChangeLog chromium-9999.ebuild
  Added:                chromium-10.0.642.2.ebuild
  Log:
  Version bump for dev channel release. Uses bundled flac (bug #352093). Always uses system V8. Fixed bug #352309 by fkhp <fkhp101@tom.com>.
  
  (Portage version: 2.1.9.25/cvs/Linux i686)

Revision  Changes    Path
1.265                www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.265&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.265&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.264&r2=1.265

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.264
retrieving revision 1.265
diff -u -r1.264 -r1.265
--- ChangeLog	19 Jan 2011 10:18:41 -0000	1.264
+++ ChangeLog	21 Jan 2011 07:51:23 -0000	1.265
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.264 2011/01/19 10:18:41 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.265 2011/01/21 07:51:23 phajdan.jr Exp $
+
+*chromium-10.0.642.2 (21 Jan 2011)
+
+  21 Jan 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  +chromium-10.0.642.2.ebuild, chromium-9999.ebuild:
+  Version bump for dev channel release. Uses bundled flac (bug #352093).
+  Always uses system V8. Fixed bug #352309 by fkhp <fkhp101@tom.com>.
 
 *chromium-9.0.597.67 (19 Jan 2011)
 



1.127                www-client/chromium/chromium-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.127&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.127&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.126&r2=1.127

Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.126
retrieving revision 1.127
diff -u -r1.126 -r1.127
--- chromium-9999.ebuild	16 Jan 2011 09:49:50 -0000	1.126
+++ chromium-9999.ebuild	21 Jan 2011 07:51:23 -0000	1.127
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.126 2011/01/16 09:49:50 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.127 2011/01/21 07:51:23 phajdan.jr Exp $
 
 EAPI="3"
 PYTHON_DEPEND="2:2.6"
@@ -17,13 +17,13 @@
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS=""
-IUSE="cups +gecko-mediaplayer gnome gnome-keyring system-sqlite system-v8"
+IUSE="cups +gecko-mediaplayer gnome gnome-keyring system-sqlite"
 
 RDEPEND="app-arch/bzip2
 	system-sqlite? (
 		>=dev-db/sqlite-3.6.23.1[fts3,icu,secure-delete,threadsafe]
 	)
-	system-v8? ( dev-lang/v8 )
+	dev-lang/v8
 	dev-libs/dbus-glib
 	>=dev-libs/icu-4.4.1
 	>=dev-libs/libevent-1.4.13
@@ -150,9 +150,6 @@
 	# Make sure we don't use bundled libvpx headers.
 	epatch "${FILESDIR}"/${PN}-system-vpx-r2.patch
 
-	# Make sure we don't use bundled xdg-utils.
-	epatch "${FILESDIR}"/${PN}-system-xdg-utils-r0.patch
-
 	# Remove most bundled libraries. Some are still needed.
 	find third_party -type f \! -iname '*.gyp*' \
 		\! -path 'third_party/WebKit/*' \
@@ -161,6 +158,7 @@
 		\! -path 'third_party/cld/*' \
 		\! -path 'third_party/expat/*' \
 		\! -path 'third_party/ffmpeg/*' \
+		\! -path 'third_party/flac/*' \
 		\! -path 'third_party/gpsd/*' \
 		\! -path 'third_party/harfbuzz/*' \
 		\! -path 'third_party/hunspell/*' \
@@ -182,6 +180,16 @@
 		\! -path 'third_party/zlib/contrib/minizip/*' \
 		-delete || die
 
+	# Remove bundled v8.
+	find v8 -type f \! -iname '*.gyp*' -delete || die
+
+	# The implementation files include v8 headers with full path,
+	# like #include "v8/include/v8.h". Make sure the system headers
+	# will be used.
+	# TODO: find a solution that can be upstreamed.
+	rmdir v8/include || die
+	ln -s /usr/include v8/include || die
+
 	if use system-sqlite; then
 		# Remove bundled sqlite, preserving the shim header.
 		find third_party/sqlite -type f \! -iname '*.gyp*' \
@@ -189,22 +197,6 @@
 			-delete || die
 	fi
 
-	if use system-v8; then
-		# Provide our own gyp file that links with the system v8.
-		# TODO: move this upstream.
-		cp "${FILESDIR}"/v8.gyp v8/tools/gyp || die
-
-		# Remove bundled v8.
-		find v8 -type f \! -iname '*.gyp*' -delete || die
-
-		# The implementation files include v8 headers with full path,
-		# like #include "v8/include/v8.h". Make sure the system headers
-		# will be used.
-		# TODO: find a solution that can be upstreamed.
-		rmdir v8/include || die
-		ln -s /usr/include v8/include || die
-	fi
-
 	# Make sure the build system will use the right python, bug #344367.
 	# Only convert directories that need it, to save time.
 	python_convert_shebangs -q -r 2 build tools
@@ -229,6 +221,7 @@
 		-Duse_system_libpng=1
 		-Duse_system_libxml=1
 		-Duse_system_speex=1
+		-Duse_system_v8=1
 		-Duse_system_vpx=1
 		-Duse_system_xdg_utils=1
 		-Duse_system_zlib=1"
@@ -264,12 +257,6 @@
 		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
 		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
 
-	if host-is-pax; then
-		# Prevent the build from failing (bug #301880). The performance
-		# difference is very small.
-		myconf+=" -Dv8_use_snapshot=0"
-	fi
-
 	if use gecko-mediaplayer; then
 		# Disable hardcoded blacklist for gecko-mediaplayer.
 		# When www-plugins/gecko-mediaplayer is compiled with USE=gnome, it causes



1.1                  www-client/chromium/chromium-10.0.642.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-10.0.642.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-10.0.642.2.ebuild?rev=1.1&content-type=text/plain

Index: chromium-10.0.642.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-10.0.642.2.ebuild,v 1.1 2011/01/21 07:51:23 phajdan.jr Exp $

EAPI="3"
PYTHON_DEPEND="2:2.6"
V8_DEPEND="3.0.7"

inherit eutils flag-o-matic multilib pax-utils portability python \
	toolchain-funcs versionator virtualx

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cups +gecko-mediaplayer gnome gnome-keyring system-sqlite"

RDEPEND="app-arch/bzip2
	system-sqlite? (
		>=dev-db/sqlite-3.7.2[fts3,icu,secure-delete,threadsafe]
	)
	>=dev-lang/v8-${V8_DEPEND}
	dev-libs/dbus-glib
	>=dev-libs/icu-4.4.1
	>=dev-libs/libevent-1.4.13
	dev-libs/libxml2
	dev-libs/libxslt
	>=dev-libs/nss-3.12.3
	gnome? ( >=gnome-base/gconf-2.24.0 )
	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
	>=media-libs/alsa-lib-1.0.19
	virtual/jpeg
	media-libs/libpng
	media-libs/libvpx
	media-libs/speex
	>=media-video/ffmpeg-0.6_p25767[threads]
	cups? ( >=net-print/cups-1.3.11 )
	sys-libs/zlib
	>=x11-libs/gtk+-2.14.7
	x11-libs/libXScrnSaver
	x11-libs/libXtst"
DEPEND="${RDEPEND}
	dev-lang/perl
	>=dev-util/chromium-tools-0.1.4
	>=dev-util/gperf-3.0.3
	>=dev-util/pkgconfig-0.23
	sys-devel/flex
	>=sys-devel/make-3.81-r2"
RDEPEND+="
	|| (
		x11-themes/gnome-icon-theme
		x11-themes/oxygen-molecule
		x11-themes/tango-icon-theme
		x11-themes/xfce4-icon-theme
	)
	x11-misc/xdg-utils
	virtual/ttf-fonts
	gecko-mediaplayer? ( !www-plugins/gecko-mediaplayer[gnome] )"

egyp() {
	set -- build/gyp_chromium --depth=. "${@}"
	echo "${@}" >&2
	"${@}"
}

pkg_setup() {
	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"

	# Make sure the build system will use the right tools, bug #340795.
	tc-export AR CC CXX RANLIB

	# Make sure the build system will use the right python, bug #344367.
	python_set_active_version 2
	python_pkg_setup

	# Prevent user problems like bug #299777.
	if ! grep -q /dev/shm <<< $(get_mounts); then
		ewarn "You don't have tmpfs mounted at /dev/shm."
		ewarn "${PN} may fail to start in that configuration."
		ewarn "Please uncomment the /dev/shm entry in /etc/fstab,"
		ewarn "and run 'mount /dev/shm'."
	fi
	if [ `stat -c %a /dev/shm` -ne 1777 ]; then
		ewarn "/dev/shm does not have correct permissions."
		ewarn "${PN} may fail to start in that configuration."
		ewarn "Please run 'chmod 1777 /dev/shm'."
	fi

	# Prevent user problems like bug #348235.
	eshopts_push -s extglob
	if is-flagq '-g?(gdb)?([1-9])'; then
		ewarn "You have enabled debug info (probably have -g or -ggdb in your \$C{,XX}FLAGS)."
		ewarn "You may experience really long compilation times and/or increased memory usage."
		ewarn "If compilation fails, please try removing -g{,gdb} before reporting a bug."
	fi
	eshopts_pop
}

src_prepare() {
	# Enable optional support for gecko-mediaplayer.
	epatch "${FILESDIR}"/${PN}-gecko-mediaplayer-r1.patch

	# Make sure we don't use bundled libvpx headers.
	epatch "${FILESDIR}"/${PN}-system-vpx-r2.patch

	# Make sure we don't use bundled xdg-utils.
	epatch "${FILESDIR}"/${PN}-system-xdg-utils-r0.patch

	# Remove most bundled libraries. Some are still needed.
	find third_party -type f \! -iname '*.gyp*' \
		\! -path 'third_party/WebKit/*' \
		\! -path 'third_party/angle/*' \
		\! -path 'third_party/cacheinvalidation/*' \
		\! -path 'third_party/cld/*' \
		\! -path 'third_party/expat/*' \
		\! -path 'third_party/ffmpeg/*' \
		\! -path 'third_party/flac/*' \
		\! -path 'third_party/gpsd/*' \
		\! -path 'third_party/harfbuzz/*' \
		\! -path 'third_party/hunspell/*' \
		\! -path 'third_party/iccjpeg/*' \
		\! -path 'third_party/libjingle/*' \
		\! -path 'third_party/libsrtp/*' \
		\! -path 'third_party/libwebp/*' \
		\! -path 'third_party/mesa/*' \
		\! -path 'third_party/modp_b64/*' \
		\! -path 'third_party/npapi/*' \
		\! -path 'third_party/openmax/*' \
		\! -path 'third_party/ots/*' \
		\! -path 'third_party/protobuf/*' \
		\! -path 'third_party/skia/*' \
		\! -path 'third_party/speex/speex.h' \
		\! -path 'third_party/sqlite/*' \
		\! -path 'third_party/tcmalloc/*' \
		\! -path 'third_party/undoview/*' \
		\! -path 'third_party/zlib/contrib/minizip/*' \
		-delete || die

	# Check for the maintainer to ensure that the dependencies
	# are up-to-date.
	local v8_bundled="$(v8-extract-version v8/src/version.cc)"
	if [ "${V8_DEPEND}" != "${v8_bundled}" ]; then
		die "update v8 dependency to ${v8_bundled}"
	fi

	# Remove bundled v8.
	find v8 -type f \! -iname '*.gyp*' -delete || die

	# The implementation files include v8 headers with full path,
	# like #include "v8/include/v8.h". Make sure the system headers
	# will be used.
	# TODO: find a solution that can be upstreamed.
	rmdir v8/include || die
	ln -s /usr/include v8/include || die

	if use system-sqlite; then
		# Remove bundled sqlite, preserving the shim header.
		find third_party/sqlite -type f \! -iname '*.gyp*' \
			\! -path 'third_party/sqlite/sqlite3.h' \
			-delete || die
	fi

	# Make sure the build system will use the right python, bug #344367.
	# Only convert directories that need it, to save time.
	python_convert_shebangs -q -r 2 build tools
}

src_configure() {
	local myconf=""

	# Never tell the build system to "enable" SSE2, it has a few unexpected
	# additions, bug #336871.
	myconf+=" -Ddisable_sse2=1"

	# Use system-provided libraries.
	# TODO: use_system_hunspell (upstream changes needed).
	# TODO: use_system_ssl (need to consult upstream).
	myconf+="
		-Duse_system_bzip2=1
		-Duse_system_ffmpeg=1
		-Duse_system_icu=1
		-Duse_system_libevent=1
		-Duse_system_libjpeg=1
		-Duse_system_libpng=1
		-Duse_system_libxml=1
		-Duse_system_speex=1
		-Duse_system_v8=1
		-Duse_system_vpx=1
		-Duse_system_xdg_utils=1
		-Duse_system_zlib=1"

	if use system-sqlite; then
		myconf+=" -Duse_system_sqlite=1"
	fi

	# The dependency on cups is optional, see bug #324105.
	if use cups; then
		myconf+=" -Duse_cups=1"
	else
		myconf+=" -Duse_cups=0"
	fi

	# Make GConf dependency optional, http://crbug.com/13322.
	if use gnome; then
		myconf+=" -Duse_gconf=1"
	else
		myconf+=" -Duse_gconf=0"
	fi

	if use "gnome-keyring"; then
		myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
	else
		# TODO: we should also disable code trying to dlopen
		# gnome-keyring in that case.
		myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
	fi

	# Enable sandbox.
	myconf+="
		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"

	if use gecko-mediaplayer; then
		# Disable hardcoded blacklist for gecko-mediaplayer.
		# When www-plugins/gecko-mediaplayer is compiled with USE=gnome, it causes
		# the browser to hang. We can handle the situation via dependencies,
		# thus making it possible to use gecko-mediaplayer.
		append-flags -DGENTOO_CHROMIUM_ENABLE_GECKO_MEDIAPLAYER
	fi

	# Our system ffmpeg should support more codecs than the bundled one
	# for Chromium.
	myconf+=" -Dproprietary_codecs=1"

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch = amd64 ]] ; then
		myconf+=" -Dtarget_arch=x64"
	elif [[ $myarch = x86 ]] ; then
		myconf+=" -Dtarget_arch=ia32"
	elif [[ $myarch = arm ]] ; then
		# TODO: check this again after
		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
		append-flags -fno-tree-sink

		myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi

	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
	# Depending on GCC version the warnings are different and we don't want
	# the build to fail because of that.
	myconf+=" -Dwerror="

	egyp ${myconf} || die
}

src_compile() {
	emake chrome chrome_sandbox BUILDTYPE=Release V=1 || die
	pax-mark m out/Release/chrome
	if use test; then
		emake base_unittests BUILDTYPE=Release V=1 || die
		pax-mark m out/Release/base_unittests
	fi
}

src_test() {
	# For more info see bug #350349.
	local mylocale='en_US.utf8'
	if ! locale -a | grep -q "$mylocale"; then
		eerror "${PN} requires ${mylocale} locale for tests"
		eerror "Please read the following guides for more information:"
		eerror "  http://www.gentoo.org/doc/en/guide-localization.xml"
		eerror "  http://www.gentoo.org/doc/en/utf-8.xml"
		die "locale ${mylocale} is not supported"
	fi

	# For more info see bug #350347.
	LC_ALL="${mylocale}" maketype=out/Release/base_unittests virtualmake \
		'--gtest_filter=-ICUStringConversionsTest.*' || die
}

src_install() {
	exeinto "${CHROMIUM_HOME}"
	doexe out/Release/chrome
	doexe out/Release/chrome_sandbox || die
	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
	doexe "${FILESDIR}"/chromium-launcher.sh || die

	insinto "${CHROMIUM_HOME}"
	doins out/Release/chrome.pak || die
	doins out/Release/resources.pak || die

	doins -r out/Release/locales || die
	doins -r out/Release/resources || die

	# chrome.1 is for chromium --help
	newman out/Release/chrome.1 chrome.1 || die
	newman out/Release/chrome.1 chromium.1 || die

	# Chromium looks for these in its folder
	# See media_posix.cc and base_paths_linux.cc
	dosym /usr/$(get_libdir)/libavcodec.so.52 "${CHROMIUM_HOME}" || die
	dosym /usr/$(get_libdir)/libavformat.so.52 "${CHROMIUM_HOME}" || die
	dosym /usr/$(get_libdir)/libavutil.so.50 "${CHROMIUM_HOME}" || die

	# Install icon and desktop entry.
	newicon chrome/app/theme/chromium/product_logo_48.png ${PN}-browser.png || die
	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
		"MimeType=text/html;text/xml;application/xhtml+xml;"
	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die

	# Install GNOME default application entry (bug #303100).
	if use gnome; then
		dodir /usr/share/gnome-control-center/default-apps || die
		insinto /usr/share/gnome-control-center/default-apps
		doins "${FILESDIR}"/chromium.xml || die
	fi
}