[gentoo-commits] gentoo-x86 commit in app-arch/tar: ChangeLog tar-1.24-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-arch/tar: ChangeLog tar-1.24-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/10/27 18:19:39

  Modified:             ChangeLog
  Added:                tar-1.24-r1.ebuild
  Log:
  Fix -C switch wrt #342735 by "ferret". Fix --transform switch wrt #342785.
  
  (Portage version: 2.2.0_alpha1/cvs/Linux x86_64)

Revision  Changes    Path
1.157                app-arch/tar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/ChangeLog?rev=1.157&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/ChangeLog?rev=1.157&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/ChangeLog?r1=1.156&r2=1.157

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v
retrieving revision 1.156
retrieving revision 1.157
diff -u -r1.156 -r1.157
--- ChangeLog	26 Oct 2010 06:31:44 -0000	1.156
+++ ChangeLog	27 Oct 2010 18:19:39 -0000	1.157
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/tar
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v 1.156 2010/10/26 06:31:44 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/ChangeLog,v 1.157 2010/10/27 18:19:39 ssuominen Exp $
+
+*tar-1.24-r1 (27 Oct 2010)
+
+  27 Oct 2010; Samuli Suominen <ssuominen@gentoo.org> +tar-1.24-r1.ebuild,
+  +files/tar-1.24-mkdirat.patch, +files/tar-1.24-transform.patch,
+  +files/tar-1.24-transform-2.patch:
+  Fix -C switch wrt #342735 by "ferret". Fix --transform switch wrt #342785.
 
   26 Oct 2010; Samuli Suominen <ssuominen@gentoo.org> tar-1.24.ebuild:
   Fix ./configure with FEATURES="-userpriv" wrt #342593.



1.1                  app-arch/tar/tar-1.24-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/tar-1.24-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/tar/tar-1.24-r1.ebuild?rev=1.1&content-type=text/plain

Index: tar-1.24-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/tar/tar-1.24-r1.ebuild,v 1.1 2010/10/27 18:19:39 ssuominen Exp $

EAPI="2"

inherit flag-o-matic eutils

DESCRIPTION="Use this to make tarballs :)"
HOMEPAGE="http://www.gnu.org/software/tar/"
SRC_URI="http://ftp.gnu.org/gnu/tar/${P}.tar.bz2
	ftp://alpha.gnu.org/gnu/tar/${P}.tar.bz2
	mirror://gnu/tar/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls static userland_GNU"

RDEPEND=""
DEPEND="${RDEPEND}
	nls? ( >=sys-devel/gettext-0.10.35 )"

RESTRICT="test" # Remove this from 1.25

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.23-strncpy.patch #317139
	epatch "${FILESDIR}"/${P}-mkdirat.patch #342735
	epatch "${FILESDIR}"/${P}-transform{,-2}.patch #342785

	if ! use userland_GNU ; then
		sed -i \
			-e 's:/backup\.sh:/gbackup.sh:' \
			scripts/{backup,dump-remind,restore}.in \
			|| die "sed non-GNU"
	fi
}

src_configure() {
	local myconf
	use static && append-ldflags -static
	use userland_GNU || myconf="--program-prefix=g"
	# Work around bug in sandbox #67051
	gl_cv_func_chown_follows_symlink=yes \
	FORCE_UNSAFE_CONFIGURE=1 \
	econf \
		--enable-backup-scripts \
		--bindir=/bin \
		--libexecdir=/usr/sbin \
		$(use_enable nls) \
		${myconf}
}

src_install() {
	local p=""
	use userland_GNU || p=g

	emake DESTDIR="${D}" install || die

	if [[ -z ${p} ]] ; then
		# a nasty yet required piece of baggage
		exeinto /etc
		doexe "${FILESDIR}"/rmt || die
	fi

	dodoc AUTHORS ChangeLog* NEWS README* THANKS
	newman "${FILESDIR}"/tar.1 ${p}tar.1
	mv "${D}"/usr/sbin/${p}backup{,-tar}
	mv "${D}"/usr/sbin/${p}restore{,-tar}

	rm -f "${D}"/usr/$(get_libdir)/charset.alias
}