[gentoo-commits] gentoo-x86 commit in dev-lang/vala: ChangeLog vala-0.11.2.ebuild

[gentoo-commits] gentoo-x86 commit in dev-lang/vala: ChangeLog vala-0.11.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/11/14 18:27:03

  Modified:             ChangeLog
  Added:                vala-0.11.2.ebuild
  Log:
  Version bump. Improvements to the .gir reader, bug fixes and bindings updates.
  
  (Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

Revision  Changes    Path
1.31                 dev-lang/vala/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/vala/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/vala/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/vala/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/vala/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	27 Oct 2010 20:59:13 -0000	1.30
+++ ChangeLog	14 Nov 2010 18:27:03 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/vala
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/vala/ChangeLog,v 1.30 2010/10/27 20:59:13 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/vala/ChangeLog,v 1.31 2010/11/14 18:27:03 eva Exp $
+
+*vala-0.11.2 (14 Nov 2010)
+
+  14 Nov 2010; Gilles Dartiguelongue <eva@gentoo.org> +vala-0.11.2.ebuild:
+  Version bump. Improvements to the .gir reader, bug fixes and bindings
+  updates.
 
 *vala-0.11.1 (27 Oct 2010)
 



1.1                  dev-lang/vala/vala-0.11.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/vala/vala-0.11.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/vala/vala-0.11.2.ebuild?rev=1.1&content-type=text/plain

Index: vala-0.11.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/vala/vala-0.11.2.ebuild,v 1.1 2010/11/14 18:27:03 eva Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit gnome2

DESCRIPTION="Vala - Compiler for the GObject type system"
HOMEPAGE="http://live.gnome.org/Vala"

LICENSE="LGPL-2.1"
SLOT="0.12"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="test +vapigen coverage"

RDEPEND=">=dev-libs/glib-2.16"
DEPEND="${RDEPEND}
	sys-devel/flex
	|| ( sys-devel/bison dev-util/byacc dev-util/yacc )
	dev-util/pkgconfig
	dev-libs/libxslt
	test? (
		dev-libs/dbus-glib
		>=dev-libs/glib-2.26 )"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-unversioned
		$(use_enable vapigen)
		$(use_enable coverage)"
	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"

	if use coverage && has ccache ${FEATURES}; then
		ewarn "USE=coverage does not work well with ccache; valac and libvala"
		ewarn "built with ccache and USE=coverage create temporary files inside"
		ewarn "CCACHE_DIR and mess with ccache's working, as well as causing"
		ewarn "sandbox violations when used to compile other packages."
		ewarn "It is STRONGLY recommended that you disable one of them."
	fi
}

src_install() {
	gnome2_src_install
	mv "${ED}"/usr/share/aclocal/vala.m4 \
		"${ED}"/usr/share/aclocal/vala-${SLOT/./-}.m4 || die "failed to move vala m4 macro"
	find "${ED}" -name "*.la" -delete || die "la file removal failed"
}