[gentoo-commits] gentoo-x86 commit in app-accessibility/espeak: ChangeLog espeak-1.44.05.ebuild

["William Hubbs (williamh)" <williamh@gentoo.org>]

williamh    10/10/29 18:06:33

  Modified:             ChangeLog
  Added:                espeak-1.44.05.ebuild
  Log:
  version bump, also fixes #303094, thanks to Kacper Kowalik
  
  (Portage version: 2.2.0_alpha2/cvs/Linux i686)

Revision  Changes    Path
1.89                 app-accessibility/espeak/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/ChangeLog?rev=1.89&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/ChangeLog?rev=1.89&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/ChangeLog?r1=1.88&r2=1.89

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-accessibility/espeak/ChangeLog,v
retrieving revision 1.88
retrieving revision 1.89
diff -u -r1.88 -r1.89
--- ChangeLog	20 Jul 2010 18:37:03 -0000	1.88
+++ ChangeLog	29 Oct 2010 18:06:33 -0000	1.89
@@ -1,6 +1,12 @@
 # ChangeLog for app-accessibility/espeak
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/espeak/ChangeLog,v 1.88 2010/07/20 18:37:03 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/espeak/ChangeLog,v 1.89 2010/10/29 18:06:33 williamh Exp $
+
+*espeak-1.44.05 (29 Oct 2010)
+
+  29 Oct 2010; William Hubbs <williamh@gentoo.org> +espeak-1.44.05.ebuild,
+  +files/espeak-1.44.05-respect-ldflags.patch:
+  Version bump, also fixes bug #303094 thanks to Kacper Kowalik.
 
   20 Jul 2010; Jeroen Roovers <jer@gentoo.org> espeak-1.42.04.ebuild:
   Stable for HPPA (bug #301793).



1.1                  app-accessibility/espeak/espeak-1.44.05.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/espeak-1.44.05.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/espeak/espeak-1.44.05.ebuild?rev=1.1&content-type=text/plain

Index: espeak-1.44.05.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-accessibility/espeak/espeak-1.44.05.ebuild,v 1.1 2010/10/29 18:06:33 williamh Exp $

EAPI="3"

inherit eutils toolchain-funcs

MY_P="${P}-source"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.zip"
DESCRIPTION="Speech synthesizer for English and other languages"
HOMEPAGE="http://espeak.sourceforge.net/"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="portaudio pulseaudio"
RDEPEND="portaudio? ( >=media-libs/portaudio-19_pre20071207 )
	pulseaudio? ( media-sound/pulseaudio )"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/${MY_P}

get_audio() {
	local MY_AUDIO

	if use portaudio; then
		MY_AUDIO=portaudio
	elif use pulseaudio; then
		MY_AUDIO=pulseaudio
	else
		MY_AUDIO=none
	fi
	echo ${MY_AUDIO}
}

pkg_setup() {
	if use portaudio && use pulseaudio; then
		die "You must choose either portaudio or pulseaudio, but not both."
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-respect-ldflags.patch
	cd src
	# gentoo uses portaudio 19.
	if use portaudio; then
		mv -f portaudio19.h portaudio.h
	fi
}

src_compile() {
	cd src
	emake PREFIX="${EPREFIX}/usr" AUDIO="$(get_audio)" \
	CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS}" all || die "Compilation failed"

	einfo "Fixing byte order of phoneme data files"
	cd "${S}/platforms/big_endian"
	make
	./espeak-phoneme-data "${S}/espeak-data"
	cp -f phondata phonindex phontab "${S}/espeak-data"
}

src_install() {
	cd src
	make DESTDIR="${D}" PREFIX="${EPREFIX}/usr" LIBDIR="\$(PREFIX)/$(get_libdir)" AUDIO="$(get_audio)" install || die "Installation failed"

	cd ..
	insinto /usr/share/espeak-data
	doins -r dictsource
	dodoc ChangeLog ReadMe
	dohtml -r docs/*
}

pkg_postinst() {
	if ! use portaudio && ! use pulseaudio; then
		ewarn "Since portaudio and pulseaudio are not in your use flags,"
		ewarn "espeak will only be able to create wav files."
		ewarn "If this is not what you want, please reemerge ${CATEGORY}/${PN}"
		ewarn "with either portaudio or pulseaudio USE flag enabled."
	fi
}