[gentoo-commits] gentoo-x86 commit in dev-util/devhelp: ChangeLog devhelp-2.32.0.ebuild devhelp-2.28.1.ebuild devhelp-0.23-r1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/devhelp: ChangeLog devhelp-2.32.0.ebuild devhelp-2.28.1.ebuild devhelp-0.23-r1.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/10/22 20:44:40

  Modified:             ChangeLog
  Added:                devhelp-2.32.0.ebuild
  Removed:              devhelp-2.28.1.ebuild devhelp-0.23-r1.ebuild
  Log:
  Version bump. Clean up old revisions.
  
  (Portage version: 2.2_rc89/cvs/Linux x86_64)

Revision  Changes    Path
1.117                dev-util/devhelp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/ChangeLog?rev=1.117&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/ChangeLog?rev=1.117&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/ChangeLog?r1=1.116&r2=1.117

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v
retrieving revision 1.116
retrieving revision 1.117
diff -u -r1.116 -r1.117
--- ChangeLog	17 Oct 2010 16:24:42 -0000	1.116
+++ ChangeLog	22 Oct 2010 20:44:40 -0000	1.117
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/devhelp
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v 1.116 2010/10/17 16:24:42 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v 1.117 2010/10/22 20:44:40 eva Exp $
+
+*devhelp-2.32.0 (22 Oct 2010)
+
+  22 Oct 2010; Gilles Dartiguelongue <eva@gentoo.org>
+  -devhelp-0.23-r1.ebuild, -devhelp-2.28.1.ebuild, +devhelp-2.32.0.ebuild,
+  +files/devhelp-2.32.0-fix-schema.patch:
+  Version bump. Clean up old revisions.
 
   17 Oct 2010; Raúl Porcel <armin76@gentoo.org> devhelp-2.30.1.ebuild:
   sparc stable wrt #324077



1.1                  dev-util/devhelp/devhelp-2.32.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/devhelp-2.32.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/devhelp-2.32.0.ebuild?rev=1.1&content-type=text/plain

Index: devhelp-2.32.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/devhelp-2.32.0.ebuild,v 1.1 2010/10/22 20:44:40 eva Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit eutils gnome2 python toolchain-funcs

DESCRIPTION="An API documentation browser for GNOME 2"
HOMEPAGE="http://live.gnome.org/devhelp"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE=""

RDEPEND=">=gnome-base/gconf-2.6
	>=x11-libs/gtk+-2.10:2
	>=dev-libs/glib-2.10:2
	>=x11-libs/libwnck-2.10
	>=net-libs/webkit-gtk-1.1.13
	>=dev-libs/libunique-1"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.40
	>=dev-util/pkgconfig-0.9"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README"
	# ICC is crazy, silence warnings (bug #154010)
	if [[ $(tc-getCC) == "icc" ]] ; then
		G2CONF="${G2CONF} --with-compile-warnings=no"
	fi
	python_set_active_version 2
}

src_prepare() {
	gnome2_src_prepare

	# disable pyc compiling
	rm py-compile
	ln -s $(type -P true) py-compile

	# Fix build with older libunique, bug #286890
	sed -e 's/-DG.*_SINGLE_INCLUDES//' \
		-e 's/-DG.*_DEPRECATED//' \
		-i src/Makefile.am src/Makefile.in || die "sed 2 failed"

	# Fix gconf schema
	epatch "${FILESDIR}/${PN}-2.32.0-fix-schema.patch"
}

src_install() {
	gnome2_src_install
	# Internal library, punt .la file
	find "${ED}" -name "*.la" -delete || die "remove of la files failed"
}

pkg_preinst() {
	gnome2_pkg_preinst
	preserve_old_lib /usr/$(get_libdir)/libdevhelp-1.so.1
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_need_rebuild
	python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins/devhelp
	preserve_old_lib_notify /usr/$(get_libdir)/libdevhelp-1.so.1
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins/devhelp
}