[gentoo-commits] gentoo-x86 commit in net-analyzer/cacti: ChangeLog cacti-0.8.7g.ebuild cacti-0.8.7e-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-analyzer/cacti: ChangeLog cacti-0.8.7g.ebuild cacti-0.8.7e-r1.ebuild

[Peter Volkov (pva)]

pva         10/11/15 15:38:09

  Modified:             ChangeLog
  Added:                cacti-0.8.7g.ebuild
  Removed:              cacti-0.8.7e-r1.ebuild
  Log:
  Version bump, bug #324457, thank Luca Lesinigo for report and Jens Ott for initial work. Fixes multiple vulnerabilities, security bug #324031, thank Matthias Geerdsen for report. Fixes installation with new php version, bug #343205, thank Bradley Leininger for report.
  
  (Portage version: 2.1.9.24/cvs/Linux x86_64)

Revision  Changes    Path
1.173                net-analyzer/cacti/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/ChangeLog?rev=1.173&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/ChangeLog?rev=1.173&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/ChangeLog?r1=1.172&r2=1.173

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/cacti/ChangeLog,v
retrieving revision 1.172
retrieving revision 1.173
diff -u -r1.172 -r1.173
--- ChangeLog	3 Jul 2010 13:25:29 -0000	1.172
+++ ChangeLog	15 Nov 2010 15:38:09 -0000	1.173
@@ -1,6 +1,15 @@
 # ChangeLog for net-analyzer/cacti
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti/ChangeLog,v 1.172 2010/07/03 13:25:29 mabi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti/ChangeLog,v 1.173 2010/11/15 15:38:09 pva Exp $
+
+*cacti-0.8.7g (15 Nov 2010)
+
+  15 Nov 2010; Peter Volkov <pva@gentoo.org> -cacti-0.8.7e-r1.ebuild,
+  +cacti-0.8.7g.ebuild:
+  Version bump, bug #324457, thank Luca Lesinigo for report and Jens Ott for
+  initial work. Fixes multiple vulnerabilities, security bug #324031, thank
+  Matthias Geerdsen for report. Fixes installation with new php version, bug
+  #343205, thank Bradley Leininger for report.
 
 *cacti-0.8.7e-r3 (03 Jul 2010)
 



1.1                  net-analyzer/cacti/cacti-0.8.7g.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/cacti-0.8.7g.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti/cacti-0.8.7g.ebuild?rev=1.1&content-type=text/plain

Index: cacti-0.8.7g.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti/cacti-0.8.7g.ebuild,v 1.1 2010/11/15 15:38:09 pva Exp $

EAPI="2"

inherit eutils webapp depend.php

# Support for _p* in version.
MY_P=${P/_p*/}
HAS_PATCHES=1

DESCRIPTION="Cacti is a complete frontend to rrdtool"
HOMEPAGE="http://www.cacti.net/"
SRC_URI="http://www.cacti.net/downloads/${MY_P}.tar.gz"

# patches
if [ "${HAS_PATCHES}" == "1" ] ; then
	UPSTREAM_PATCHES="data_source_deactivate
		graph_list_view
		html_output
		ldap_group_authenication
		script_server_command_line_parse
		ping
		poller_interval"
	for i in ${UPSTREAM_PATCHES} ; do
		SRC_URI="${SRC_URI} http://www.cacti.net/downloads/patches/${PV/_p*}/${i}.patch"
	done
fi

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="snmp doc"

DEPEND=""

need_httpd_cgi

RDEPEND="snmp? ( >=net-analyzer/net-snmp-5.1.2 )
	net-analyzer/rrdtool
	dev-php/adodb
	virtual/mysql
	virtual/cron
	dev-lang/php[cli,mysql,xml,session,sockets]
	|| ( <dev-lang/php-5.3[pcre] >=dev-lang/php-5.3 )"

src_unpack() {
	unpack ${MY_P}.tar.gz
	if [ "${HAS_PATCHES}" == "1" ] ; then
		[ ! ${MY_P} == ${P} ] && mv ${MY_P} ${P}
	fi
}

src_prepare() {
	if [ "${HAS_PATCHES}" == "1" ] ; then
		# patches
		for i in ${UPSTREAM_PATCHES} ; do
			EPATCH_OPTS="-p1 -d ${S} -N" epatch "${DISTDIR}"/${i}.patch
		done ;
	fi

	sed -i -e \
		's:$config\["library_path"\] . "/adodb/adodb.inc.php":"adodb/adodb.inc.php":' \
		"${S}"/include/global.php

	rm -rf lib/adodb # don't use bundled adodb
}

src_compile() { :; }

src_install() {
	webapp_src_preinst

	rm LICENSE README
	dodoc docs/{CHANGELOG,CONTRIB,README,txt/manual.txt} || die
	use doc && dohtml -r docs/html/
	rm -rf docs

	edos2unix `find -type f -name '*.php'`

	dodir ${MY_HTDOCSDIR}
	cp -r . "${D}"${MY_HTDOCSDIR}

	webapp_serverowned ${MY_HTDOCSDIR}/rra
	webapp_serverowned ${MY_HTDOCSDIR}/log/cacti.log
	webapp_configfile ${MY_HTDOCSDIR}/include/config.php
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt

	webapp_src_install
}