[gentoo-commits] gentoo-x86 commit in media-libs/clutter: ChangeLog clutter-1.5.10.ebuild clutter-1.2.10.ebuild clutter-1.2.12.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/clutter: ChangeLog clutter-1.5.10.ebuild clutter-1.2.10.ebuild clutter-1.2.12.ebuild

[Nirbheek Chauhan (nirbheek)]

nirbheek    10/12/24 01:49:39

  Modified:             ChangeLog
  Added:                clutter-1.5.10.ebuild
  Removed:              clutter-1.2.10.ebuild clutter-1.2.12.ebuild
  Log:
  Bump to 1.5.10, various fixes and features
  
  (Portage version: 2.1.9.26/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 media-libs/clutter/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	5 Dec 2010 14:37:51 -0000	1.11
+++ ChangeLog	24 Dec 2010 01:49:39 -0000	1.12
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/clutter
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.11 2010/12/05 14:37:51 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.12 2010/12/24 01:49:39 nirbheek Exp $
+
+*clutter-1.5.10 (24 Dec 2010)
+
+  24 Dec 2010; <nirbheek@gentoo.org> -clutter-1.2.10.ebuild,
+  -clutter-1.2.12.ebuild, +clutter-1.5.10.ebuild:
+  Bump to 1.5.10, various fixes and features
 
 *clutter-1.5.8 (05 Dec 2010)
 



1.1                  media-libs/clutter/clutter-1.5.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/clutter-1.5.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/clutter/clutter-1.5.10.ebuild?rev=1.1&content-type=text/plain

Index: clutter-1.5.10.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/clutter-1.5.10.ebuild,v 1.1 2010/12/24 01:49:39 nirbheek Exp $

EAPI="2"

inherit clutter

DESCRIPTION="Clutter is a library for creating graphical user interfaces"

SLOT="1.0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="debug doc +gtk +introspection"

# NOTE: glx flavour uses libdrm + >=mesa-7.3
RDEPEND=">=dev-libs/glib-2.26
	>=x11-libs/cairo-1.10
	>=x11-libs/pango-1.20[introspection?]
	>=dev-libs/json-glib-0.12[introspection?]
	>=dev-libs/atk-1.7

	virtual/opengl
	x11-libs/libdrm
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXdamage
	x11-libs/libXi
	x11-proto/inputproto
	>=x11-libs/libXfixes-3
	>=x11-libs/libXcomposite-0.4

	gtk? ( || (
		x11-libs/gdk-pixbuf
		>=x11-libs/gtk+-2.0 ) )
	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
"
DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/pkgconfig
	>=dev-util/gtk-doc-am-1.13
	doc? (
		>=dev-util/gtk-doc-1.13
		>=app-text/docbook-sgml-utils-0.6.14[jadetex]
		dev-libs/libxslt )
"
DOCS="AUTHORS README NEWS ChangeLog*"

src_configure() {
	# We only need conformance tests, the rest are useless for us
	sed -e 's/^\(SUBDIRS =\).*/\1/g' \
		-i tests/Makefile.am || die "am tests sed failed"
	sed -e 's/^\(SUBDIRS =\).*/\1/g' \
		-i tests/Makefile.in || die "in tests sed failed"

	# XXX: Conformance test suite (and clutter itself) does not work under Xvfb
	# XXX: Profiling, coverage disabled for now
	# XXX: What about eglx/eglnative/opengl-egl-xlib/osx/wayland/etc flavours?
	#      Uses gudev-1.0 and libxkbcommon for eglnative/cex1000
	local myconf="
		--enable-debug=minimum
		--enable-cogl-debug=minimum
		--enable-conformance=no
		--disable-gcov
		--enable-profile=no
		--enable-maintainer-flags=no
		--enable-xinput
		--with-flavour=glx
		--with-imagebackend=gdk-pixbuf
		$(use_enable introspection)
		$(use_enable doc docs)
		$(use_enable doc cogl2-reference)"

	if ! use gtk; then
		myconf="${myconf} --with-imagebackend=internal"
		# Internal image backend is experimental
		ewarn "You have selected the experimental internal image backend"
	fi

	if use debug; then
		myconf="${myconf}
			--enable-debug=yes
			--enable-cogl-debug=yes"
	fi

	econf ${myconf}
}