[gentoo-commits] gentoo-x86 commit in dev-libs/libpcre: libpcre-8.11.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-libs/libpcre: libpcre-8.11.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    10/12/14 23:23:15

  Modified:             ChangeLog
  Added:                libpcre-8.11.ebuild
  Log:
  Version bump; thanks to Arseny Solokha for reporting (bug #348743).
  
  (Portage version: 2.2.0_alpha8/cvs/Linux x86_64)

Revision  Changes    Path
1.169                dev-libs/libpcre/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpcre/ChangeLog?rev=1.169&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpcre/ChangeLog?rev=1.169&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpcre/ChangeLog?r1=1.168&r2=1.169

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libpcre/ChangeLog,v
retrieving revision 1.168
retrieving revision 1.169
diff -u -r1.168 -r1.169
--- ChangeLog	13 Dec 2010 15:49:10 -0000	1.168
+++ ChangeLog	14 Dec 2010 23:23:14 -0000	1.169
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libpcre
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpcre/ChangeLog,v 1.168 2010/12/13 15:49:10 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpcre/ChangeLog,v 1.169 2010/12/14 23:23:14 flameeyes Exp $
+
+*libpcre-8.11 (14 Dec 2010)
+
+  14 Dec 2010; Diego E. Pettenò <flameeyes@gentoo.org> +libpcre-8.11.ebuild:
+  Version bump; thanks to Arseny Solokha for reporting (bug #348743).
 
   13 Dec 2010; Jeroen Roovers <jer@gentoo.org> libpcre-8.02.ebuild:
   Stable for HPPA (bug #348487).



1.1                  dev-libs/libpcre/libpcre-8.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpcre/libpcre-8.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpcre/libpcre-8.11.ebuild?rev=1.1&content-type=text/plain

Index: libpcre-8.11.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpcre/libpcre-8.11.ebuild,v 1.1 2010/12/14 23:23:14 flameeyes Exp $

EAPI=2

inherit libtool eutils toolchain-funcs

DESCRIPTION="Perl-compatible regular expression library"
HOMEPAGE="http://www.pcre.org/"
if [[ ${PV} == ${PV/_rc} ]]
then
	MY_P="pcre-${PV}"
	SRC_URI="ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/${MY_P}.tar.bz2"
else
	MY_P="pcre-${PV/_rc/-RC}"
	SRC_URI="ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/Testing/${MY_P}.tar.bz2"
fi
LICENSE="BSD"
SLOT="3"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="bzip2 +cxx unicode zlib static-libs +recursion-limit"

RDEPEND="bzip2? ( app-arch/bzip2 )
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	userland_GNU? ( >=sys-apps/findutils-4.4.0 )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	sed -i -e "s:-lpcre ::" libpcrecpp.pc.in || die "Fixing libpcrecpp pkgconfig files failed"
	elibtoolize
}

src_configure() {
	econf --with-match-limit-recursion=$(use recursion-limit && echo 8192 || echo MATCH_LIMIT) \
		$(use_enable unicode utf8) $(use_enable unicode unicode-properties) \
		$(use_enable cxx cpp) \
		$(use_enable zlib pcregrep-libz) \
		$(use_enable bzip2 pcregrep-libbz2) \
		$(use_enable static-libs static) \
		--enable-shared \
		--htmldir=/usr/share/doc/${PF}/html \
		--docdir=/usr/share/doc/${PF} \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	gen_usr_ldscript -a pcre
	find "${D}" -type f -name '*.la' -exec rm -rf '{}' '+' || die "la removal failed"
}

pkg_postinst() {
	elog "This version of ${PN} has stopped installing .la files. This may"
	elog "cause compilation failures in other packages. To fix this problem,"
	elog "install dev-util/lafilefixer and run:"
	elog "lafilefixer --justfixit"
}