* [gentoo-commits] gentoo-x86 commit in app-misc/gpsdrive: ChangeLog gpsdrive-2.11-r1.ebuild gpsdrive-2.11.ebuild
@ 2010-10-30 1:12 Steve Arnold (nerdboy)
0 siblings, 0 replies; only message in thread
From: Steve Arnold (nerdboy) @ 2010-10-30 1:12 UTC (permalink / raw
To: gentoo-commits
nerdboy 10/10/30 01:12:00
Modified: ChangeLog
Added: gpsdrive-2.11-r1.ebuild
Removed: gpsdrive-2.11.ebuild
Log:
Updated with new cmake directive to address bug 341693.
(Portage version: 2.2_rc99/cvs/Linux x86_64)
Revision Changes Path
1.41 app-misc/gpsdrive/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gpsdrive/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gpsdrive/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gpsdrive/ChangeLog?r1=1.40&r2=1.41
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/gpsdrive/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog 18 Oct 2010 09:09:30 -0000 1.40
+++ ChangeLog 30 Oct 2010 01:12:00 -0000 1.41
@@ -1,6 +1,13 @@
# ChangeLog for app-misc/gpsdrive
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/gpsdrive/ChangeLog,v 1.40 2010/10/18 09:09:30 nerdboy Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/gpsdrive/ChangeLog,v 1.41 2010/10/30 01:12:00 nerdboy Exp $
+
+*gpsdrive-2.11-r1 (30 Oct 2010)
+
+ 30 Oct 2010; Steve Arnold <nerdboy@gentoo.org> -gpsdrive-2.11.ebuild,
+ +gpsdrive-2.11-r1.ebuild:
+ Updated with new cmake directive to address bug #341693. Updated deps
+ to latest documented versions.
*gpsdrive-2.11 (18 Oct 2010)
1.1 app-misc/gpsdrive/gpsdrive-2.11-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gpsdrive/gpsdrive-2.11-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gpsdrive/gpsdrive-2.11-r1.ebuild?rev=1.1&content-type=text/plain
Index: gpsdrive-2.11-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/gpsdrive/gpsdrive-2.11-r1.ebuild,v 1.1 2010/10/30 01:12:00 nerdboy Exp $
EAPI=2
inherit cmake-utils eutils fdo-mime versionator
DESCRIPTION="GPS navigation system with NMEA and Garmin support, zoomable map display, waypoints, etc."
HOMEPAGE="http://www.gpsdrive.de/"
SRC_URI="${HOMEPAGE}/packages/${P/_/}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
S=${WORKDIR}/${P/_/}
KEYWORDS="~amd64 ~ppc ~x86"
# submit bug for ppc64
IUSE="dbus -debug -kismet libgda gdal mapnik scripts -speech"
COMMON_DEP=">=sci-geosciences/gpsd-2.94
net-misc/curl
dev-libs/libxml2
dev-db/sqlite:3
x11-libs/gtk+:2
dbus? ( dev-libs/dbus-glib )
gdal? ( sci-libs/gdal )
kismet? ( net-wireless/kismet )
mapnik? ( >=sci-geosciences/mapnik-0.7.0[postgres]
>=dev-db/postgis-1.5.2 )
libgda? ( =gnome-extra/libgda-3.0*[postgres] )
speech? ( >=app-accessibility/speech-dispatcher-0.6.7 )"
DEPEND="${COMMON_DEP}
>=dev-util/cmake-2.8.0
dev-util/pkgconfig"
RDEPEND="${COMMON_DEP}
sci-geosciences/openstreetmap-icons
sci-geosciences/mapnik-world-boundaries
media-fonts/dejavu"
src_prepare() {
# Get rid of the package's FindBoost.
rm "${S}"/cmake/Modules/FindBoost.cmake
# Update mapnik font path...
sed -i \
-e "s:truetype/ttf-dejavu:dejavu:g" \
-e "s:mapnik/0.5:mapnik:g" \
tests/gpsdriverc-in \
src/gpsdrive_config.c || die "sed failed"
# update OSM icon paths
sed -i \
-e "s|icons/map-icons|osm|g" \
cmake/Modules/DefineInstallationPaths.cmake \
scripts/osm/perl_lib/Geo/Gpsdrive/DB_Defaults.pm \
scripts/osm/perl_lib/Geo/Gpsdrive/OSM.pm \
src/icons.c \
|| die "sed failed"
# Fix desktop file...
sed -i -e "s:gpsicon:/usr/share/icons/gpsdrive.png:g" \
-e "s:Graphics;Network;Geography:Education;Science;Geography;GPS:g" \
data/gpsdrive.desktop || die "sed failed"
epatch "${FILESDIR}"/gpsdrive-2.11_DefineOptions_gpsd.patch
}
src_configure() {
cat >> cmake/Modules/DefineProjectDefaults.cmake <<- _EOF_
# set policy for new linker paths
cmake_policy(SET CMP0003 NEW) # or cmake_policy(VERSION 2.6)
_EOF_
local mycmakeargs="${mycmakeargs}
$(cmake-utils_use_with scripts SCRIPTS)
$(cmake-utils_use_with mapnik MAPNIK)
$(cmake-utils_use_with mapnik POSTGIS)
$(cmake-utils_use_with kismet KISMET)
$(cmake-utils_use_with dbus DBUS)
$(cmake-utils_use_with libgda GDA3)
$(cmake-utils_use_with speech SPEECH)
$(cmake-utils_use_with gdal GDAL)"
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
dodoc AUTHORS ChangeLog README \
Documentation/{CREDITS.i18n,FAQ.gpsdrive,FAQ.gpsdrive.fr,LEEME} \
Documentation/{LISEZMOI,NMEA.txt,LISEZMOI.kismet,TODO} \
Documentation/README.{Bluetooth,lib_map,nasamaps,tracks,kismet}
if use mapnik ; then
dodoc Documentation/install-mapnik-osm.txt
else
rm -f "${D}"usr/bin/gpsdrive_mapnik_gentiles.py
rm -f "${D}"usr/share/gpsdrive/osm-template.xml
fi
if use scripts ; then
dodoc Documentation/README.gpspoint2gspdrive
if ! use gdal ; then
rm -f "${D}"usr/bin/{gdal_slice,nasaconv}.sh
fi
else
rm -f "${D}"usr/share/man/man1/gpsd_nmea.sh.1
fi
}
pkg_postinst() {
fdo-mime_desktop_database_update
elog
elog "Be sure to see the README files in /usr/share/doc/${PF}"
elog "for information on using Kismet with gpsdrive."
elog
if use mapnik ; then
elog "Using mapnik to render online maps requires you to load"
elog "data into the postgis database. Follow the instructions"
elog "on http://wiki.openstreetmap.org/index.php/Mapnik"
fi
elog
elog "This version also now depends on the gpsd package, and"
elog "specific devices are supported there. Start gpsd first,"
elog "otherwise gpsdrive will only run in simulation mode (which"
elog "is handy for downloading maps for another location, but"
elog "not much else)."
elog
elog "openstreetmap-icons now installs to a more appropriate"
elog "location, so if you have trouble starting gpsdrive, you"
elog "should probably update your ~/.gpsdrive/gpsdriverc file"
elog "and change the path to the geoinfofile to reflect this:"
elog " geoinfofile = /usr/share/osm/geoinfo.db"
elog
}
pkg_postrm() {
fdo-mime_desktop_database_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-10-30 1:12 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-10-30 1:12 [gentoo-commits] gentoo-x86 commit in app-misc/gpsdrive: ChangeLog gpsdrive-2.11-r1.ebuild gpsdrive-2.11.ebuild Steve Arnold (nerdboy)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox