[gentoo-commits] gentoo-x86 commit in gnome-extra/bug-buddy: bug-buddy-2.32.0-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in gnome-extra/bug-buddy: bug-buddy-2.32.0-r1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       10/12/16 19:36:17

  Modified:             ChangeLog
  Added:                bug-buddy-2.32.0-r1.ebuild
  Log:
  Revision bump to revert upstream commit that was causing gnome-session to be always running in debug mode (bug #348722), and to prevent old gnomebreakpad from trying to be loaded (bug #348351).
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.187                gnome-extra/bug-buddy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/bug-buddy/ChangeLog?rev=1.187&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/bug-buddy/ChangeLog?rev=1.187&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/bug-buddy/ChangeLog?r1=1.186&r2=1.187

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/bug-buddy/ChangeLog,v
retrieving revision 1.186
retrieving revision 1.187
diff -u -r1.186 -r1.187
--- ChangeLog	22 Oct 2010 19:40:13 -0000	1.186
+++ ChangeLog	16 Dec 2010 19:36:17 -0000	1.187
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/bug-buddy
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/bug-buddy/ChangeLog,v 1.186 2010/10/22 19:40:13 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/bug-buddy/ChangeLog,v 1.187 2010/12/16 19:36:17 pacho Exp $
+
+*bug-buddy-2.32.0-r1 (16 Dec 2010)
+
+  16 Dec 2010; Pacho Ramos <pacho@gentoo.org> +bug-buddy-2.32.0-r1.ebuild:
+  Revision bump to revert upstream commit that was causing gnome-session to be
+  always running in debug mode (bug #348722), and to prevent old gnomebreakpad
+  from trying to be loaded (bug #348351).
 
   22 Oct 2010; Gilles Dartiguelongue <eva@gentoo.org>
   -bug-buddy-2.26.0.ebuild, -bug-buddy-2.28.0.ebuild,



1.1                  gnome-extra/bug-buddy/bug-buddy-2.32.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/bug-buddy/bug-buddy-2.32.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/bug-buddy/bug-buddy-2.32.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: bug-buddy-2.32.0-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/bug-buddy/bug-buddy-2.32.0-r1.ebuild,v 1.1 2010/12/16 19:36:17 pacho Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit gnome2 eutils

DESCRIPTION="A graphical bug reporting tool"
HOMEPAGE="http://www.gnome.org/"

LICENSE="Ximian-logos GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="eds"

RDEPEND=">=gnome-base/libbonobo-2
	>=dev-libs/glib-2.16:2
	>=dev-libs/libxml2-2.4.6
	>=x11-libs/gtk+-2.14:2
	>=net-libs/libsoup-2.4
	>=gnome-base/libgtop-2.13.3
	>=gnome-base/gconf-2
	|| ( dev-libs/elfutils dev-libs/libelf )
	>=sys-devel/gdb-5.1
	eds? ( >=gnome-extra/evolution-data-server-1.3 )"
DEPEND="${RDEPEND}
	>=app-text/gnome-doc-utils-0.3.2
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_enable eds)"
	DOCS="AUTHORS ChangeLog NEWS README TODO"
}

src_prepare() {
	gnome2_src_prepare

	# Revert this commit as it causes gnome-session to always run in debug mode, bug #348722
	EPATCH_OPTS="-R" epatch "${FILESDIR}/${PN}-2.32.0-gnomesession-debug.patch"
}

pkg_postinst() {
	# Prevent old gnomebreakpad to be requested, bug #348351
	local gconftool="${EROOT}usr/bin/gconftool-2"
	local GCONF_CONFIG_SOURCE="$("${gconftool}" --get-default-source | sed "s;:/;:${ROOT};")"

	"${gconftool}" --direct --config-source "${GCONF_CONFIG_SOURCE}" --type=string \
		--set /apps/gnome_settings_daemon/gtk-modules/gnomebreakpad false || die

	gnome2_pkg_postinst
}