[gentoo-commits] gentoo-x86 commit in dev-python/sphinx: ChangeLog sphinx-1.0.5.ebuild

["Arfrever Frehtes Taifersar Arahesis (arfrever)" <arfrever@gentoo.org>]

arfrever    10/11/15 14:26:57

  Modified:             ChangeLog
  Added:                sphinx-1.0.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha4_p23/cvs/Linux x86_64)

Revision  Changes    Path
1.76                 dev-python/sphinx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/ChangeLog?r1=1.75&r2=1.76

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog	24 Oct 2010 15:35:56 -0000	1.75
+++ ChangeLog	15 Nov 2010 14:26:57 -0000	1.76
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/sphinx
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.75 2010/10/24 15:35:56 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.76 2010/11/15 14:26:57 arfrever Exp $
+
+*sphinx-1.0.5 (15 Nov 2010)
+
+  15 Nov 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  -sphinx-0.6.5.ebuild, -sphinx-0.6.6.ebuild, -sphinx-1.0.ebuild,
+  -sphinx-1.0.1.ebuild, -sphinx-1.0.3.ebuild, +sphinx-1.0.5.ebuild:
+  Version bump.
 
   24 Oct 2010; Raúl Porcel <armin76@gentoo.org> sphinx-1.0.4.ebuild:
   alpha/arm/ia64/s390/sh/sparc stable wrt #341513



1.1                  dev-python/sphinx/sphinx-1.0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/sphinx-1.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/sphinx-1.0.5.ebuild?rev=1.1&content-type=text/plain

Index: sphinx-1.0.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/sphinx-1.0.5.ebuild,v 1.1 2010/11/15 14:26:57 arfrever Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"
DISTUTILS_SRC_TEST="nosetests"

inherit distutils

MY_PN="Sphinx"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Tool to create documentation for Python projects"
HOMEPAGE="http://sphinx.pocoo.org/ http://pypi.python.org/pypi/Sphinx"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc latex"

RDEPEND=">=dev-python/docutils-0.5
	>=dev-python/jinja-2.2
	>=dev-python/pygments-0.8
	latex? ( dev-texlive/texlive-latexextra )"
DEPEND="${RDEPEND}
	dev-python/setuptools"

S="${WORKDIR}/${MY_P}"

DOCS="CHANGES"

src_compile() {
	distutils_src_compile

	if use doc; then
		pushd doc > /dev/null
		einfo "Generation of documentation"
		PYTHONPATH="../" emake SPHINXBUILD="$(PYTHON -f) ../sphinx-build.py" html || die "Generation of documentation failed"
		popd > /dev/null
	fi
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -A txt -r doc/_build/html/* || die "Installation of documentation failed"
	fi
}

pkg_postinst() {
	distutils_pkg_postinst

	# Generate the Grammar pickle to avoid sandbox violations.
	generation_of_grammar_pickle() {
		"$(PYTHON)" -c "import sys; sys.path.insert(0, '${EROOT}$(python_get_sitedir -b)'); from sphinx.pycode.pgen2.driver import load_grammar; load_grammar('${EROOT}$(python_get_sitedir -b)/sphinx/pycode/Grammar.txt')"
	}
	python_execute_function \
		--action-message 'Generation of Grammar pickle with $(python_get_implementation) $(python_get_version)...' \
		--failure-message 'Generation of Grammar pickle with $(python_get_implementation) $(python_get_version) failed' \
		generation_of_grammar_pickle
}

pkg_postrm() {
	distutils_pkg_postrm

	deletion_of_grammar_pickle() {
		rm -f "${EROOT}$(python_get_sitedir -b)/sphinx/pycode"/Grammar*.pickle || return 1

		# Delete empty parent directories.
		local dir="${EROOT}$(python_get_sitedir -b)/sphinx/pycode"
		while [[ "${dir}" != "${EROOT%/}" ]]; do
			rmdir "${dir}" 2> /dev/null || break
			dir="${dir%/*}"
		done
	}
	python_execute_function \
		--action-message 'Deletion of Grammar pickle with $(python_get_implementation) $(python_get_version)...' \
		--failure-message 'Deletion of Grammar pickle with $(python_get_implementation) $(python_get_version) failed' \
		deletion_of_grammar_pickle
}