[gentoo-commits] gentoo-x86 commit in dev-lang/yap: ChangeLog yap-6.0.6.ebuild

[gentoo-commits] gentoo-x86 commit in dev-lang/yap: ChangeLog yap-6.0.6.ebuild

[Keri Harris (keri)]

keri        10/09/12 06:43:40

  Modified:             ChangeLog
  Added:                yap-6.0.6.ebuild
  Log:
  Version bump
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.40                 dev-lang/yap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/yap/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/yap/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/yap/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	12 Sep 2010 02:31:41 -0000	1.39
+++ ChangeLog	12 Sep 2010 06:43:40 -0000	1.40
@@ -1,6 +1,14 @@
 # ChangeLog for dev-lang/yap
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v 1.39 2010/09/12 02:31:41 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/ChangeLog,v 1.40 2010/09/12 06:43:40 keri Exp $
+
+*yap-6.0.6 (12 Sep 2010)
+
+  12 Sep 2010; <keri@gentoo.org> +yap-6.0.6.ebuild,
+  +files/yap-6.0.6-DESTDIR.patch, +files/yap-6.0.6-chr-sublist.patch,
+  +files/yap-6.0.6-itries.patch, +files/yap-6.0.6-ldflags.patch,
+  +files/yap-6.0.6-runpath.patch, +files/yap-6.0.6-yapsharedir.patch:
+  Version bump
 
 *yap-6.0.5-r1 (12 Sep 2010)
 



1.1                  dev-lang/yap/yap-6.0.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/yap/yap-6.0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/yap/yap-6.0.6.ebuild?rev=1.1&content-type=text/plain

Index: yap-6.0.6.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/yap/yap-6.0.6.ebuild,v 1.1 2010/09/12 06:43:40 keri Exp $

inherit eutils java-pkg-opt-2

DESCRIPTION="YAP is a high-performance Prolog compiler."
HOMEPAGE="http://www.ncc.up.pt/~vsc/Yap/"
SRC_URI="http://www.ncc.up.pt/~vsc/Yap/${P}.tar.gz"

LICENSE="Artistic LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug doc examples gmp java mpi mysql odbc readline static tk threads"

DEPEND="sys-libs/zlib
	gmp? ( dev-libs/gmp )
	java? ( >=virtual/jdk-1.4 )
	mpi? ( virtual/mpi )
	mysql? ( virtual/mysql )
	odbc? ( dev-db/unixODBC )
	readline? ( sys-libs/readline )
	doc? ( app-text/texi2html )"

RDEPEND="${DEPEND}
	tk? ( dev-lang/tk )"

S="${WORKDIR}"/${PN}-6

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${P}-yapsharedir.patch
	epatch "${FILESDIR}"/${P}-ldflags.patch
	epatch "${FILESDIR}"/${P}-runpath.patch
	epatch "${FILESDIR}"/${P}-chr-sublist.patch
	epatch "${FILESDIR}"/${P}-itries.patch
	epatch "${FILESDIR}"/${P}-DESTDIR.patch
}

src_compile() {
	local myddas_conf
	if use mysql || use odbc; then
		myddas_conf="--enable-myddas \
				--enable-myddas-stats \
				--enable-myddas-top-level"
	else
		myddas_conf="--disable-myddas"
	fi

	econf \
		--libdir=/usr/$(get_libdir) \
		$(use_enable !static dynamic-loading) \
		$(use_enable threads) \
		$(use_enable threads pthread-locking) \
		$(use_enable debug debug-yap) \
		$(use_enable debug low-level-tracer) \
		$(use_with gmp) \
		$(use_with readline) \
		$(use_with mpi) \
		$(use_with mpi mpe) \
		$(use_with java) \
		${myddas_conf} \
		|| die "econf failed"

	emake || die "emake failed"

	if use doc ; then
		emake html || die "emake html failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" -j1 install || die "make install failed."

	if use tk ; then
		exeinto /usr/bin
		doexe misc/tkyap
	fi

	dodoc changes*.html README

	if use doc ; then
		dodoc yap.html
	fi

	if use examples ; then
		docinto examples/chr
		dodoc packages/chr/Examples/*.{chr,pl}
		docinto examples/plunit
		dodoc packages/plunit/examples/*.pl
		if use java ; then
			docinto examples/jpl/prolog
			dodoc packages/jpl/examples/prolog/*.pl
			docinto examples/jpl/java
			dodoc packages/jpl/examples/java/*/*.java
		fi
		if use mpi ; then
			docinto examples/mpi
			dodoc library/mpi/examples/*.pl
		fi
	fi
}