[gentoo-commits] gentoo-x86 commit in gnome-extra/deskbar-applet: deskbar-applet-2.32.0.ebuild ChangeLog deskbar-applet-2.26.2.ebuild deskbar-applet-2.28.0.ebuild deskbar-applet-2.26.2-r1.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-extra/deskbar-applet: deskbar-applet-2.32.0.ebuild ChangeLog deskbar-applet-2.26.2.ebuild deskbar-applet-2.28.0.ebuild deskbar-applet-2.26.2-r1.ebuild

[Pacho Ramos (pacho)]

pacho       10/10/29 21:29:20

  Modified:             ChangeLog
  Added:                deskbar-applet-2.32.0.ebuild
  Removed:              deskbar-applet-2.26.2.ebuild
                        deskbar-applet-2.28.0.ebuild
                        deskbar-applet-2.26.2-r1.ebuild
  Log:
  Version bump for Gnome 2.32
  
  (Portage version: 2.1.9.23/cvs/Linux x86_64)

Revision  Changes    Path
1.143                gnome-extra/deskbar-applet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog?r1=1.142&r2=1.143

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog	17 Oct 2010 15:42:59 -0000	1.142
+++ ChangeLog	29 Oct 2010 21:29:20 -0000	1.143
@@ -1,6 +1,19 @@
 # ChangeLog for gnome-extra/deskbar-applet
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog,v 1.142 2010/10/17 15:42:59 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog,v 1.143 2010/10/29 21:29:20 pacho Exp $
+
+*deskbar-applet-2.32.0 (29 Oct 2010)
+
+  29 Oct 2010; Pacho Ramos <pacho@gentoo.org>
+  -files/deskbar-applet-2.24.1-multilib.patch,
+  -deskbar-applet-2.26.2.ebuild, -deskbar-applet-2.26.2-r1.ebuild,
+  -files/deskbar-applet-2.26.2-double-label.patch,
+  -deskbar-applet-2.28.0.ebuild, +deskbar-applet-2.32.0.ebuild:
+  Version bump for Gnome 2.32: Use accessor functions so it compiles with
+  -DGSEAL_ENABLE, AccelEntry: Specify UTF-8 encoding at the top of the file,
+  removed gdmclient import and fixed switch user action, translation
+  updates. Make it compile when using python3 as main interpreter. Remove
+  old.
 
   17 Oct 2010; Raúl Porcel <armin76@gentoo.org>
   deskbar-applet-2.30.1.ebuild:



1.1                  gnome-extra/deskbar-applet/deskbar-applet-2.32.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/deskbar-applet/deskbar-applet-2.32.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/deskbar-applet/deskbar-applet-2.32.0.ebuild?rev=1.1&content-type=text/plain

Index: deskbar-applet-2.32.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/deskbar-applet-2.32.0.ebuild,v 1.1 2010/10/29 21:29:20 pacho Exp $

EAPI="3"
GCONF_DEBUG="no"
PYTHON_DEPEND="2:2.4"

inherit eutils gnome2 python

DESCRIPTION="An Omnipresent Versatile Search Interface"
HOMEPAGE="http://projects.gnome.org/deskbar-applet/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="eds spell"

RDEPEND="
	>=x11-libs/gtk+-2.20:2
	>=gnome-base/gnome-desktop-2.10
	>=gnome-base/gconf-2

	>=dev-python/pygtk-2.12
	>=dev-python/pygobject-2.15.3
	>=dev-python/dbus-python-0.80.2

	>=dev-python/gconf-python-2.22.1
	>=dev-python/gnome-applets-python-2.22
	>=dev-python/gnome-desktop-python-2.22
	>=dev-python/gnome-keyring-python-2.22
	>=dev-python/libwnck-python-2.22

	eds? ( >=gnome-extra/evolution-data-server-1.7.92 )
	spell? ( >=gnome-extra/gnome-utils-2.16.2 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.35
	app-text/scrollkeeper
	app-text/gnome-doc-utils
	dev-util/pkgconfig
	app-text/docbook-xml-dtd:4.2"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README TODO"
	G2CONF="${G2CONF}
		$(use_enable eds evolution)
		--exec-prefix=/usr
		--disable-scrollkeeper"
	python_set_active_version 2
}

src_prepare() {
	gnome2_src_prepare

	# disable pyc compiling
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile

	python_convert_shebangs -r 2 .
}

src_compile() {
	# Needed for import gnomedesktop in configure, bug #270524
	addpredict "$(unset HOME; echo ~)/.gnome2"

	gnome2_src_compile
}

src_install() {
	gnome2_src_install
	python_clean_installation_image
	python_convert_shebangs 2 "${ED}"usr/libexec/${PN}/${PN}
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_need_rebuild
	python_mod_optimize deskbar
	python_mod_optimize /usr/libexec/deskbar-applet/deskbar-applet
	python_mod_optimize /usr/libexec/deskbar-applet/modules-2.20-compatible

	if ! has_version gnome-extra/gnome-utils; then
		ewarn "The dictionary plugin in deskbar-applet uses the dictionary from "
		ewarn "gnome-extra/gnome-utils.  If it is not present, the dictionary "
		ewarn "plugin will fail silently."
	fi
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup deskbar
	python_mod_cleanup /usr/libexec/deskbar-applet/modules-2.20-compatible
}