* [gentoo-commits] gentoo-x86 commit in www-client/chromium: metadata.xml ChangeLog chromium-9999.ebuild chromium-7.0.536.2.ebuild chromium-7.0.517.13.ebuild chromium-6.0.472.59.ebuild chromium-6.0.472.63-r1.ebuild chromium-6.0.472.62-r1.ebuild
@ 2010-10-01 8:34 PaweA Hajdan (phajdan.jr)
0 siblings, 0 replies; only message in thread
From: PaweA Hajdan (phajdan.jr) @ 2010-10-01 8:34 UTC (permalink / raw
To: gentoo-commits
phajdan.jr 10/10/01 08:34:59
Modified: metadata.xml ChangeLog chromium-9999.ebuild
Added: chromium-7.0.536.2.ebuild
Removed: chromium-7.0.517.13.ebuild
chromium-6.0.472.59.ebuild
chromium-6.0.472.63-r1.ebuild
chromium-6.0.472.62-r1.ebuild
Log:
Version bump for dev channel release. Add an option to build with system-provided sqlite library. Re-enable tcmalloc support. Minor ebuild cleanups. Remove old versions.
(Portage version: 2.1.8.3/cvs/Linux i686)
Revision Changes Path
1.9 www-client/chromium/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/metadata.xml?r1=1.8&r2=1.9
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml 20 Sep 2010 16:21:23 -0000 1.8
+++ metadata.xml 1 Oct 2010 08:34:59 -0000 1.9
@@ -3,4 +3,8 @@
<pkgmetadata>
<herd>chromium</herd>
<longdescription>Chromium is the open-source web browser project behind Google Chrome</longdescription>
+ <use>
+ <flag name="system-sqlite">Use the system-wide <pkg>dev-db/sqlite</pkg>
+ installation with secure-delete enabled</flag>
+ </use>
</pkgmetadata>
1.192 www-client/chromium/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.192&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.192&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.191&r2=1.192
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.191
retrieving revision 1.192
diff -u -r1.191 -r1.192
--- ChangeLog 29 Sep 2010 09:54:08 -0000 1.191
+++ ChangeLog 1 Oct 2010 08:34:59 -0000 1.192
@@ -1,6 +1,17 @@
# ChangeLog for www-client/chromium
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.191 2010/09/29 09:54:08 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.192 2010/10/01 08:34:59 phajdan.jr Exp $
+
+*chromium-7.0.536.2 (01 Oct 2010)
+
+ 01 Oct 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+ +files/chromium-system-sqlite-r0.patch, -chromium-6.0.472.59.ebuild,
+ -chromium-6.0.472.62-r1.ebuild, -chromium-6.0.472.63-r1.ebuild,
+ -chromium-7.0.517.13.ebuild, +chromium-7.0.536.2.ebuild,
+ chromium-9999.ebuild, metadata.xml:
+ Version bump for dev channel release. Add an option to build with
+ system-provided sqlite library. Re-enable tcmalloc support. Minor ebuild
+ cleanups. Remove old versions.
*chromium-7.0.517.24 (29 Sep 2010)
1.87 www-client/chromium/chromium-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.86&r2=1.87
Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- chromium-9999.ebuild 23 Sep 2010 12:31:25 -0000 1.86
+++ chromium-9999.ebuild 1 Oct 2010 08:34:59 -0000 1.87
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.86 2010/09/23 12:31:25 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.87 2010/10/01 08:34:59 phajdan.jr Exp $
EAPI="2"
@@ -15,9 +15,10 @@
LICENSE="BSD"
SLOT="0"
KEYWORDS=""
-IUSE="cups gnome gnome-keyring"
+IUSE="cups gnome gnome-keyring system-sqlite"
RDEPEND="app-arch/bzip2
+ system-sqlite? ( >=dev-db/sqlite-3.6.23.1[fts3,secure-delete] )
>=dev-libs/icu-4.4.1
>=dev-libs/libevent-1.4.13
dev-libs/libxml2
@@ -109,6 +110,10 @@
# Add Gentoo plugin paths.
epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch
+ # Small fixes to the system-provided sqlite support,
+ # to be upstreamed.
+ epatch "${FILESDIR}"/${PN}-system-sqlite-r0.patch
+
remove_bundled_lib "third_party/bzip2"
remove_bundled_lib "third_party/codesighs"
remove_bundled_lib "third_party/cros"
@@ -128,6 +133,11 @@
remove_bundled_lib "third_party/tlslite"
# TODO: also remove third_party/zlib. For now the compilation fails if we
# remove it (minizip-related).
+
+ if use system-sqlite; then
+ remove_bundled_lib "third_party/sqlite/src"
+ remove_bundled_lib "third_party/sqlite/preprocessed"
+ fi
}
src_configure() {
@@ -139,7 +149,6 @@
# Use system-provided libraries.
# TODO: use_system_ffmpeg (http://crbug.com/50678).
- # TODO: use_system_sqlite (http://crbug.com/22208).
# TODO: use_system_hunspell (upstream changes needed).
# TODO: use_system_ssl when we have a recent enough system NSS.
myconf+="
@@ -151,6 +160,10 @@
-Duse_system_libxml=1
-Duse_system_zlib=1"
+ if use system-sqlite; then
+ myconf+=" -Duse_system_sqlite=1"
+ fi
+
# The dependency on cups is optional, see bug #324105.
if use cups; then
myconf+=" -Duse_cups=1"
@@ -175,10 +188,6 @@
# and the performance gain isn't worth it.
myconf+=" -Dv8_use_snapshot=0"
- # Disable tcmalloc memory allocator. It causes problems,
- # for example bug #320419.
- myconf+=" -Dlinux_use_tcmalloc=0"
-
# Use target arch detection logic from bug #296917.
local myarch="$ABI"
[[ $myarch = "" ]] && myarch="$ARCH"
@@ -211,16 +220,11 @@
# the build to fail because of that.
myconf+=" -Dwerror="
- build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die
+ build/gyp_chromium --depth=. ${myconf} || die
}
src_compile() {
- emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
- CC="$(tc-getCC)" \
- CXX="$(tc-getCXX)" \
- AR="$(tc-getAR)" \
- RANLIB="$(tc-getRANLIB)" \
- || die
+ emake chrome chrome_sandbox BUILDTYPE=Release V=1 || die
}
src_install() {
1.1 www-client/chromium/chromium-7.0.536.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.536.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.536.2.ebuild?rev=1.1&content-type=text/plain
Index: chromium-7.0.536.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.536.2.ebuild,v 1.1 2010/10/01 08:34:59 phajdan.jr Exp $
EAPI="2"
inherit eutils flag-o-matic multilib pax-utils toolchain-funcs
DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="cups gnome gnome-keyring system-sqlite"
RDEPEND="app-arch/bzip2
system-sqlite? ( >=dev-db/sqlite-3.6.23.1[fts3,secure-delete] )
>=dev-libs/icu-4.4.1
>=dev-libs/libevent-1.4.13
dev-libs/libxml2
dev-libs/libxslt
>=dev-libs/nss-3.12.3
>=gnome-base/gconf-2.24.0
gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
>=media-libs/alsa-lib-1.0.19
media-libs/jpeg:0
media-libs/libpng
cups? ( >=net-print/cups-1.4.4 )
sys-libs/zlib
>=x11-libs/gtk+-2.14.7
x11-libs/libXScrnSaver"
DEPEND="${RDEPEND}
dev-lang/perl
>=dev-util/gperf-3.0.3
>=dev-util/pkgconfig-0.23
sys-devel/flex"
RDEPEND+="
|| (
x11-themes/gnome-icon-theme
x11-themes/oxygen-molecule
x11-themes/tango-icon-theme
x11-themes/xfce4-icon-theme
)
x11-apps/xmessage
x11-misc/xdg-utils
virtual/ttf-fonts"
remove_bundled_lib() {
einfo "Removing bundled library $1 ..."
local out
out="$(find $1 -mindepth 1 \! -iname '*.gyp' -print -delete)" \
|| die "failed to remove bundled library $1"
if [[ -z $out ]]; then
die "no files matched when removing bundled library $1"
fi
}
pkg_setup() {
CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
}
src_prepare() {
# Add Gentoo plugin paths.
epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch
# Small fixes to the system-provided sqlite support,
# to be upstreamed.
epatch "${FILESDIR}"/${PN}-system-sqlite-r0.patch
remove_bundled_lib "third_party/bzip2"
remove_bundled_lib "third_party/codesighs"
remove_bundled_lib "third_party/cros"
remove_bundled_lib "third_party/icu"
remove_bundled_lib "third_party/jemalloc"
remove_bundled_lib "third_party/lcov"
remove_bundled_lib "third_party/libevent"
remove_bundled_lib "third_party/libjpeg"
remove_bundled_lib "third_party/libpng"
remove_bundled_lib "third_party/libxml"
remove_bundled_lib "third_party/libxslt"
remove_bundled_lib "third_party/lzma_sdk"
remove_bundled_lib "third_party/molokocacao"
remove_bundled_lib "third_party/ocmock"
remove_bundled_lib "third_party/pyftpdlib"
remove_bundled_lib "third_party/simplejson"
remove_bundled_lib "third_party/tlslite"
# TODO: also remove third_party/zlib. For now the compilation fails if we
# remove it (minizip-related).
if use system-sqlite; then
remove_bundled_lib "third_party/sqlite/src"
remove_bundled_lib "third_party/sqlite/preprocessed"
fi
}
src_configure() {
local myconf=""
# Never tell the build system to "enable" SSE2, it has a few unexpected
# additions, bug #336871.
myconf+=" -Ddisable_sse2=1"
# Use system-provided libraries.
# TODO: use_system_ffmpeg (http://crbug.com/50678).
# TODO: use_system_hunspell (upstream changes needed).
# TODO: use_system_ssl when we have a recent enough system NSS.
myconf+="
-Duse_system_bzip2=1
-Duse_system_icu=1
-Duse_system_libevent=1
-Duse_system_libjpeg=1
-Duse_system_libpng=1
-Duse_system_libxml=1
-Duse_system_zlib=1"
if use system-sqlite; then
myconf+=" -Duse_system_sqlite=1"
fi
# The dependency on cups is optional, see bug #324105.
if use cups; then
myconf+=" -Duse_cups=1"
else
myconf+=" -Duse_cups=0"
fi
if use "gnome-keyring"; then
myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
else
# TODO: we should also disable code trying to dlopen
# gnome-keyring in that case.
myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
fi
# Enable sandbox.
myconf+="
-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
# and the performance gain isn't worth it.
myconf+=" -Dv8_use_snapshot=0"
# Use target arch detection logic from bug #296917.
local myarch="$ABI"
[[ $myarch = "" ]] && myarch="$ARCH"
if [[ $myarch = amd64 ]] ; then
myconf+=" -Dtarget_arch=x64"
elif [[ $myarch = x86 ]] ; then
myconf+=" -Dtarget_arch=ia32"
elif [[ $myarch = arm ]] ; then
# TODO: check this again after
# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
append-flags -fno-tree-sink
myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
else
die "Failed to determine target arch, got '$myarch'."
fi
if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
myconf+=" -Dno_strict_aliasing=1 -Dgcc_version=44"
fi
# Work around a likely GCC bug, see bug #331945.
if [[ "$(gcc-major-version)$(gcc-minor-version)" == "45" ]]; then
append-flags -fno-ipa-cp
fi
# Make sure that -Werror doesn't get added to CFLAGS by the build system.
# Depending on GCC version the warnings are different and we don't want
# the build to fail because of that.
myconf+=" -Dwerror="
build/gyp_chromium --depth=. ${myconf} || die
}
src_compile() {
emake chrome chrome_sandbox BUILDTYPE=Release V=1 || die
}
src_install() {
exeinto "${CHROMIUM_HOME}"
pax-mark m out/Release/chrome
doexe out/Release/chrome
doexe out/Release/chrome_sandbox || die
fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
doexe out/Release/xdg-settings || die
doexe "${FILESDIR}"/chromium-launcher.sh || die
insinto "${CHROMIUM_HOME}"
doins out/Release/chrome.pak || die
doins out/Release/resources.pak || die
doins -r out/Release/locales || die
doins -r out/Release/resources || die
# chrome.1 is for chromium --help
newman out/Release/chrome.1 chrome.1 || die
newman out/Release/chrome.1 chromium.1 || die
doexe out/Release/ffmpegsumo_nolink || die
doexe out/Release/libffmpegsumo.so || die
# Install icon and desktop entry.
newicon out/Release/product_logo_48.png ${PN}-browser.png || die
dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
"MimeType=text/html;text/xml;application/xhtml+xml;"
sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die
# Install GNOME default application entry (bug #303100).
if use gnome; then
dodir /usr/share/gnome-control-center/default-apps || die
insinto /usr/share/gnome-control-center/default-apps
doins "${FILESDIR}"/chromium.xml || die
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-10-01 8:35 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-10-01 8:34 [gentoo-commits] gentoo-x86 commit in www-client/chromium: metadata.xml ChangeLog chromium-9999.ebuild chromium-7.0.536.2.ebuild chromium-7.0.517.13.ebuild chromium-6.0.472.59.ebuild chromium-6.0.472.63-r1.ebuild chromium-6.0.472.62-r1.ebuild PaweA Hajdan (phajdan.jr)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox