[gentoo-commits] gentoo-x86 commit in dev-ml/ocamlduce: ocamlduce-3.12.0.0.ebuild ChangeLog

["Alexis Ballier (aballier)" <aballier@gentoo.org>]

aballier    10/11/07 17:40:03

  Modified:             ChangeLog
  Added:                ocamlduce-3.12.0.0.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 dev-ml/ocamlduce/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlduce/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlduce/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlduce/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/ocamlduce/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	12 Apr 2010 06:34:53 -0000	1.15
+++ ChangeLog	7 Nov 2010 17:40:03 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ml/ocamlduce
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlduce/ChangeLog,v 1.15 2010/04/12 06:34:53 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlduce/ChangeLog,v 1.16 2010/11/07 17:40:03 aballier Exp $
+
+*ocamlduce-3.12.0.0 (07 Nov 2010)
+
+  07 Nov 2010; Alexis Ballier <aballier@gentoo.org>
+  +ocamlduce-3.12.0.0.ebuild:
+  version bump
 
   12 Apr 2010; Alexis Ballier <aballier@gentoo.org>
   -ocamlduce-3.11.1.0.ebuild:



1.1                  dev-ml/ocamlduce/ocamlduce-3.12.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlduce/ocamlduce-3.12.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlduce/ocamlduce-3.12.0.0.ebuild?rev=1.1&content-type=text/plain

Index: ocamlduce-3.12.0.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlduce/ocamlduce-3.12.0.0.ebuild,v 1.1 2010/11/07 17:40:03 aballier Exp $

EAPI="2"

inherit versionator eutils toolchain-funcs flag-o-matic multilib

OCAML_VERSION=3.12.0
OCAML_TARBALL=ocaml-${OCAML_VERSION}.tar.bz2
OCAML_PATCHLEVEL=2
OCAML_GENTOO_PATCHES=ocaml-patches-${OCAML_PATCHLEVEL}.tar.bz2

DESCRIPTION="OCamlDuce is a merger between OCaml and CDuce"
HOMEPAGE="http://ocamlduce.forge.ocamlcore.org/"
SRC_URI="https://forge.ocamlcore.org/frs/download.php/441/${P}.tar.gz
	ftp://ftp.inria.fr/INRIA/cristal/ocaml/ocaml-$(get_version_component_range 1-2 ${OCAML_VERSION})/${OCAML_TARBALL}
	mirror://gentoo/${OCAML_GENTOO_PATCHES}"

LICENSE="QPL-1.0 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="+ocamlopt"

DEPEND="~dev-lang/ocaml-${OCAML_VERSION}[ocamlopt?]
	>=dev-ml/findlib-1.2.4-r1
	!!<dev-ml/${P}"

RDEPEND="${DEPEND}"

S=${WORKDIR}/${P}/ocaml-${OCAML_VERSION}

src_unpack() {
	unpack ${P}.tar.gz ${OCAML_GENTOO_PATCHES}
}

src_prepare() {
	cd "${WORKDIR}/${P}"
	emake OCAML_SOURCE="${DISTDIR}/${OCAML_TARBALL}" prepare || die "failed to prepare"
	cd "${S}"
	EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
}

src_configure() {
	RAW_LDFLAGS="$(raw-ldflags)" ./configure -prefix /usr \
		--bindir /usr/bin \
		--libdir /usr/$(get_libdir)/ocaml \
		--mandir /usr/share/man \
		-host "${CHOST}" \
		-cc "$(tc-getCC)" \
		-as "$(tc-getAS)" \
		-aspp "$(tc-getCC) -c" \
		--with-pthread || die "configure failed!"
}

src_compile() {
	if use ocamlopt; then
		emake -f Makefile.ocamlduce -j1 world.opt || die
	else
		emake -f Makefile.ocamlduce -j1 world || die
	fi
}

src_install() {
	emake -f Makefile.ocamlduce BINDIR="${D}/usr/bin" LIBDIR="${D}/usr/$(get_libdir)/ocaml" installbyte || die
	if use ocamlopt; then
		emake -f Makefile.ocamlduce BINDIR="${D}/usr/bin" LIBDIR="${D}/usr/$(get_libdir)/ocaml" installopt || die
	fi
	dodoc Changes README
}