[gentoo-commits] gentoo-x86 commit in sci-chemistry/tinker: ChangeLog tinker-5.1.09.ebuild tinker-5.1.08.ebuild

[gentoo-commits] gentoo-x86 commit in sci-chemistry/tinker: ChangeLog tinker-5.1.09.ebuild tinker-5.1.08.ebuild

[Justin Lecher (jlec)]

jlec        10/10/03 10:49:16

  Modified:             ChangeLog
  Added:                tinker-5.1.09.ebuild
  Removed:              tinker-5.1.08.ebuild
  Log:
  Version bump, fixes 335197 & 337074
  
  (Portage version: 2.2_rc88/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 sci-chemistry/tinker/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/tinker/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/tinker/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/tinker/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/tinker/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	3 Oct 2010 08:31:34 -0000	1.24
+++ ChangeLog	3 Oct 2010 10:49:15 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for sci-chemistry/tinker
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/tinker/ChangeLog,v 1.24 2010/10/03 08:31:34 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/tinker/ChangeLog,v 1.25 2010/10/03 10:49:15 jlec Exp $
+
+*tinker-5.1.09 (03 Oct 2010)
+
+  03 Oct 2010; Justin Lecher <jlec@gentoo.org> +files/5.1.09-Makefile.patch,
+  -tinker-5.1.08.ebuild, +tinker-5.1.09.ebuild:
+  Version bump, fixes 335197 & 337074
 
   03 Oct 2010; Justin Lecher <jlec@gentoo.org> tinker-5.1.08.ebuild,
   tinker-6.0.ebuild:



1.1                  sci-chemistry/tinker/tinker-5.1.09.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/tinker/tinker-5.1.09.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/tinker/tinker-5.1.09.ebuild?rev=1.1&content-type=text/plain

Index: tinker-5.1.09.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/tinker/tinker-5.1.09.ebuild,v 1.1 2010/10/03 10:49:16 jlec Exp $

EAPI="2"
FORTRAN="gfortran ifc"

inherit eutils fortran java-pkg-opt-2 toolchain-funcs

DESCRIPTION="Molecular modeling package that includes force fields, such as AMBER and CHARMM"
HOMEPAGE="http://dasher.wustl.edu/tinker/"
SRC_URI="http://dasher.wustl.edu/${PN}/downloads/${P}.tar.gz"

SLOT="0"
LICENSE="Tinker"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="examples"

DEPEND=">=virtual/jdk-1.6"
RDEPEND="
	dev-libs/maloc
	!dev-util/diffuse
	>=sci-chemistry/apbs-1.2.1b-r4[tinker]
	>=virtual/jre-1.6"
RESTRICT="mirror"

S="${WORKDIR}"/tinker/source

pkg_setup() {
	fortran_pkg_setup
	java-pkg-opt-2_pkg_setup
}

src_prepare() {
	cd ..
	epatch "${FILESDIR}"/${PV}-Makefile.patch
}

src_compile() {
	local javalib=
	for i in $(java-config -g LDPATH | sed 's|:| |g'); do
		[[ -f ${i}/libjvm.so ]] && javalib=${i}
	done
	emake -e \
		-f ../make/Makefile \
		F77="${FORTRANC}" \
		CC="$(tc-getCC) -c" \
		F77FLAGS=-c \
		OPTFLAGS="${FFLAGS}" \
		LINKFLAGS="${LDFLAGS} -Wl,-rpath ${javalib}" \
		INCLUDEDIR="$(java-pkg_get-jni-cflags) -I${EPREFIX}/usr/include" \
		LIBS="$(pkg-config --libs apbs) -lmaloc -L${javalib} -ljvm" \
		all || die
	mkdir "${S}"/../bin || die

	emake \
		-f ../make/Makefile \
		BINDIR="${S}"/../bin \
		rename || die
}

src_test() {
	cd "${WORKDIR}"/tinker/test/
	for test in *.run; do
		einfo "Testing ${test} ..."
		bash ${test} || die
	done
}

src_install() {
	dobin "${WORKDIR}"/${PN}/perl/mdavg "${WORKDIR}"/${PN}/bin/* || die

	insinto /usr/share/${PN}/
	doins -r "${WORKDIR}"/${PN}/params || die

	dodoc \
		"${WORKDIR}"/${PN}/doc/{*.txt,announce/release-*,*.pdf,0README} || die

	if use examples; then
		insinto /usr/share/${P}
		doins -r "${WORKDIR}"/${PN}/example || die

		doins -r "${WORKDIR}"/${PN}/test || die
	fi

}