[gentoo-commits] gentoo-x86 commit in app-arch/rpm: ChangeLog rpm-4.8.1-r1.ebuild rpm-4.8.1.ebuild

[gentoo-commits] gentoo-x86 commit in app-arch/rpm: ChangeLog rpm-4.8.1-r1.ebuild rpm-4.8.1.ebuild

[Stanislav Ochotnicky (sochotnicky)]

sochotnicky    10/12/27 18:55:45

  Modified:             ChangeLog
  Added:                rpm-4.8.1-r1.ebuild
  Removed:              rpm-4.8.1.ebuild
  Log:
  Fix #349840 (incorrect symlinks to /bin/rpm)
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.120                app-arch/rpm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	14 Dec 2010 02:04:48 -0000	1.119
+++ ChangeLog	27 Dec 2010 18:55:45 -0000	1.120
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/rpm
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v 1.119 2010/12/14 02:04:48 mattst88 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/ChangeLog,v 1.120 2010/12/27 18:55:45 sochotnicky Exp $
+
+*rpm-4.8.1-r1 (27 Dec 2010)
+
+  27 Dec 2010; Stanislav Ochotnicky <sochotnicky@gentoo.org>
+  -rpm-4.8.1.ebuild, +rpm-4.8.1-r1.ebuild:
+  Fix #349840 (incorrect symlinks to /bin/rpm)
 
   14 Dec 2010; Matt Turner <mattst88@gentoo.org> rpm-4.4.7-r4.ebuild,
   rpm-4.4.7-r5.ebuild, rpm-4.4.7-r6.ebuild, rpm-4.8.1.ebuild,



1.1                  app-arch/rpm/rpm-4.8.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-4.8.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rpm/rpm-4.8.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: rpm-4.8.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/rpm/rpm-4.8.1-r1.ebuild,v 1.1 2010/12/27 18:55:45 sochotnicky Exp $

EAPI=2

inherit eutils autotools flag-o-matic perl-module distutils

DESCRIPTION="Red Hat Package Management Utils"
HOMEPAGE="http://www.rpm.org"
SRC_URI="http://rpm.org/releases/rpm-4.8.x/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="nls python doc sqlite caps lua acl"

RDEPEND="=sys-libs/db-4.5*
	>=sys-libs/zlib-1.2.3-r1
	>=app-arch/bzip2-1.0.1
	>=dev-libs/popt-1.7
	>=app-crypt/gnupg-1.2
	dev-libs/elfutils
	virtual/libintl
	>=dev-lang/perl-5.8.8
	dev-libs/nss
	python? ( >=dev-lang/python-2.3 )
	nls? ( virtual/libintl )
	sqlite? ( >=dev-db/sqlite-3.3.5 )
	lua? ( >=dev-lang/lua-5.1.0 )
	acl? ( virtual/acl )
	caps? ( >=sys-libs/libcap-2.0 )"

DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	doc? ( app-doc/doxygen )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-autotools.patch
	epatch "${FILESDIR}"/${P}-db-path.patch

	# fix #326665
	sed -i 's:rpmio/librpmio.la:rpmio/.libs/librpmio.la:' \
			lib/Makefile.am || die "Patching librpm Makefile.am failed"

	eautoreconf
}

src_compile() {
	emake || die "emake failed"
}

src_configure() {
	econf \
		--without-selinux \
		--with-external-db \
		$(use_enable python) \
		$(use_with doc hackingdocs) \
		$(use_enable sqlite sqlite3) \
		$(use_enable nls) \
		$(use_with lua) \
		$(use_with caps cap)\
		$(use_with acl)\
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" INSTALLDIRS=vendor install || die "emake install failed"

	mv "${D}"/bin/rpm "${D}"/usr/bin
	rmdir "${D}"/bin
	# fix symlinks to /bin/rpm (#349840)
	for binary in rpmdb rpmquery rpmsign rpmverify;do
		ln -sf rpm "${D}"/usr/bin/$binary
	done

	use nls || rm -rf "${D}"/usr/share/man/??

	keepdir /usr/src/rpm/{SRPMS,SPECS,SOURCES,RPMS,BUILD}

	dodoc CHANGES CREDITS GROUPS README*
	use doc && dohtml -r apidocs/html/*

	# Fix perllocal.pod file collision
	fixlocalpod
}

pkg_postinst() {
	if [[ -f "${ROOT}"/var/lib/rpm/Packages ]] ; then
		einfo "RPM database found... Rebuilding database (may take a while)..."
		"${ROOT}"/usr/bin/rpm --rebuilddb --root="${ROOT}"
	else
		einfo "No RPM database found... Creating database..."
		"${ROOT}"/usr/bin/rpm --initdb --root="${ROOT}"
	fi

	distutils_pkg_postinst
}