[gentoo-commits] gentoo-x86 commit in media-radio/unixcw: unixcw-2.3-r6.ebuild ChangeLog metadata.xml

[gentoo-commits] gentoo-x86 commit in media-radio/unixcw: unixcw-2.3-r6.ebuild ChangeLog metadata.xml

[Thomas Beierlein (tomjbe)]

tomjbe      10/09/12 10:07:30

  Added:                unixcw-2.3-r6.ebuild ChangeLog metadata.xml
  Log:
  Initial portage version, moved from sunrise. Bug #220027
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  media-radio/unixcw/unixcw-2.3-r6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/unixcw-2.3-r6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/unixcw-2.3-r6.ebuild?rev=1.1&content-type=text/plain

Index: unixcw-2.3-r6.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-radio/unixcw/unixcw-2.3-r6.ebuild,v 1.1 2010/09/12 10:07:30 tomjbe Exp $

EAPI=2

inherit autotools eutils multilib

DESCRIPTION="A package of programs that fit together to form a morse code tutor program."
HOMEPAGE="http://radio.linux.org.au/?sectpat=morse"
SRC_URI="ftp://metalab.unc.edu/pub/Linux/apps/ham/morse/${P}.tgz
	qt4? (	mirror://gentoo/unixcw-2.3-qt3to4.patch.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ncurses suid qt4"

RDEPEND="ncurses? ( sys-libs/ncurses )
	qt4? ( x11-libs/qt-gui:4[qt3support] )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${P}-destdir.patch \
		"${FILESDIR}"/${P}-config.patch \
		"${FILESDIR}"/${P}-parallel-make.patch \
		"${FILESDIR}"/${P}--as-needed.patch \
		"${FILESDIR}"/${P}-ldflags.patch \
		"${FILESDIR}"/${P}-fPIC.patch \
		"${FILESDIR}"/${P}-audio.patch \
		"${FILESDIR}"/${P}-gcc43.patch
	if use qt4 ; then
		epatch "${DISTDIR}"/${P}-qt3to4.patch.gz
	fi
	eautoreconf
}

src_configure() {
	econf --libdir=/usr/$(get_libdir) \
		$(use_enable ncurses) \
		$(use_enable qt4)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README || die "dodoc failed"
	if ! use suid ; then
		fperms 711 /usr/bin/cw || die "fperms failed"
		if use ncurses ; then
			fperms 711 /usr/bin/cwcp || die "fperms failed"
		fi
		if use qt4 ; then
			fperms 711 /usr/bin/xcwcp || die "fperms failed"
		fi
	fi
}

pkg_postinst() {
	if use suid ; then
		ewarn "You have choosen to install 'cw', 'cwcp' and 'xcwcp' setuid"
		ewarn "by setting USE=suid."
		ewarn "Be aware that this is a security risk and not recommended."
		ewarn ""
		ewarn "These files do only need root access if you want to use the"
		ewarn "PC speaker for morse sidetone output. You can alternativly"
		ewarn "drop USE=suid and use sudo."
	else
		elog "Be aware that 'cw', 'cwcp' and 'xcwcp' needs root access if"
		elog "you want to use the PC speaker for morse sidetone output."
		elog "You can call the programs via sudo for that (see 'man sudo')."
	fi
}



1.1                  media-radio/unixcw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-radio/unixcw
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-radio/unixcw/ChangeLog,v 1.1 2010/09/12 10:07:30 tomjbe Exp $

*unixcw-2.3-r6 (12 Sep 2010)

  12 Sep 2010; Thomas Beierlein <tomjbe@gentoo.org> +unixcw-2.3-r6.ebuild,
  +files/unixcw-2.3--as-needed.patch, +files/unixcw-2.3-audio.patch,
  +files/unixcw-2.3-config.patch, +files/unixcw-2.3-destdir.patch,
  +files/unixcw-2.3-fPIC.patch, +files/unixcw-2.3-gcc43.patch,
  +files/unixcw-2.3-ldflags.patch, +files/unixcw-2.3-parallel-make.patch,
  +metadata.xml:
  Initial portage version, moved from sunrise. Bug #220027




1.1                  media-radio/unixcw/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-radio/unixcw/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>no-herd</herd>
	<maintainer>
		<email>tomjbe@gentoo.org</email>
		<name>Thomas Beierlein</name>
	</maintainer>
	<longdescription>unixcw is package of libraries and programs that fit
		together to form a morse code tutor program. It provides the general
		purpose 'libcw' library with functions to generate Morse code
		characters and a frontend program 'cw' to convert text strings to 
		morse code output via soundcard or console speaker. It further provides
		a set of Morse Code tutor programs (see USE flag description).
	</longdescription>
	<use>
		<flag name='ncurses'>Enables building the curses based morse code tutor
			program 'cwcp'.</flag>
	</use>
</pkgmetadata>