* [gentoo-commits] gentoo-x86 commit in net-misc/curl: ChangeLog curl-7.21.3.ebuild curl-7.21.1.ebuild curl-7.21.0.ebuild curl-7.20.1.ebuild
@ 2011-01-12 18:37 Dror Levin (spatz)
0 siblings, 0 replies; only message in thread
From: Dror Levin (spatz) @ 2011-01-12 18:37 UTC (permalink / raw
To: gentoo-commits
spatz 11/01/12 18:37:32
Modified: ChangeLog
Added: curl-7.21.3.ebuild
Removed: curl-7.21.1.ebuild curl-7.21.0.ebuild
curl-7.20.1.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha15/cvs/Linux x86_64)
Revision Changes Path
1.170 net-misc/curl/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?rev=1.170&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?rev=1.170&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/ChangeLog?r1=1.169&r2=1.170
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v
retrieving revision 1.169
retrieving revision 1.170
diff -u -r1.169 -r1.170
--- ChangeLog 1 Dec 2010 20:42:44 -0000 1.169
+++ ChangeLog 12 Jan 2011 18:37:32 -0000 1.170
@@ -1,6 +1,12 @@
# ChangeLog for net-misc/curl
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.169 2010/12/01 20:42:44 scarabeus Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/ChangeLog,v 1.170 2011/01/12 18:37:32 spatz Exp $
+
+*curl-7.21.3 (12 Jan 2011)
+
+ 12 Jan 2011; Dror Levin <spatz@gentoo.org> -curl-7.20.1.ebuild,
+ -curl-7.21.0.ebuild, -curl-7.21.1.ebuild, +curl-7.21.3.ebuild:
+ Version bump.
*curl-7.21.2 (01 Dec 2010)
1.1 net-misc/curl/curl-7.21.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/curl-7.21.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/curl/curl-7.21.3.ebuild?rev=1.1&content-type=text/plain
Index: curl-7.21.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/curl-7.21.3.ebuild,v 1.1 2011/01/12 18:37:32 spatz Exp $
# NOTE: If you bump this ebuild, make sure you bump dev-python/pycurl!
EAPI=3
inherit multilib eutils libtool prefix
#MY_P=${P/_pre/-}
DESCRIPTION="A Client that groks URLs"
HOMEPAGE="http://curl.haxx.se/"
#SRC_URI="http://cool.haxx.se/curl-daily/${MY_P}.tar.bz2"
SRC_URI="http://curl.haxx.se/download/${P}.tar.bz2"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="ares gnutls idn ipv6 kerberos ldap libssh2 nss ssl test threads"
RDEPEND="ldap? ( net-nds/openldap )
ssl? (
gnutls? ( net-libs/gnutls app-misc/ca-certificates )
nss? ( !gnutls? ( dev-libs/nss app-misc/ca-certificates ) )
!gnutls? ( !nss? ( dev-libs/openssl ) )
)
idn? ( net-dns/libidn )
!threads? ( ares? ( >=net-dns/c-ares-1.4.0 ) )
kerberos? ( virtual/krb5 )
libssh2? ( >=net-libs/libssh2-0.16 )"
# rtmpdump ( media-video/rtmpdump ) / --with-librtmp
# fbopenssl (not in gentoo) --with-spnego
# krb4 http://web.mit.edu/kerberos/www/krb4-end-of-life.html
DEPEND="${RDEPEND}
test? (
sys-apps/diffutils
dev-lang/perl
)"
# used - but can do without in self test: net-misc/stunnel
pkg_setup() {
if ! use ssl && ( use gnutls || use nss ) ; then
ewarn "USE='gnutls nss' are ignored without USE='ssl'."
ewarn "Please review the local USE flags for this package."
fi
if use ares && use threads; then
ewarn "USE flags 'ares' and 'threads' are mutually exclusive,"
ewarn "disabling 'ares', please review and re-emerge if needed."
fi
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-7.20.0-strip-ldflags.patch \
"${FILESDIR}"/${PN}-7.19.7-test241.patch \
"${FILESDIR}"/${PN}-7.18.2-prefix.patch
eprefixify curl-config.in
# for FreeMiNT
elibtoolize
}
src_configure() {
myconf="$(use_enable ldap)
$(use_enable ldap ldaps)
$(use_with idn libidn)
$(use_with kerberos gssapi "${EPREFIX}"/usr)
$(use_with libssh2)
$(use_enable ipv6)
$(use_enable threads threaded-resolver)
$(use threads && echo --disable-ares || use_enable ares)
--enable-http
--enable-ftp
--enable-gopher
--enable-file
--enable-dict
--enable-manual
--enable-telnet
--enable-smtp
--enable-pop3
--enable-imap
--enable-rtsp
--enable-nonblocking
--enable-largefile
--enable-maintainer-mode
--disable-sspi
--without-krb4
--without-librtmp
--without-spnego"
if use ssl ; then
if use gnutls; then
myconf="${myconf} --without-ssl --with-gnutls --without-nss"
myconf="${myconf} --with-ca-bundle=${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
elif use nss; then
myconf="${myconf} --without-ssl --without-gnutls --with-nss"
myconf="${myconf} --with-ca-bundle=${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
else
myconf="${myconf} --without-gnutls --without-nss --with-ssl"
myconf="${myconf} --without-ca-bundle --with-ca-path=${EPREFIX}/etc/ssl/certs"
fi
else
myconf="${myconf} --without-gnutls --without-nss --without-ssl"
fi
econf ${myconf} || die 'configure failed'
}
src_install() {
emake DESTDIR="${D}" install || die "installed failed for current version"
rm -rf "${ED}"/etc/
# https://sourceforge.net/tracker/index.php?func=detail&aid=1705197&group_id=976&atid=350976
insinto /usr/share/aclocal
doins docs/libcurl/libcurl.m4 || die
dodoc CHANGES README || die
dodoc docs/FEATURES docs/INTERNALS || die
dodoc docs/MANUAL docs/FAQ docs/BUGS docs/CONTRIBUTE || die
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2011-01-12 18:38 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-01-12 18:37 [gentoo-commits] gentoo-x86 commit in net-misc/curl: ChangeLog curl-7.21.3.ebuild curl-7.21.1.ebuild curl-7.21.0.ebuild curl-7.20.1.ebuild Dror Levin (spatz)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox