[gentoo-commits] gentoo-x86 commit in app-text/pdftk: pdftk-1.44.ebuild ChangeLog pdftk-1.41-r2.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/pdftk: pdftk-1.44.ebuild ChangeLog pdftk-1.41-r2.ebuild

[Michael Weber (xmw)]

xmw         10/11/27 22:16:39

  Modified:             ChangeLog
  Added:                pdftk-1.44.ebuild pdftk-1.41-r2.ebuild
  Log:
  Revision bump to fix gcc:4.5 problems (bug 339345).
  
  (Portage version: 2.1.9.24/cvs/Linux x86_64)

Revision  Changes    Path
1.34                 app-text/pdftk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/pdftk/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/pdftk/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/pdftk/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/pdftk/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	9 Jul 2010 09:25:37 -0000	1.33
+++ ChangeLog	27 Nov 2010 22:16:39 -0000	1.34
@@ -1,6 +1,19 @@
 # ChangeLog for app-text/pdftk
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/pdftk/ChangeLog,v 1.33 2010/07/09 09:25:37 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/pdftk/ChangeLog,v 1.34 2010/11/27 22:16:39 xmw Exp $
+
+*pdftk-1.41-r2 (27 Nov 2010)
+
+  27 Nov 2010; Michael Weber <xmw@gentoo.org> +pdftk-1.41-r2.ebuild,
+  +pdftk-1.44.ebuild, +files/pdftk-1.44-LDFLAGS.patch,
+  +files/pdftk-1.44-Makefile.patch:
+  Revision bump to fix gcc:4.5 problems (bug 339345).
+
+*pdftk-1.44 (27 Nov 2010)
+
+  27 Nov 2010; Michael Weber <xmw@gentoo.org> +pdftk-1.44.ebuild,
+  +files/pdftk-1.44-LDFLAGS.patch, +files/pdftk-1.44-Makefile.patch:
+  Version bump, thanks to dabbot for the ebuild/patches on bug 343361.
 
   09 Jul 2010; Samuli Suominen <ssuominen@gentoo.org> pdftk-1.41-r1.ebuild:
   Drop ppc64 wrt #196361, Comment #4



1.1                  app-text/pdftk/pdftk-1.44.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/pdftk/pdftk-1.44.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/pdftk/pdftk-1.44.ebuild?rev=1.1&content-type=text/plain

Index: pdftk-1.44.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/pdftk/pdftk-1.44.ebuild,v 1.1 2010/11/27 22:16:39 xmw Exp $

EAPI="2"

inherit eutils

DESCRIPTION="A tool for manipulating PDF documents"
HOMEPAGE="http://www.pdflabs.com/tools/pdftk-the-pdf-toolkit/"
SRC_URI="http://www.pdflabs.com/tools/pdftk-the-pdf-toolkit/${P}-src.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
DEPEND=">=sys-devel/gcc-4.3.1[gcj]"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${P}-dist/${PN}

src_prepare() {
	epatch "${FILESDIR}/${P}-Makefile.patch"
	epatch "${FILESDIR}/${P}-LDFLAGS.patch"
}

src_compile() {
	# java-config settings break compilation by gcj.
	unset CLASSPATH
	unset JAVA_HOME
	# parallel make fails
	emake -j1 -f "${S}"/Makefile.Debian || die "Compilation failed."
}

src_install() {
	dobin pdftk || die
	doman ../pdftk.1 || die
	dohtml ../pdftk.1.html || die
}



1.1                  app-text/pdftk/pdftk-1.41-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/pdftk/pdftk-1.41-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/pdftk/pdftk-1.41-r2.ebuild?rev=1.1&content-type=text/plain

Index: pdftk-1.41-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/pdftk/pdftk-1.41-r2.ebuild,v 1.1 2010/11/27 22:16:39 xmw Exp $

EAPI="2"

inherit eutils toolchain-funcs

DESCRIPTION="A tool for manipulating PDF documents"
HOMEPAGE="http://www.pdflabs.com/tools/pdftk-the-pdf-toolkit/"
SRC_URI="http://www.pdfhacks.com/pdftk/${P}.tar.gz
	http://aur.archlinux.org/packages/pdftk/pdftk/makefile.patch -> ${P}-makefile.patch"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nodrm"

DEPEND=">=sys-devel/gcc-4.3.1[gcj]"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${P}/${PN}

src_prepare() {
	cd "${WORKDIR}" || die

	#bug #225709 and #251796
	epatch "${FILESDIR}/${P}-gcc-4.3.patch"

	#bug #269312
	epatch "${FILESDIR}/${P}-gcc-4.4.patch"

	#bug #209802
	epatch "${FILESDIR}/${P}-honor-ldflags.patch"

	cd "${S}"/.. || die
	#bug 339345
	epatch "${DISTDIR}/${P}-makefile.patch"

	# force usage of custom CFLAGS.
	sed -iorig 's:-O2:\$(CFLAGS):g' "${S}"/Makefile.Generic
	# nodrm patch, bug 296455
	if use nodrm; then
		sed -i 's:passwordIsOwner= false:passwordIsOwner= true:' "${WORKDIR}/${P}"/java_libs/com/lowagie/text/pdf/PdfReader.java || die
	fi

	sed -e '/^export GCJ=/d' -e '/^export GCJH=/d' \
		-i "${WORKDIR}"/${P}/${PN}/Makefile.Generic || die
}

src_compile() {
	# java-config settings break compilation by gcj.
	unset CLASSPATH
	unset JAVA_HOME

	tc-export GCJ
	export GCJH="${GCJ}"h

	# parallel make fails
	emake -j1 -f Makefile.Generic || die "Compilation failed."
}

src_install() {
	dobin pdftk || die
	newman ../debian/pdftk.1 pdftk.1 || die
	dohtml ../pdftk.1.html || die
}