[gentoo-commits] gentoo-x86 commit in net-misc/rabbitmq-server: ChangeLog rabbitmq-server-2.1.0.ebuild rabbitmq-server-1.8.0.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/rabbitmq-server: ChangeLog rabbitmq-server-2.1.0.ebuild rabbitmq-server-1.8.0.ebuild

[Benedikt Boehm (hollow)]

hollow      10/09/19 08:35:51

  Modified:             ChangeLog
  Added:                rabbitmq-server-2.1.0.ebuild
  Removed:              rabbitmq-server-1.8.0.ebuild
  Log:
  version bump wrt #337597; remove old ebuild
  
  (Portage version: 2.2_rc83/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  net-misc/rabbitmq-server/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rabbitmq-server/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rabbitmq-server/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rabbitmq-server/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rabbitmq-server/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	29 Aug 2010 17:36:35 -0000	1.8
+++ ChangeLog	19 Sep 2010 08:35:51 -0000	1.9
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/rabbitmq-server
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rabbitmq-server/ChangeLog,v 1.8 2010/08/29 17:36:35 hollow Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rabbitmq-server/ChangeLog,v 1.9 2010/09/19 08:35:51 hollow Exp $
+
+*rabbitmq-server-2.1.0 (19 Sep 2010)
+
+  19 Sep 2010; Benedikt Böhm <hollow@gentoo.org>
+  -rabbitmq-server-1.8.0.ebuild, +rabbitmq-server-2.1.0.ebuild:
+  version bump wrt #337597; remove old ebuild
 
   29 Aug 2010; Benedikt Böhm <hollow@gentoo.org>
   rabbitmq-server-2.0.0.ebuild:



1.1                  net-misc/rabbitmq-server/rabbitmq-server-2.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rabbitmq-server/rabbitmq-server-2.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rabbitmq-server/rabbitmq-server-2.1.0.ebuild?rev=1.1&content-type=text/plain

Index: rabbitmq-server-2.1.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rabbitmq-server/rabbitmq-server-2.1.0.ebuild,v 1.1 2010/09/19 08:35:51 hollow Exp $

EAPI="2"

inherit eutils

DESCRIPTION="RabbitMQ is a high-performance AMQP-compliant message broker written in Erlang."
HOMEPAGE="http://www.rabbitmq.com/"
SRC_URI="http://www.rabbitmq.com/releases/rabbitmq-server/v${PV}/rabbitmq-server-${PV}.tar.gz"

LICENSE="MPL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="dev-lang/erlang"
DEPEND="${RDEPEND}
	app-text/docbook-xml-dtd:4.5
	app-text/xmlto
	dev-libs/libxslt
	dev-python/simplejson
"

pkg_setup() {
	enewgroup rabbitmq
	enewuser rabbitmq -1 -1 /var/lib/rabbitmq rabbitmq
}

src_compile() {
	emake all docs_all || die "emake all failed"
	gunzip docs/*.gz
}

src_install() {
	# erlang module
	local targetdir="/usr/$(get_libdir)/erlang/lib/${P}"

	einfo "Setting correct RABBITMQ_HOME in scripts"
	sed -e "s:^RABBITMQ_HOME=.*:RABBITMQ_HOME=\"${targetdir}\":g" \
		-i scripts/rabbitmq-env

	einfo "Installing Erlang modules to ${targetdir}"
	insinto "${targetdir}"
	doins -r ebin include

	einfo "Installing server scripts to /usr/sbin"
	for script in rabbitmq-env rabbitmq-server rabbitmqctl rabbitmq-multi; do
		exeinto /usr/libexec/rabbitmq
		doexe scripts/${script}
		newsbin "${FILESDIR}"/rabbitmq-script-wrapper ${script}
	done

	# create the directory where our log file will go.
	diropts -m 0770 -o rabbitmq -g rabbitmq
	keepdir /var/log/rabbitmq

	# create the mnesia directory
	diropts -m 0770 -o rabbitmq -g rabbitmq
	dodir /var/lib/rabbitmq{,/mnesia}

	# install the init script
	newinitd "${FILESDIR}"/rabbitmq-server.init-r1 rabbitmq

	# install documentation
	doman docs/*.[15]
	dodoc README
}

pkg_preinst() {
	if has_version "<=net-misc/rabbitmq-server-1.8.0"; then
		elog "IMPORTANT UPGRADE NOTICE:"
		elog
		elog "RabbitMQ is now running as an unprivileged user instead of root."
		elog "Therefore you need to fix the permissions for RabbitMQs Mnesia database."
		elog "Please run the following commands as root:"
		elog
		elog "  usermod -d /var/lib/rabbitmq rabbitmq"
		elog "  chown rabbitmq:rabbitmq -R /var/lib/rabbitmq"
		elog
	fi
}