* [gentoo-commits] gentoo-x86 commit in media-libs/raptor: metadata.xml ChangeLog raptor-1.4.21-r1.ebuild raptor-1.9.0.ebuild
@ 2010-10-15 18:15 Samuli Suominen (ssuominen)
0 siblings, 0 replies; only message in thread
From: Samuli Suominen (ssuominen) @ 2010-10-15 18:15 UTC (permalink / raw
To: gentoo-commits
ssuominen 10/10/15 18:15:30
Modified: metadata.xml ChangeLog
Added: raptor-1.4.21-r1.ebuild raptor-1.9.0.ebuild
Log:
Version bump. Remove rapper (with it's manpage) from 1.4.21 for slotting.
(Portage version: 2.2_rc96/cvs/Linux x86_64)
Revision Changes Path
1.3 media-libs/raptor/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/metadata.xml?r1=1.2&r2=1.3
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/raptor/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml 19 Apr 2005 08:18:10 -0000 1.2
+++ metadata.xml 15 Oct 2010 18:15:29 -0000 1.3
@@ -1,5 +1,8 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
-<herd>sound</herd>
+ <herd>sound</herd>
+ <use>
+ <flag name="json">Enable support for JSON parsing</flag>
+ </use>
</pkgmetadata>
1.85 media-libs/raptor/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/ChangeLog?r1=1.84&r2=1.85
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog 23 Aug 2010 19:11:25 -0000 1.84
+++ ChangeLog 15 Oct 2010 18:15:29 -0000 1.85
@@ -1,6 +1,13 @@
# ChangeLog for media-libs/raptor
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.84 2010/08/23 19:11:25 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.85 2010/10/15 18:15:29 ssuominen Exp $
+
+*raptor-1.9.0 (15 Oct 2010)
+*raptor-1.4.21-r1 (15 Oct 2010)
+
+ 15 Oct 2010; Samuli Suominen <ssuominen@gentoo.org>
+ +raptor-1.4.21-r1.ebuild, +raptor-1.9.0.ebuild:
+ Version bump. Remove rapper (with it's manpage) from 1.4.21 for slotting.
23 Aug 2010; Samuli Suominen <ssuominen@gentoo.org> raptor-1.4.21.ebuild:
Punt .la files and fix HTML documentation directory.
1.1 media-libs/raptor/raptor-1.4.21-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/raptor-1.4.21-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/raptor-1.4.21-r1.ebuild?rev=1.1&content-type=text/plain
Index: raptor-1.4.21-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/raptor-1.4.21-r1.ebuild,v 1.1 2010/10/15 18:15:29 ssuominen Exp $
EAPI=3
inherit eutils libtool
DESCRIPTION="The RDF Parser Toolkit"
HOMEPAGE="http://librdf.org/raptor"
SRC_URI="http://download.librdf.org/source/${P}.tar.gz"
LICENSE="LGPL-2.1 Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="+curl debug static-libs unicode +xml"
RDEPEND="unicode? ( dev-libs/glib:2 )
xml? ( >=dev-libs/libxml2-2.6.8 )
!xml? ( dev-libs/expat )
curl? ( net-misc/curl )
dev-libs/libxslt"
DEPEND="${RDEPEND}
sys-devel/flex
dev-util/pkgconfig"
src_prepare() {
epunt_cxx
elibtoolize # Required by FreeBSD .so versioning
}
src_configure() {
local myconf
if use xml; then
myconf+=" --with-xml-parser=libxml"
else
myconf+=" --with-xml-parser=expat"
fi
if use curl; then
myconf+=" --with-www=curl"
elif use xml; then
myconf+=" --with-www=xml"
else
myconf+=" --with-www=none"
fi
econf \
--disable-dependency-tracking \
$(use_enable static-libs static) \
$(use_enable unicode nfc-check) \
$(use_enable debug) \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
${myconf}
}
src_install() {
emake DESTDIR="${D}" install || die
dodoc AUTHORS ChangeLog NEWS NOTICE README
dohtml NEWS.html README.html RELEASE.html
find "${ED}" -name '*.la' -exec rm -f '{}' +
# Fix file collision with SLOT="2"
rm -f "${D}"/usr/bin/rapper "${D}"/usr/share/man/man1/rapper.1*
}
1.1 media-libs/raptor/raptor-1.9.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/raptor-1.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/raptor/raptor-1.9.0.ebuild?rev=1.1&content-type=text/plain
Index: raptor-1.9.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/raptor-1.9.0.ebuild,v 1.1 2010/10/15 18:15:29 ssuominen Exp $
EAPI=3
inherit eutils libtool
MY_P=${PN}2-${PV}
DESCRIPTION="The RDF Parser Toolkit"
HOMEPAGE="http://librdf.org/raptor"
SRC_URI="http://download.librdf.org/source/${MY_P}.tar.gz"
LICENSE="LGPL-2.1 Apache-2.0"
SLOT="2"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="+curl debug json static-libs unicode +xml"
RDEPEND="unicode? ( dev-libs/glib:2 )
xml? ( >=dev-libs/libxml2-2.6.8 )
!xml? ( dev-libs/expat )
curl? ( net-misc/curl )
json? ( dev-libs/yajl )
dev-libs/libxslt"
DEPEND="${RDEPEND}
sys-devel/flex
dev-util/pkgconfig"
S=${WORKDIR}/${MY_P}
src_prepare() {
epunt_cxx
elibtoolize # for FreeBSD
}
src_configure() {
local myconf
if use xml; then
myconf+=" --with-xml-parser=libxml"
else
myconf+=" --with-xml-parser=expat"
fi
if use curl; then
myconf+=" --with-www=curl"
elif use xml; then
myconf+=" --with-www=xml"
else
myconf+=" --with-www=none"
fi
econf \
--disable-dependency-tracking \
$(use_enable static-libs static) \
$(use_enable unicode nfc-check) \
$(use_enable debug) \
$(use_with json yajl) \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
${myconf}
}
src_install() {
emake DESTDIR="${D}" install || die
dodoc AUTHORS ChangeLog NEWS NOTICE README
dohtml {NEWS,README,RELEASE,UPGRADING}.html
find "${ED}" -name '*.la' -exec rm -f '{}' +
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-10-15 18:15 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-10-15 18:15 [gentoo-commits] gentoo-x86 commit in media-libs/raptor: metadata.xml ChangeLog raptor-1.4.21-r1.ebuild raptor-1.9.0.ebuild Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox