[gentoo-commits] gentoo-x86 commit in media-radio/xastir: ChangeLog xastir-1.9.8-r1.ebuild

[gentoo-commits] gentoo-x86 commit in media-radio/xastir: ChangeLog xastir-1.9.8-r1.ebuild

[Thomas Beierlein (tomjbe)]

tomjbe      10/09/24 17:52:16

  Modified:             ChangeLog
  Added:                xastir-1.9.8-r1.ebuild
  Log:
  Fix for bug #337365 (Thanks Diego for reporting) and fix installdir for doc files
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.14                 media-radio/xastir/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-radio/xastir/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	17 Jul 2010 09:41:43 -0000	1.13
+++ ChangeLog	24 Sep 2010 17:52:16 -0000	1.14
@@ -1,6 +1,13 @@
 # ChangeLog for media-radio/xastir
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-radio/xastir/ChangeLog,v 1.13 2010/07/17 09:41:43 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-radio/xastir/ChangeLog,v 1.14 2010/09/24 17:52:16 tomjbe Exp $
+
+*xastir-1.9.8-r1 (24 Sep 2010)
+
+  24 Sep 2010; Thomas Beierlein <tomjbe@gentoo.org> +xastir-1.9.8-r1.ebuild,
+  +files/xastir-1.9.8-fortify.diff:
+  Fix for bug #337365 (Thanks Diego for reporting) and fix installdir for
+  doc files
 
   17 Jul 2010; Christian Faulhammer <fauli@gentoo.org> xastir-1.9.8.ebuild:
   stable x86, bug 328067



1.1                  media-radio/xastir/xastir-1.9.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/xastir-1.9.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/xastir/xastir-1.9.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: xastir-1.9.8-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-radio/xastir/xastir-1.9.8-r1.ebuild,v 1.1 2010/09/24 17:52:16 tomjbe Exp $

EAPI=2
inherit autotools eutils multilib

DESCRIPTION="X Amateur Station Tracking and Information Reporting"
HOMEPAGE="http://xastir.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="festival gdal geotiff imagemagick"

DEPEND="x11-libs/openmotif
	x11-libs/libXpm
	x11-apps/xfontsel
	dev-libs/libpcre
	net-misc/curl
	sys-libs/db
	sci-libs/shapelib
	geotiff? ( sci-libs/proj
		sci-libs/libgeotiff
		media-libs/tiff )
	gdal? ( sci-libs/gdal )
	imagemagick? ( media-gfx/imagemagick )
	festival? ( app-accessibility/festival )"
RDEPEND="${DEPEND}"

src_prepare() {
	# fix hardcoded /usr/local paths in scripts
	epatch "${FILESDIR}"/${P}-scripts.diff
	# and patch libdir
	for f in scripts/permutations.pl scripts/test_coord.pl \
		scripts/toporama250k.pl scripts/toporama50k.pl; do
		sed -i -e "s:/usr/lib:/usr/$(get_libdir):g" "${f}" \
			|| die "sed failed on ${f}"
	done

	# fix __FORTIFY_SOURCE warning (bug #337365)
	epatch 	"${FILESDIR}"/${P}-fortify.diff

	# fix for DESTDIR
	epatch 	"${FILESDIR}"/${P}-Destdir.diff

	eautoreconf
}

src_configure() {
	econf --without-graphicsmagick \
		--with-pcre \
		--with-shapelib \
		--with-dbfawk \
		--without-ax25 \
		--without-gpsman \
		$(use_with geotiff libproj) \
		$(use_with geotiff) \
		$(use_with gdal) \
		$(use_with imagemagick) \
		$(use_with festival)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	rm -rf "${D}"/usr/share/doc/${PN}
	dodoc AUTHORS ChangeLog FAQ README README.Contributing \
		README.Getting-Started README.MAPS || die "dodoc failed"
}

pkg_postinst() {
	elog "Kernel mode AX.25 and GPSman library not supported."
	elog
	elog "Remember you have to be root to add addditional scripts,"
	elog "maps and other configuration data under /usr/share/xastir"
	elog "and /usr/$(get_libdir)/xastir."
}