From: "Mike Frysinger (vapier)" <vapier@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in net-fs/nfs-utils: ChangeLog nfs-utils-1.2.3-r1.ebuild
Date: Sun, 14 Nov 2010 00:49:39 +0000 (UTC) [thread overview]
Message-ID: <20101114004939.CBA5220054@flycatcher.gentoo.org> (raw)
vapier 10/11/14 00:49:39
Modified: ChangeLog
Added: nfs-utils-1.2.3-r1.ebuild
Log:
Add fix from upstream for ti-rpc static port bindings #340797 by John J. Aylward.
(Portage version: 2.2.0_alpha4/cvs/Linux x86_64)
Revision Changes Path
1.175 net-fs/nfs-utils/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/ChangeLog?rev=1.175&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/ChangeLog?rev=1.175&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/ChangeLog?r1=1.174&r2=1.175
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v
retrieving revision 1.174
retrieving revision 1.175
diff -u -r1.174 -r1.175
--- ChangeLog 8 Oct 2010 19:48:08 -0000 1.174
+++ ChangeLog 14 Nov 2010 00:49:39 -0000 1.175
@@ -1,6 +1,14 @@
# ChangeLog for net-fs/nfs-utils
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v 1.174 2010/10/08 19:48:08 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v 1.175 2010/11/14 00:49:39 vapier Exp $
+
+*nfs-utils-1.2.3-r1 (14 Nov 2010)
+
+ 14 Nov 2010; Mike Frysinger <vapier@gentoo.org>
+ +nfs-utils-1.2.3-r1.ebuild,
+ +files/nfs-utils-1.2.3-ti-rpc-static-ports.patch:
+ Add fix from upstream for ti-rpc static port bindings #340797 by John J.
+ Aylward.
*nfs-utils-1.2.3 (08 Oct 2010)
1.1 net-fs/nfs-utils/nfs-utils-1.2.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.2.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.2.3-r1.ebuild?rev=1.1&content-type=text/plain
Index: nfs-utils-1.2.3-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.2.3-r1.ebuild,v 1.1 2010/11/14 00:49:39 vapier Exp $
EAPI="2"
inherit eutils flag-o-matic multilib
DESCRIPTION="NFS client and server daemons"
HOMEPAGE="http://linux-nfs.org/"
SRC_URI="mirror://sourceforge/nfs/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="caps ipv6 kerberos +nfsv3 +nfsv4 tcpd elibc_glibc"
RESTRICT="test" #315573
# kth-krb doesn't provide the right include
# files, and nfs-utils doesn't build against heimdal either,
# so don't depend on virtual/krb.
# (04 Feb 2005 agriffis)
DEPEND_COMMON="tcpd? ( sys-apps/tcp-wrappers )
caps? ( sys-libs/libcap )
sys-libs/e2fsprogs-libs
net-nds/rpcbind
net-libs/libtirpc
nfsv4? (
>=dev-libs/libevent-1.0b
>=net-libs/libnfsidmap-0.21-r1
kerberos? (
net-libs/librpcsecgss
net-libs/libgssglue
net-libs/libtirpc[kerberos]
app-crypt/mit-krb5
)
)"
RDEPEND="${DEPEND_COMMON} !net-nds/portmap"
# util-linux dep is to prevent man-page collision
DEPEND="${DEPEND_COMMON}
>=sys-apps/util-linux-2.12r-r7"
src_prepare() {
epatch "${FILESDIR}"/${PN}-1.1.4-mtab-sym.patch
epatch "${FILESDIR}"/${PN}-1.1.4-no-exec.patch
epatch "${FILESDIR}"/${P}-ti-rpc-static-ports.patch #340797
}
src_configure() {
econf \
--with-statedir=/var/lib/nfs \
--enable-tirpc \
$(use_with tcpd tcp-wrappers) \
$(use_enable nfsv3) \
$(use_enable nfsv4) \
$(use_enable ipv6) \
$(use_enable caps) \
$(use nfsv4 && use_enable kerberos gss || echo "--disable-gss")
}
src_install() {
emake DESTDIR="${D}" install || die
# Don't overwrite existing xtab/etab, install the original
# versions somewhere safe... more info in pkg_postinst
keepdir /var/lib/nfs/{,sm,sm.bak}
mv "${D}"/var/lib "${D}"/usr/$(get_libdir) || die
# Install some client-side binaries in /sbin
dodir /sbin
mv "${D}"/usr/sbin/rpc.statd "${D}"/sbin/ || die
dodoc ChangeLog README
docinto linux-nfs ; dodoc linux-nfs/*
insinto /etc
doins "${FILESDIR}"/exports
local f list="" opt_need=""
if use nfsv4 ; then
opt_need="rpc.idmapd"
list="${list} rpc.idmapd rpc.pipefs"
use kerberos && list="${list} rpc.gssd rpc.svcgssd"
fi
for f in nfs nfsmount rpc.statd ${list} ; do
newinitd "${FILESDIR}"/${f}.initd ${f} || die "doinitd ${f}"
done
newconfd "${FILESDIR}"/nfs.confd nfs
dosed "/^NFS_NEEDED_SERVICES=/s:=.*:=\"${opt_need}\":" /etc/conf.d/nfs #234132
# uClibc doesn't provide rpcgen like glibc, so lets steal it from nfs-utils
if ! use elibc_glibc ; then
dobin tools/rpcgen/rpcgen || die "rpcgen"
newdoc tools/rpcgen/README README.rpcgen
fi
}
pkg_postinst() {
# Install default xtab and friends if there's none existing. In
# src_install we put them in /usr/lib/nfs for safe-keeping, but
# the daemons actually use the files in /var/lib/nfs. #30486
local f
for f in "${ROOT}"/usr/$(get_libdir)/nfs/*; do
[[ -e ${ROOT}/var/lib/nfs/${f##*/} ]] && continue
einfo "Copying default ${f##*/} from /usr/$(get_libdir)/nfs to /var/lib/nfs"
cp -pPR "${f}" "${ROOT}"/var/lib/nfs/
done
}
next reply other threads:[~2010-11-14 0:49 UTC|newest]
Thread overview: 7+ messages / expand[flat|nested] mbox.gz Atom feed top
2010-11-14 0:49 Mike Frysinger (vapier) [this message]
-- strict thread matches above, loose matches on Subject: below --
2011-03-13 13:00 [gentoo-commits] gentoo-x86 commit in net-fs/nfs-utils: ChangeLog nfs-utils-1.2.3-r1.ebuild Kacper Kowalik (xarthisius)
2011-03-14 20:08 Markos Chandras (hwoarang)
2011-03-18 8:47 Mike Frysinger (vapier)
2011-03-24 10:40 Thomas Kahle (tomka)
2011-04-24 17:51 Raul Porcel (armin76)
2011-05-29 0:34 Mike Frysinger (vapier)
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20101114004939.CBA5220054@flycatcher.gentoo.org \
--to=vapier@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox