* [gentoo-commits] gentoo-x86 commit in net-p2p/transmission: ChangeLog transmission-2.13.ebuild transmission-2.11-r1.ebuild transmission-2.11-r3.ebuild
@ 2010-12-19 14:44 Peter Volkov (pva)
0 siblings, 0 replies; only message in thread
From: Peter Volkov (pva) @ 2010-12-19 14:44 UTC (permalink / raw
To: gentoo-commits
pva 10/12/19 14:44:51
Modified: ChangeLog
Added: transmission-2.13.ebuild
Removed: transmission-2.11-r1.ebuild
transmission-2.11-r3.ebuild
Log:
Version bump, drop old.
(Portage version: 2.1.9.25/cvs/Linux x86_64)
Revision Changes Path
1.135 net-p2p/transmission/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.135&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.135&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?r1=1.134&r2=1.135
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v
retrieving revision 1.134
retrieving revision 1.135
diff -u -r1.134 -r1.135
--- ChangeLog 16 Nov 2010 15:25:38 -0000 1.134
+++ ChangeLog 19 Dec 2010 14:44:51 -0000 1.135
@@ -1,6 +1,13 @@
# ChangeLog for net-p2p/transmission
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.134 2010/11/16 15:25:38 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.135 2010/12/19 14:44:51 pva Exp $
+
+*transmission-2.13 (19 Dec 2010)
+
+ 19 Dec 2010; Peter Volkov <pva@gentoo.org> -transmission-2.11-r1.ebuild,
+ -transmission-2.11-r3.ebuild, +transmission-2.13.ebuild,
+ -files/transmission-daemon.initd.4:
+ Version bump, drop old.
*transmission-2.12 (16 Nov 2010)
1.1 net-p2p/transmission/transmission-2.13.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.13.ebuild?rev=1.1&content-type=text/plain
Index: transmission-2.13.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-2.13.ebuild,v 1.1 2010/12/19 14:44:51 pva Exp $
EAPI=2
inherit eutils fdo-mime gnome2-utils qt4-r2
DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com/"
SRC_URI="http://download.transmissionbt.com/${PN}/files/${P}.tar.bz2"
LICENSE="MIT GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="gnome gtk kde libnotify sound qt4"
RDEPEND="
sys-libs/zlib
>=dev-libs/libevent-1.4.11
<dev-libs/libevent-2
>=dev-libs/openssl-0.9.4
|| ( >=net-misc/curl-7.16.3[ssl]
>=net-misc/curl-7.16.3[gnutls] )
gtk? ( >=dev-libs/glib-2.15.5:2
>=x11-libs/gtk+-2.12:2
>=dev-libs/dbus-glib-0.70
gnome? ( >=gnome-base/gconf-2.20.0 )
libnotify? ( >=x11-libs/libnotify-0.4.3 )
sound? ( >=media-libs/libcanberra-0.10 ) )
qt4? ( x11-libs/qt-gui:4[dbus] )"
DEPEND="${RDEPEND}
>=sys-devel/libtool-2.2.6b
sys-devel/gettext
>=dev-util/intltool-0.40
dev-util/pkgconfig
sys-apps/sed"
pkg_setup() {
enewgroup transmission
enewuser transmission -1 -1 -1 transmission
}
src_prepare() {
sed -i -e 's:-ggdb3::g' configure || die
# Magnet link support
if use kde; then
cat > qt/transmission-magnet.protocol <<-EOF
[Protocol]
exec=transmission-qt '%u'
protocol=magnet
Icon=transmission
input=none
output=none
helper=true
listing=
reading=false
writing=false
makedir=false
deleting=false
EOF
fi
}
src_configure() {
# cli and daemon doesn't have external deps and are enabled by default
econf \
--disable-dependency-tracking \
$(use_enable gtk) \
$(use gtk && use_enable libnotify) \
$(use gtk && use_enable sound libcanberra) \
$(use gtk && use_enable gnome gconf2)
use qt4 && cd qt && eqmake4 qtr.pro
}
src_compile() {
emake || die
use qt4 && cd qt && { emake || die; }
}
src_install() {
emake DESTDIR="${D}" install || die
dodoc AUTHORS NEWS qt/README.txt
rm -f "${D}"/usr/share/${PN}/web/LICENSE
newinitd "${FILESDIR}"/${PN}-daemon.initd.5 ${PN}-daemon || die
newconfd "${FILESDIR}"/${PN}-daemon.confd.2 ${PN}-daemon || die
keepdir /var/{transmission/{config,downloads},log/transmission}
fowners -R transmission:transmission /var/{transmission/{,config,downloads},log/transmission}
if use qt4; then
cd qt
emake INSTALL_ROOT="${D}/usr" install || die
insinto /usr/share/applications/
doins transmission-qt.desktop || die
mv icons/transmission{,-qt}.png
doicon icons/transmission-qt.png || die
if use kde; then
insinto /usr/share/kde4/services/
doins transmission-magnet.protocol || die
fi
fi
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
# Keep default permissions on default dirs
chown -R transmission:transmission /var/{transmission/{,config,downloads},log/transmission}
ewarn "If you use transmission-daemon, please, set 'rpc-username' and"
ewarn "'rpc-password' (in plain text, transmission-daemon will hash it on"
ewarn "start) in settings.json file located at /var/transmission/config or"
ewarn "any other appropriate config directory."
if use gtk; then
elog 'If you want magnet link support in gnome run this commands:'
elog 'gconftool-2 -t string -s /desktop/gnome/url-handlers/magnet/command "/usr/bin/transmission-gtk %s"'
elog 'gconftool-2 -s /desktop/gnome/url-handlers/magnet/needs_terminal false -t bool'
elog 'gconftool-2 -t bool -s /desktop/gnome/url-handlers/magnet/enabled true'
fi
}
pkg_postrm() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-12-19 14:45 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-12-19 14:44 [gentoo-commits] gentoo-x86 commit in net-p2p/transmission: ChangeLog transmission-2.13.ebuild transmission-2.11-r1.ebuild transmission-2.11-r3.ebuild Peter Volkov (pva)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox