[gentoo-commits] gentoo-x86 commit in app-admin/webapp-config: ChangeLog webapp-config-1.50.16-r4.ebuild webapp-config-1.50.16-r3.ebuild

[gentoo-commits] gentoo-x86 commit in app-admin/webapp-config: ChangeLog webapp-config-1.50.16-r4.ebuild webapp-config-1.50.16-r3.ebuild

[Rafael Martins (rafaelmartins)]

rafaelmartins    10/12/19 18:31:55

  Modified:             ChangeLog
  Added:                webapp-config-1.50.16-r4.ebuild
  Removed:              webapp-config-1.50.16-r3.ebuild
  Log:
  Added support to www-servers/{nginx,gatling}. Thanks to Fernando V. (bug #211996)
  
  (Portage version: 2.2.0_alpha8/cvs/Linux x86_64)

Revision  Changes    Path
1.68                 app-admin/webapp-config/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	4 Oct 2010 00:01:32 -0000	1.67
+++ ChangeLog	19 Dec 2010 18:31:55 -0000	1.68
@@ -1,6 +1,14 @@
 # ChangeLog for app-admin/webapp-config
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v 1.67 2010/10/04 00:01:32 reavertm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/ChangeLog,v 1.68 2010/12/19 18:31:55 rafaelmartins Exp $
+
+*webapp-config-1.50.16-r4 (19 Dec 2010)
+
+  19 Dec 2010; Rafael G. Martins <rafaelmartins@gentoo.org>
+  -webapp-config-1.50.16-r3.ebuild, +webapp-config-1.50.16-r4.ebuild,
+  +files/webapp-config-1.50.16-update-servers.patch:
+  Added support to www-servers/{nginx,gatling}. Thanks to Fernando V. (bug
+  #211996)
 
   03 Oct 2010; Maciej Mrozowski <reavertm@gentoo.org>
   webapp-config-1.50.16-r1.ebuild:



1.1                  app-admin/webapp-config/webapp-config-1.50.16-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/webapp-config-1.50.16-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/webapp-config/webapp-config-1.50.16-r4.ebuild?rev=1.1&content-type=text/plain

Index: webapp-config-1.50.16-r4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/webapp-config-1.50.16-r4.ebuild,v 1.1 2010/12/19 18:31:55 rafaelmartins Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"

inherit distutils eutils

DESCRIPTION="Gentoo's installer for web-based applications"
HOMEPAGE="http://sourceforge.net/projects/webapp-config/"
SRC_URI="mirror://gentoo/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE=""

DEPEND=""
RDEPEND=""
RESTRICT_PYTHON_ABIS="3.*"

PYTHON_MODNAME="WebappConfig"

src_prepare() {
	epatch "${FILESDIR}/${P}-apache-move.patch"
	epatch "${FILESDIR}/${P}-baselayout2.patch"
	epatch "${FILESDIR}/${P}-htdocs-symlink.patch"
	epatch "${FILESDIR}/${P}-absolute-paths.patch"
	epatch "${FILESDIR}/${P}-update-servers.patch"
	# Do not build nor install eclass manual, bug 322759
	rm -f doc/webapp.eclass.5*
	sed -e '/MAN_PAGES/s/webapp.eclass.5//' \
		-e '/HTML_PAGES/s/webapp.eclass.5.html//' \
		-i doc/Makefile || die
}

src_install() {
	# According to this discussion:
	# http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
	# distutils does not provide for specifying two different script install
	# locations. Since we only install one script here the following should
	# be ok
	distutils_src_install --install-scripts="/usr/sbin"

	python_convert_shebangs 2 "${ED}usr/sbin/webapp-config"

	insinto /etc/vhosts
	doins config/webapp-config

	keepdir /usr/share/webapps
	keepdir /var/db/webapps

	dodoc examples/phpmyadmin-2.5.4-r1.ebuild AUTHORS.txt CHANGES.txt examples/postinstall-en.txt
	doman doc/*.[58]
	dohtml doc/*.[58].html
}

src_test() {
	testing() {
		PYTHONPATH="." "$(PYTHON)" WebappConfig/tests/dtest.py
	}
	python_execute_function testing
}

pkg_postinst() {
	distutils_pkg_postinst

	elog "Now that you have upgraded webapp-config, you **must** update your"
	elog "config files in /etc/vhosts/webapp-config before you emerge any"
	elog "packages that use webapp-config."
}