[gentoo-commits] gentoo-x86 commit in xfce-base/thunar: thunar-1.1.6.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in xfce-base/thunar: thunar-1.1.6.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    11/01/02 15:44:33

  Modified:             ChangeLog
  Added:                thunar-1.1.6.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha10/cvs/Linux x86_64)

Revision  Changes    Path
1.109                xfce-base/thunar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/thunar/ChangeLog?rev=1.109&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/thunar/ChangeLog?rev=1.109&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/thunar/ChangeLog?r1=1.108&r2=1.109

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v
retrieving revision 1.108
retrieving revision 1.109
diff -u -r1.108 -r1.109
--- ChangeLog	25 Dec 2010 10:35:48 -0000	1.108
+++ ChangeLog	2 Jan 2011 15:44:33 -0000	1.109
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/thunar
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.108 2010/12/25 10:35:48 ssuominen Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.109 2011/01/02 15:44:33 ssuominen Exp $
+
+*thunar-1.1.6 (02 Jan 2011)
+
+  02 Jan 2011; Samuli Suominen <ssuominen@gentoo.org> +thunar-1.1.6.ebuild:
+  Version bump.
 
   25 Dec 2010; Samuli Suominen <ssuominen@gentoo.org> thunar-1.1.5.ebuild:
   Missing gnome-base/gvfs runtime depend which is required by Trash.



1.1                  xfce-base/thunar/thunar-1.1.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/thunar/thunar-1.1.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/thunar/thunar-1.1.6.ebuild?rev=1.1&content-type=text/plain

Index: thunar-1.1.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/thunar-1.1.6.ebuild,v 1.1 2011/01/02 15:44:33 ssuominen Exp $

EAPI=3
inherit virtualx xfconf

MY_P=${P/t/T}

DESCRIPTION="A file manager for the Xfce desktop environment"
HOMEPAGE="http://www.xfce.org/projects/thunar/ http://thunar.xfce.org/"
SRC_URI="mirror://xfce/src/xfce/${PN}/1.1/${MY_P}.tar.bz2"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="dbus debug exif libnotify pcre startup-notification test +xfce_plugins_trash udev"

GVFS_DEPEND=">=gnome-base/gvfs-1.6.4-r2"
COMMON_DEPEND=">=xfce-base/exo-0.5.3
	>=dev-libs/glib-2.18:2
	>=x11-libs/gtk+-2.14:2
	>=xfce-base/libxfce4util-4.6
	>=xfce-base/libxfce4ui-4.7.1
	>=dev-lang/perl-5.6
	dbus? ( >=dev-libs/dbus-glib-0.88 )
	exif? ( >=media-libs/libexif-0.6.19 )
	libnotify? ( x11-libs/libnotify )
	pcre? ( >=dev-libs/libpcre-6 )
	startup-notification? ( x11-libs/startup-notification )
	udev? ( >=sys-fs/udev-145[extras] )
	xfce_plugins_trash? ( >=dev-libs/dbus-glib-0.88
		>=xfce-base/xfce4-panel-4.3.90 )"
RDEPEND="${COMMON_DEPEND}
	x11-misc/shared-mime-info
	dev-util/desktop-file-utils
	dbus? ( ${GVFS_DEPEND} )
	udev? ( ${GVFS_DEPEND}[gdu,udev] )
	xfce_plugins_trash? ( ${GVFS_DEPEND} )"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	dev-util/pkgconfig
	sys-devel/gettext"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	XFCONF=(
		--docdir="${EPREFIX}"/usr/share/doc/${PF}
		--disable-dependency-tracking
		$(use_enable dbus)
		$(use_enable startup-notification)
		$(use_enable udev gudev)
		$(use_enable libnotify notifications)
		$(xfconf_use_debug)
		$(use_enable exif)
		$(use_enable pcre)
		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
		)

	if use xfce_plugins_trash; then
		XFCONF+=( --enable-dbus )
	else
		XFCONF+=( --disable-tpa-plugin )
	fi

	DOCS="AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO"
}

src_test() {
	Xemake check || die
}