public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in sci-physics/root: ChangeLog root-5.26.00-r4.ebuild
@ 2010-06-25 17:12 Justin Lecher (jlec)
  0 siblings, 0 replies; 5+ messages in thread
From: Justin Lecher (jlec) @ 2010-06-25 17:12 UTC (permalink / raw
  To: gentoo-commits

jlec        10/06/25 17:12:36

  Modified:             ChangeLog
  Added:                root-5.26.00-r4.ebuild
  Log:
  Fixes for PYTHON ABIs
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.69                 sci-physics/root/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?r1=1.68&r2=1.69

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog	22 Jun 2010 16:07:52 -0000	1.68
+++ ChangeLog	25 Jun 2010 17:12:36 -0000	1.69
@@ -1,6 +1,11 @@
 # ChangeLog for sci-physics/root
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.68 2010/06/22 16:07:52 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.69 2010/06/25 17:12:36 jlec Exp $
+
+*root-5.26.00-r4 (25 Jun 2010)
+
+  25 Jun 2010; Justin Lecher <jlec@gentoo.org> +root-5.26.00-r4.ebuild:
+  Fixes for PYTHON ABIs
 
   22 Jun 2010; Sébastien Fabbro <bicatali@gentoo.org>
   root-5.26.00-r3.ebuild:



1.1                  sci-physics/root/root-5.26.00-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.1&content-type=text/plain

Index: root-5.26.00-r4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v 1.1 2010/06/25 17:12:36 jlec Exp $

EAPI=3

PYTHON_DEPEND="python? 2"

inherit versionator eutils qt4 elisp-common fdo-mime python toolchain-funcs

DOC_PV=$(get_major_version)_$(get_version_component_range 2)
ROOFIT_DOC_PV=2.91-33
TMVA_DOC_PV=4
PATCH_PV=p04

DESCRIPTION="C++ data analysis framework and interpreter from CERN"
HOMEPAGE="http://root.cern.ch/"
SRC_URI="
	ftp://root.cern.ch/${PN}/${PN}_v${PV}.source.tar.gz
	mirror://gentoo/${P}-patches-${PATCH_PV}.tar.bz2
	doc? (
		ftp://root.cern.ch/root/doc/Users_Guide_${DOC_PV}.pdf
		ftp://root.cern.ch/root/doc/RooFit_Users_Manual_${ROOFIT_DOC_PV}.pdf
		http://tmva.sourceforge.net/docu/TMVAUsersGuide.pdf -> TMVAUsersGuide-v${TMVA_DOC_PV}.pdf )"

SLOT="0"
LICENSE="LGPL-2.1"
KEYWORDS="~amd64 ~hppa ~sparc ~x86"
IUSE="afs clarens doc emacs examples fftw geant4 gsl kerberos ldap
	+math mysql	odbc +opengl openmp oracle postgres pythia6 pythia8 python
	+reflex	ruby qt4 ssl xft xml xinetd xrootd"

# libafterimage ignored, to check every version
# see https://savannah.cern.ch/bugs/?func=detailitem&item_id=30944
#	|| ( >=media-libs/libafterimage-1.18 x11-wm/afterstep )
CDEPEND=">=dev-lang/cfortran-4.4-r2
	dev-libs/libpcre
	>=media-libs/ftgl-2.1.3_rc5
	media-libs/libpng
	media-libs/jpeg
	media-libs/giflib
	media-libs/glew
	media-libs/tiff
	sys-apps/shadow
	x11-libs/libXpm
	x11-libs/libXft
	afs? ( >=net-fs/openafs-1.4.7 )
	clarens? ( dev-libs/xmlrpc-c )
	emacs? ( virtual/emacs )
	fftw? ( sci-libs/fftw:3.0 )
	geant4? ( sci-physics/geant:4 )
	gsl? ( >=sci-libs/gsl-1.8 )
	kerberos? ( virtual/krb5 )
	ldap? ( net-nds/openldap )
	mysql? ( virtual/mysql )
	odbc? ( || ( dev-db/libiodbc dev-db/unixODBC ) )
	opengl? ( virtual/opengl virtual/glu )
	oracle? ( dev-db/oracle-instantclient-basic )
	postgres? ( dev-db/postgresql-base )
	pythia6? ( sci-physics/pythia:6 )
	pythia8? ( sci-physics/pythia:8 )
	qt4? ( x11-libs/qt-gui:4
		x11-libs/qt-opengl:4
		x11-libs/qt-qt3support:4
		x11-libs/qt-xmlpatterns:4 )
	ruby? ( dev-lang/ruby
			dev-ruby/rubygems )
	ssl? ( dev-libs/openssl )
	xml? ( dev-libs/libxml2 )"

DEPEND="${CDEPEND}
	dev-util/pkgconfig"

RDEPEND="${CDEPEND}
	xinetd? ( sys-apps/xinetd )"

S="${WORKDIR}/${PN}"

pkg_setup() {
	elog
	elog "You may want to build ROOT with these non Gentoo extra packages:"
	elog "AliEn, castor, Chirp, dCache, gfal, gLite, Globus,"
	elog "Monalisa, MaxDB/SapDB, SRP."
	elog "You can use the env variable EXTRA_ECONF variable for this."
	elog "For example, for SRP, you would set: "
	elog "EXTRA_ECONF=\"--enable-srp --with-srp-libdir=/usr/$(get_libdir)\""
	elog
	enewgroup rootd
	enewuser rootd -1 -1 /var/spool/rootd rootd

	if use openmp && \
		[[ $(tc-getCC)$ == *gcc* ]] && \
		( [[ $(gcc-major-version)$(gcc-minor-version) -lt 42 ]] || \
			! has_version sys-devel/gcc[openmp] ); then
		ewarn "You are using gcc and OpenMP is available with gcc >= 4.2"
		ewarn "If you want to build this package with OpenMP, abort now,"
		ewarn "and set CC to an OpenMP capable compiler"
		epause 5
	elif use openmp; then
		export USE_OPENMP=1
		use math && export USE_PARALLEL_MINUIT2=1
	fi
	python_set_active_version 2
}

src_prepare() {
	epatch "${WORKDIR}"/${P}-svn33855.patch
	epatch "${WORKDIR}"/${P}-prop-ldflags.patch
	epatch "${WORKDIR}"/${P}-xrootd-prop-flags.patch
	epatch "${WORKDIR}"/${P}-configure-paths.patch
	epatch "${FILESDIR}"/${P}-nobyte-compile.patch

	# use system cfortran
	rm montecarlo/eg/inc/cfortran.h README/cfortran.doc

	# take a more descriptive name for ruby libs
	sed -i \
		-e 's/libRuby/libRubyROOT/g' \
		bindings/ruby/Module.mk bindings/ruby/src/drr.cxx \
		|| die "ajusting ruby libname failed"

	# in gentoo, libPythia6 is called libpythia6
	# libungif is called libgif, and libftgl_pic is libftgl
	sed -i \
		-e 's/libPythia6/libpythia6/g' \
		-e 's/ungif/gif/g' \
		configure || die "adjusting library names failed"

	# libafterimage flags are hardcoded
	sed -i \
		-e 's/CFLAGS="-O3"//' \
		-e 's/CFLAGS=$$ACFLAGS//' \
		graf2d/asimage/Module.mk graf2d/asimage/src/libAfterImage/configure \
		|| die "flag propagation in libafterimage failed"
	# QTDIR only used for qt3 in gentoo, and configure looks for it.
	unset QTDIR
}

src_configure() {
	# the configure script is not the standard autotools
	./configure \
		--with-cc=$(tc-getCC) \
		--with-cxx=$(tc-getCXX) \
		--with-f77=$(tc-getFC) \
		--fail-on-missing \
		--prefix="${EPREFIX}"/usr \
		--libdir="${EPREFIX}"/usr/$(get_libdir)/${PN} \
		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
		--tutdir="${EPREFIX}"/usr/share/doc/${PF}/examples/tutorials \
		--testdir="${EPREFIX}"/usr/share/doc/${PF}/examples/tests \
		--with-sys-iconpath="${EPREFIX}"/usr/share/pixmaps \
		--disable-builtin-freetype \
		--disable-builtin-ftgl \
		--disable-builtin-glew \
		--disable-builtin-pcre \
		--disable-builtin-zlib \
		--disable-rpath \
		--enable-asimage \
		--enable-astiff \
		--enable-exceptions	\
		--enable-explicitlink \
		--enable-gdml \
		--enable-memstat \
		--enable-shadowpw \
		--enable-shared	\
		--enable-soversion \
		--enable-table \
		--with-afs-shared=yes \
		$(use_enable afs) \
		$(use_enable clarens) \
		$(use_enable clarens peac) \
		$(use_enable fftw fftw3) \
		$(use_enable geant4 g4root) \
		$(use_enable kerberos krb5) \
		$(use_enable ldap) \
		$(use_enable gsl gsl-shared) \
		$(use_enable math genvector) \
		$(use_enable math mathmore) \
		$(use_enable math minuit2) \
		$(use_enable math roofit) \
		$(use_enable math unuran) \
		$(use_enable mysql) \
		$(use_enable odbc) \
		$(use_enable opengl) \
		$(use_enable postgres pgsql) \
		$(use_enable pythia6) \
		$(use_enable pythia8) \
		$(use_enable python) \
		$(use_enable qt4 qt) \
		$(use_enable qt4 qtgsi) \
		$(use_enable reflex cintex) \
		$(use_enable reflex) \
		$(use_enable ruby) \
		$(use_enable ssl) \
		$(use_enable xft) \
		$(use_enable xml) \
		$(use_enable xrootd) \
		${EXTRA_ECONF} \
		|| die "configure failed"
}

src_compile() {
	emake OPT="${CFLAGS}" F77OPT="${FFLAGS}" || die "emake failed"
	if use emacs; then
		elisp-compile build/misc/*.el || die "elisp-compile failed"
	fi
}

doc_install() {
	cd "${S}"
	if use doc; then
		einfo "Installing user's guides"
		insinto /usr/share/doc/${PF}
		doins \
			"${DISTDIR}"/Users_Guide_${DOC_PV}.pdf \
			"${DISTDIR}"/TMVAUsersGuide-v${TMVA_DOC_PV}.pdf \
			|| die "pdf install failed"
		if use math; then
			doins "${DISTDIR}"/RooFit_Users_Manual_${ROOFIT_DOC_PV}.pdf \
				|| die "math doc install failed"
		fi
	fi

	if use examples; then
		# these should really be taken care of by the root make install
		insinto /usr/share/doc/${PF}/examples/tutorials/tmva
		doins -r tmva/test || die
	else
		rm -rf "${D}"/usr/share/doc/${PF}/examples
	fi
}

daemon_install() {
	cd "${S}"
	local daemons="rootd proofd"
	dodir /var/spool/rootd
	fowners rootd:rootd /var/spool/rootd
	dodir /var/spool/rootd/{pub,tmp}
	fperms 1777 /var/spool/rootd/{pub,tmp}

	use xrootd && daemons="${daemons} xrootd olbd"
	for i in ${daemons}; do
		newinitd "${FILESDIR}"/${i}.initd ${i}
		newconfd "${FILESDIR}"/${i}.confd ${i}
	done
	if use xinetd; then
		insinto /etc/xinetd
		doins etc/daemons/{rootd,proofd}.xinetd || die
	fi
}

desktop_install() {
	cd "${S}"
	sed -e 's,@prefix@,/usr,' \
		build/package/debian/root-system-bin.desktop.in > root.desktop
	domenu root.desktop
	doicon "${S}"/build/package/debian/root-system-bin.png

	insinto /usr/share/icons/hicolor/48x48/mimetypes
	doins build/package/debian/application-x-root.png

	insinto /usr/share/icons/hicolor/48x48/apps
	doicon build/package/debian/root-system-bin.xpm
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	echo "LDPATH=${EPREFIX}/usr/$(get_libdir)/root" > 99root
	use pythia8 && echo "PYTHIA8=${EPREFIX}/usr" >> 99root
	use python && echo "PYTHONPATH=${EPREFIX}/usr/$(get_libdir)/root" >> 99root
	use ruby && echo "RUBYLIB=${EPREFIX}/usr/$(get_libdir)/root" >> 99root
	doenvd 99root || die "doenvd failed"

	# The build system installs Emacs support unconditionally and in the wrong
	# directory. Remove it and call elisp-install in case of USE=emacs.
	rm -rf "${D}"/usr/share/emacs
	if use emacs; then
		elisp-install ${PN} build/misc/*.{el,elc} || die "elisp-install failed"
	fi

	doc_install
	daemon_install
	desktop_install

	# Cleanup of files either already distributed or unused on Gentoo
	rm "${ED}"usr/share/doc/${PF}/{INSTALL,LICENSE,COPYING.CINT}
	rm "${ED}"usr/share/root/fonts/LICENSE
	pushd "${ED}"usr/$(get_libdir)/root/cint/cint/lib > /dev/null
	rm -f posix/mktypes dll_stl/setup \
		G__* dll_stl/G__* dll_stl/rootcint_* posix/exten.o
	rm -f "${ED}"usr/$(get_libdir)/root/cint/cint/include/makehpib
	rm -f "${ED}"/etc/root/proof/*.sample
	rm -rf "${ED}"/etc/root/daemons
	popd > /dev/null
}

pkg_postinst() {
	use ruby && elog "ROOT Ruby module is available as libRubyROOT"
	fdo-mime_desktop_database_update
	use python && python_mod_optimize "${EPREFIX}"/usr/$(get_libdir)/root
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	use python && python_mod_optimize "${EPREFIX}"/usr/$(get_libdir)/root
}






^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sci-physics/root: ChangeLog root-5.26.00-r4.ebuild
@ 2010-06-25 22:13 Arfrever Frehtes Taifersar Arahesis (arfrever)
  0 siblings, 0 replies; 5+ messages in thread
From: Arfrever Frehtes Taifersar Arahesis (arfrever) @ 2010-06-25 22:13 UTC (permalink / raw
  To: gentoo-commits

arfrever    10/06/25 22:13:38

  Modified:             ChangeLog root-5.26.00-r4.ebuild
  Log:
  Fix usage of python_set_active_version() and python_mod_optimize(), use python_mod_cleanup() instead of python_mod_optimize() in pkg_postrm() (bug #316247).
  (Portage version: HEAD/cvs/Linux x86_64)

Revision  Changes    Path
1.71                 sci-physics/root/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	25 Jun 2010 20:38:40 -0000	1.70
+++ ChangeLog	25 Jun 2010 22:13:38 -0000	1.71
@@ -1,6 +1,12 @@
 # ChangeLog for sci-physics/root
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.70 2010/06/25 20:38:40 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.71 2010/06/25 22:13:38 arfrever Exp $
+
+  25 Jun 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  root-5.26.00-r4.ebuild:
+  Fix usage of python_set_active_version() and python_mod_optimize(), use
+  python_mod_cleanup() instead of python_mod_optimize() in pkg_postrm() (bug
+  #316247).
 
   25 Jun 2010; Sébastien Fabbro <bicatali@gentoo.org>
   -root-5.22.00-r3.ebuild, -root-5.24.00-r1.ebuild, -root-5.26.00-r3.ebuild,



1.3                  sci-physics/root/root-5.26.00-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?r1=1.2&r2=1.3

Index: root-5.26.00-r4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- root-5.26.00-r4.ebuild	25 Jun 2010 20:38:40 -0000	1.2
+++ root-5.26.00-r4.ebuild	25 Jun 2010 22:13:38 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v 1.2 2010/06/25 20:38:40 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v 1.3 2010/06/25 22:13:38 arfrever Exp $
 
 EAPI=3
 
@@ -100,7 +100,7 @@
 		export USE_OPENMP=1
 		use math && export USE_PARALLEL_MINUIT2=1
 	fi
-	python_set_active_version 2
+	use python && python_set_active_version 2
 }
 
 src_prepare() {
@@ -298,10 +298,10 @@
 pkg_postinst() {
 	use ruby && elog "ROOT Ruby module is available as libRubyROOT"
 	fdo-mime_desktop_database_update
-	use python && python_mod_optimize "${EPREFIX}"/usr/$(get_libdir)/root
+	use python && python_mod_optimize /usr/$(get_libdir)/root
 }
 
 pkg_postrm() {
 	fdo-mime_desktop_database_update
-	use python && python_mod_optimize "${EPREFIX}"/usr/$(get_libdir)/root
+	use python && python_mod_cleanup /usr/$(get_libdir)/root
 }






^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sci-physics/root: ChangeLog root-5.26.00-r4.ebuild
@ 2010-07-06 15:59 Sebastien Fabbro (bicatali)
  0 siblings, 0 replies; 5+ messages in thread
From: Sebastien Fabbro (bicatali) @ 2010-07-06 15:59 UTC (permalink / raw
  To: gentoo-commits

bicatali    10/07/06 15:59:37

  Modified:             ChangeLog root-5.26.00-r4.ebuild
  Log:
  Added graphviz use flag
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.72                 sci-physics/root/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	25 Jun 2010 22:13:38 -0000	1.71
+++ ChangeLog	6 Jul 2010 15:59:37 -0000	1.72
@@ -1,6 +1,10 @@
 # ChangeLog for sci-physics/root
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.71 2010/06/25 22:13:38 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.72 2010/07/06 15:59:37 bicatali Exp $
+
+  06 Jul 2010; Sébastien Fabbro <bicatali@gentoo.org>
+  root-5.26.00-r4.ebuild:
+  Added graphviz use flag
 
   25 Jun 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   root-5.26.00-r4.ebuild:
@@ -21,7 +25,7 @@
   22 Jun 2010; Sébastien Fabbro <bicatali@gentoo.org>
   root-5.26.00-r3.ebuild:
   Removed cint7 flag, discontinued effort, and does not compile (bug
-  #324957])
+  #324957)
 
   17 Jun 2010; Patrick Lauer <patrick@gentoo.org> root-5.22.00-r2.ebuild,
   root-5.22.00-r3.ebuild, root-5.24.00-r1.ebuild, root-5.26.00-r2.ebuild,



1.4                  sci-physics/root/root-5.26.00-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?r1=1.3&r2=1.4

Index: root-5.26.00-r4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- root-5.26.00-r4.ebuild	25 Jun 2010 22:13:38 -0000	1.3
+++ root-5.26.00-r4.ebuild	6 Jul 2010 15:59:37 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v 1.3 2010/06/25 22:13:38 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v 1.4 2010/07/06 15:59:37 bicatali Exp $
 
 EAPI=3
 
@@ -26,7 +26,7 @@
 SLOT="0"
 LICENSE="LGPL-2.1"
 KEYWORDS="~amd64 ~hppa ~sparc ~x86"
-IUSE="afs clarens doc emacs examples fftw geant4 kerberos ldap
+IUSE="afs clarens doc emacs examples fftw geant4 graphviz kerberos ldap
 	+math mysql	odbc +opengl openmp oracle postgres pythia6 pythia8 python
 	+reflex	ruby qt4 ssl xft xml xinetd xrootd"
 
@@ -49,6 +49,7 @@
 	emacs? ( virtual/emacs )
 	fftw? ( sci-libs/fftw:3.0 )
 	geant4? ( sci-physics/geant:4 )
+	graphviz? ( media-gfx/graphviz )
 	kerberos? ( virtual/krb5 )
 	ldap? ( net-nds/openldap )
 	math? ( >=sci-libs/gsl-1.8 )
@@ -171,6 +172,7 @@
 		$(use_enable clarens peac) \
 		$(use_enable fftw fftw3) \
 		$(use_enable geant4 g4root) \
+		$(use_enable graphviz gviz) \
 		$(use_enable kerberos krb5) \
 		$(use_enable ldap) \
 		$(use_enable math gsl-shared) \






^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sci-physics/root: ChangeLog root-5.26.00-r4.ebuild
@ 2010-10-16 17:37 Kacper Kowalik (xarthisius)
  0 siblings, 0 replies; 5+ messages in thread
From: Kacper Kowalik (xarthisius) @ 2010-10-16 17:37 UTC (permalink / raw
  To: gentoo-commits

xarthisius    10/10/16 17:37:25

  Modified:             ChangeLog root-5.26.00-r4.ebuild
  Log:
  Fix building with gmake-3.82 wrt 333083. Thanks to Diego for reporting.
  
  (Portage version: 2.2_rc94/cvs/Linux x86_64)

Revision  Changes    Path
1.74                 sci-physics/root/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	10 Jul 2010 19:05:23 -0000	1.73
+++ ChangeLog	16 Oct 2010 17:37:24 -0000	1.74
@@ -1,6 +1,10 @@
 # ChangeLog for sci-physics/root
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.73 2010/07/10 19:05:23 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.74 2010/10/16 17:37:24 xarthisius Exp $
+
+  16 Oct 2010; Kacper Kowalik <xarthisius@gentoo.org>
+  root-5.26.00-r4.ebuild, +files/root-5.26.00-make-3.82.patch:
+  Fix building with gmake-3.82 wrt 333083. Thanks to Diego for reporting.
 
   10 Jul 2010; Raúl Porcel <armin76@gentoo.org> root-5.26.00-r2.ebuild:
   sparc stable wrt #318469



1.5                  sci-physics/root/root-5.26.00-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild?r1=1.4&r2=1.5

Index: root-5.26.00-r4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- root-5.26.00-r4.ebuild	6 Jul 2010 15:59:37 -0000	1.4
+++ root-5.26.00-r4.ebuild	16 Oct 2010 17:37:24 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v 1.4 2010/07/06 15:59:37 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/root-5.26.00-r4.ebuild,v 1.5 2010/10/16 17:37:24 xarthisius Exp $
 
 EAPI=3
 
@@ -105,6 +105,7 @@
 }
 
 src_prepare() {
+	epatch "${FILESDIR}"/${P}-make-3.82.patch
 	epatch "${WORKDIR}"/${P}-svn34137.patch
 	epatch "${WORKDIR}"/${P}-prop-ldflags.patch
 	epatch "${WORKDIR}"/${P}-xrootd-prop-flags.patch






^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sci-physics/root: ChangeLog root-5.26.00-r4.ebuild
@ 2011-01-18 17:11 Kacper Kowalik (xarthisius)
  0 siblings, 0 replies; 5+ messages in thread
From: Kacper Kowalik (xarthisius) @ 2011-01-18 17:11 UTC (permalink / raw
  To: gentoo-commits

xarthisius    11/01/18 17:11:58

  Modified:             ChangeLog
  Removed:              root-5.26.00-r4.ebuild
  Log:
  Drop old.
  
  (Portage version: 2.2.0_alpha16/cvs/Linux x86_64)

Revision  Changes    Path
1.78                 sci-physics/root/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-physics/root/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	8 Nov 2010 17:54:05 -0000	1.77
+++ ChangeLog	18 Jan 2011 17:11:58 -0000	1.78
@@ -1,6 +1,9 @@
 # ChangeLog for sci-physics/root
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.77 2010/11/08 17:54:05 xarthisius Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-physics/root/ChangeLog,v 1.78 2011/01/18 17:11:58 xarthisius Exp $
+
+  18 Jan 2011; Kacper Kowalik <xarthisius@gentoo.org> -root-5.26.00-r4.ebuild:
+  Drop old.
 
   08 Nov 2010; Kacper Kowalik <xarthisius@gentoo.org>
   root-5.26.00-r2.ebuild, root-5.26.00-r4.ebuild, root-5.26.00e-r1.ebuild:






^ permalink raw reply	[flat|nested] 5+ messages in thread
end of thread, other threads:[~2011-01-18 17:12 UTC | newest]

Thread overview: 5+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-01-18 17:11 [gentoo-commits] gentoo-x86 commit in sci-physics/root: ChangeLog root-5.26.00-r4.ebuild Kacper Kowalik (xarthisius)
  -- strict thread matches above, loose matches on Subject: below --
2010-10-16 17:37 Kacper Kowalik (xarthisius)
2010-07-06 15:59 Sebastien Fabbro (bicatali)
2010-06-25 22:13 Arfrever Frehtes Taifersar Arahesis (arfrever)
2010-06-25 17:12 Justin Lecher (jlec)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox