public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-9999.ebuild chromium-7.0.503.1-r1.ebuild
@ 2010-09-07 17:19 PaweA Hajdan (phajdan.jr)
  0 siblings, 0 replies; 2+ messages in thread
From: PaweA Hajdan (phajdan.jr) @ 2010-09-07 17:19 UTC (permalink / raw
  To: gentoo-commits

phajdan.jr    10/09/07 17:19:25

  Modified:             ChangeLog chromium-9999.ebuild
  Added:                chromium-7.0.503.1-r1.ebuild
  Log:
  Fix dependencies, bug #332411 by Patrizio Bassi <hetfield666@gmail.com> and comment by Yuri Arabadji <yuri@deepunix.net>.
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.171                www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.171&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.171&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.170&r2=1.171

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.170
retrieving revision 1.171
diff -u -r1.170 -r1.171
--- ChangeLog	4 Sep 2010 01:52:33 -0000	1.170
+++ ChangeLog	7 Sep 2010 17:19:25 -0000	1.171
@@ -1,6 +1,14 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.170 2010/09/04 01:52:33 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.171 2010/09/07 17:19:25 phajdan.jr Exp $
+
+*chromium-7.0.503.1-r1 (07 Sep 2010)
+
+  07 Sep 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  +files/chromium-gnome-keyring-r0.patch, +chromium-7.0.503.1-r1.ebuild,
+  chromium-9999.ebuild:
+  Fix dependencies, bug #332411 by Patrizio Bassi <hetfield666@gmail.com>
+  and comment by Yuri Arabadji <yuri@deepunix.net>.
 
 *chromium-6.0.472.53-r1 (04 Sep 2010)
 



1.81                 www-client/chromium/chromium-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.80&r2=1.81

Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.80
retrieving revision 1.81
diff -u -r1.80 -r1.81
--- chromium-9999.ebuild	28 Aug 2010 18:10:20 -0000	1.80
+++ chromium-9999.ebuild	7 Sep 2010 17:19:25 -0000	1.81
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.80 2010/08/28 18:10:20 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.81 2010/09/07 17:19:25 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -34,8 +34,8 @@
 	dev-lang/perl
 	>=dev-util/gperf-3.0.3
 	>=dev-util/pkgconfig-0.23
-	>=gnome-base/gnome-keyring-2.28.2
-	sys-devel/flex"
+	sys-devel/flex
+	virtual/perl-version"
 RDEPEND+="
 	|| (
 		x11-themes/gnome-icon-theme
@@ -108,6 +108,9 @@
 	# Add Gentoo plugin paths.
 	epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch
 
+	# Make compile-time dependency on gnome-keyring optional, bug #332411.
+	epatch "${FILESDIR}"/${PN}-gnome-keyring-r0.patch
+
 	remove_bundled_lib "third_party/bzip2"
 	remove_bundled_lib "third_party/codesighs"
 	remove_bundled_lib "third_party/cros"
@@ -161,11 +164,11 @@
 	fi
 
 	if use "gnome-keyring"; then
-		myconf="${myconf} -Dlinux_link_gnome_keyring=1"
+		myconf="${myconf} -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
 	else
 		# TODO: we should also disable code trying to dlopen
 		# gnome-keyring in that case.
-		myconf="${myconf} -Dlinux_link_gnome_keyring=0"
+		myconf="${myconf} -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
 	fi
 
 	# Enable sandbox.



1.1                  www-client/chromium/chromium-7.0.503.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: chromium-7.0.503.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild,v 1.1 2010/09/07 17:19:25 phajdan.jr Exp $

EAPI="2"

inherit eutils flag-o-matic multilib pax-utils toolchain-funcs

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="cups gnome gnome-keyring sse2"

RDEPEND="app-arch/bzip2
	>=dev-libs/icu-4.4.1
	>=dev-libs/libevent-1.4.13
	>=dev-libs/nss-3.12.3
	>=gnome-base/gconf-2.24.0
	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
	>=media-libs/alsa-lib-1.0.19
	media-libs/jpeg:0
	media-libs/libpng
	cups? ( >=net-print/cups-1.4.4 )
	sys-libs/zlib
	>=x11-libs/gtk+-2.14.7
	x11-libs/libXScrnSaver"
DEPEND="${RDEPEND}
	dev-lang/perl
	>=dev-util/gperf-3.0.3
	>=dev-util/pkgconfig-0.23
	sys-devel/flex
	virtual/perl-version"
RDEPEND+="
	|| (
		x11-themes/gnome-icon-theme
		x11-themes/oxygen-molecule
		x11-themes/tango-icon-theme
		x11-themes/xfce4-icon-theme
	)
	x11-apps/xmessage
	x11-misc/xdg-utils
	virtual/ttf-fonts"

get_chromium_home() {
	echo "/usr/$(get_libdir)/chromium-browser"
}

remove_bundled_lib() {
	einfo "Removing bundled library $1 ..."
	local out
	out="$(find $1 -mindepth 1 \! -iname '*.gyp' -print -delete)" \
		|| die "failed to remove bundled library $1"
	if [[ -z $out ]]; then
		die "no files matched when removing bundled library $1"
	fi
}

src_prepare() {
	# Add Gentoo plugin paths.
	epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch

	# Make compile-time dependency on gnome-keyring optional, bug #332411.
	epatch "${FILESDIR}"/${PN}-gnome-keyring-r0.patch

	remove_bundled_lib "third_party/bzip2"
	remove_bundled_lib "third_party/codesighs"
	remove_bundled_lib "third_party/cros"
	remove_bundled_lib "third_party/icu"
	remove_bundled_lib "third_party/jemalloc"
	remove_bundled_lib "third_party/lcov"
	remove_bundled_lib "third_party/libevent"
	remove_bundled_lib "third_party/libjpeg"
	remove_bundled_lib "third_party/libpng"
	remove_bundled_lib "third_party/lzma_sdk"
	remove_bundled_lib "third_party/molokocacao"
	remove_bundled_lib "third_party/ocmock"
	remove_bundled_lib "third_party/pyftpdlib"
	remove_bundled_lib "third_party/simplejson"
	remove_bundled_lib "third_party/tlslite"
	# TODO: also remove third_party/libxml and third_party/libxslt when
	# http://crbug.com/29333 is fixed.
	# TODO: also remove third_party/zlib. For now the compilation fails if we
	# remove it (minizip-related).
}

src_configure() {
	local myconf=""

	# Make it possible to build chromium on non-sse2 systems.
	if use sse2; then
		myconf="${myconf} -Ddisable_sse2=0"
	else
		myconf="${myconf} -Ddisable_sse2=1"
	fi

	# Use system-provided libraries.
	# TODO: use_system_ffmpeg (http://crbug.com/50678).
	# TODO: use_system_libxml (http://crbug.com/29333).
	# TODO: use_system_sqlite (http://crbug.com/22208).
	# TODO: use_system_hunspell (upstream changes needed).
	# TODO: use_system_ssl when we have a recent enough system NSS.
	myconf="${myconf}
		-Duse_system_bzip2=1
		-Duse_system_icu=1
		-Duse_system_libevent=1
		-Duse_system_libjpeg=1
		-Duse_system_libpng=1
		-Duse_system_zlib=1"

	# The dependency on cups is optional, see bug #324105.
	if use cups; then
		myconf="${myconf} -Duse_cups=1"
	else
		myconf="${myconf} -Duse_cups=0"
	fi

	if use "gnome-keyring"; then
		myconf="${myconf} -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
	else
		# TODO: we should also disable code trying to dlopen
		# gnome-keyring in that case.
		myconf="${myconf} -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
	fi

	# Enable sandbox.
	myconf="${myconf}
		-Dlinux_sandbox_path=$(get_chromium_home)/chrome_sandbox
		-Dlinux_sandbox_chrome_path=$(get_chromium_home)/chrome"

	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
	# and the performance gain isn't worth it.
	myconf="${myconf} -Dv8_use_snapshot=0"

	# Disable tcmalloc memory allocator. It causes problems,
	# for example bug #320419.
	myconf="${myconf} -Dlinux_use_tcmalloc=0"

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch = amd64 ]] ; then
		myconf="${myconf} -Dtarget_arch=x64"
	elif [[ $myarch = x86 ]] ; then
		myconf="${myconf} -Dtarget_arch=ia32"
	elif [[ $myarch = arm ]] ; then
		# TODO: check this again after
		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
		append-flags -fno-tree-sink

		myconf="${myconf} -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi

	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
		myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
	fi

	# Work around a likely GCC bug, see bug #331945.
	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "45" ]]; then
		append-flags -fno-ipa-cp
	fi

	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
	# Depending on GCC version the warnings are different and we don't want
	# the build to fail because of that.
	myconf="${myconf} -Dwerror="

	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
}

src_compile() {
	emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
		CC="$(tc-getCC)" \
		CXX="$(tc-getCXX)" \
		AR="$(tc-getAR)" \
		RANLIB="$(tc-getRANLIB)" \
		|| die "compilation failed"
}

src_install() {
	dodir "$(get_chromium_home)"

	exeinto "$(get_chromium_home)"
	pax-mark m out/Release/chrome
	doexe out/Release/chrome
	doexe out/Release/chrome_sandbox
	fperms 4755 "$(get_chromium_home)/chrome_sandbox"
	doexe out/Release/xdg-settings
	doexe "${FILESDIR}"/chromium-launcher.sh

	insinto "$(get_chromium_home)"
	doins out/Release/chrome.pak || die "installing chrome.pak failed"
	doins out/Release/resources.pak || die "installing resources.pak failed"

	doins -r out/Release/locales
	doins -r out/Release/resources

	# chrome.1 is for chromium --help
	newman out/Release/chrome.1 chrome.1
	newman out/Release/chrome.1 chromium.1

	doexe out/Release/ffmpegsumo_nolink || die
	doexe out/Release/libffmpegsumo.so || die

	# Install icon and desktop entry.
	newicon out/Release/product_logo_48.png ${PN}-browser.png
	dosym "$(get_chromium_home)/chromium-launcher.sh" /usr/bin/chromium
	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
		"MimeType=text/html;text/xml;application/xhtml+xml;"
	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
		|| die "desktop file sed failed"

	# Install GNOME default application entry (bug #303100).
	if use gnome; then
		dodir /usr/share/gnome-control-center/default-apps
		insinto /usr/share/gnome-control-center/default-apps
		doins "${FILESDIR}"/chromium.xml
	fi
}






^ permalink raw reply	[flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-9999.ebuild chromium-7.0.503.1-r1.ebuild
@ 2010-09-11 16:10 PaweA Hajdan (phajdan.jr)
  0 siblings, 0 replies; 2+ messages in thread
From: PaweA Hajdan (phajdan.jr) @ 2010-09-11 16:10 UTC (permalink / raw
  To: gentoo-commits

phajdan.jr    10/09/11 16:10:20

  Modified:             ChangeLog chromium-9999.ebuild
                        chromium-7.0.503.1-r1.ebuild
  Log:
  Apply most cleanup changes from bug #333513 by scarabeus.
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.173                www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.173&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.173&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.172&r2=1.173

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.172
retrieving revision 1.173
diff -u -r1.172 -r1.173
--- ChangeLog	8 Sep 2010 00:36:18 -0000	1.172
+++ ChangeLog	11 Sep 2010 16:10:20 -0000	1.173
@@ -1,6 +1,10 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.172 2010/09/08 00:36:18 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.173 2010/09/11 16:10:20 phajdan.jr Exp $
+
+  11 Sep 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  chromium-7.0.503.1-r1.ebuild, chromium-9999.ebuild:
+  Apply most cleanup changes from bug #333513 by scarabeus.
 
 *chromium-6.0.472.55 (08 Sep 2010)
 



1.82                 www-client/chromium/chromium-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.81&r2=1.82

Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- chromium-9999.ebuild	7 Sep 2010 17:19:25 -0000	1.81
+++ chromium-9999.ebuild	11 Sep 2010 16:10:20 -0000	1.82
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.81 2010/09/07 17:19:25 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.82 2010/09/11 16:10:20 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -34,8 +34,7 @@
 	dev-lang/perl
 	>=dev-util/gperf-3.0.3
 	>=dev-util/pkgconfig-0.23
-	sys-devel/flex
-	virtual/perl-version"
+	sys-devel/flex"
 RDEPEND+="
 	|| (
 		x11-themes/gnome-icon-theme
@@ -90,10 +89,6 @@
 	elog "Installing/updating to version ${MAJOR}.${MINOR}.${BUILD}.${PATCH}_p${CREV} "
 }
 
-get_chromium_home() {
-	echo "/usr/$(get_libdir)/chromium-browser"
-}
-
 remove_bundled_lib() {
 	einfo "Removing bundled library $1 ..."
 	local out
@@ -104,6 +99,10 @@
 	fi
 }
 
+pkg_setup() {
+	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
+}
+
 src_prepare() {
 	# Add Gentoo plugin paths.
 	epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch
@@ -137,9 +136,9 @@
 
 	# Make it possible to build chromium on non-sse2 systems.
 	if use sse2; then
-		myconf="${myconf} -Ddisable_sse2=0"
+		myconf+=" -Ddisable_sse2=0"
 	else
-		myconf="${myconf} -Ddisable_sse2=1"
+		myconf+=" -Ddisable_sse2=1"
 	fi
 
 	# Use system-provided libraries.
@@ -148,7 +147,7 @@
 	# TODO: use_system_sqlite (http://crbug.com/22208).
 	# TODO: use_system_hunspell (upstream changes needed).
 	# TODO: use_system_ssl when we have a recent enough system NSS.
-	myconf="${myconf}
+	myconf+="
 		-Duse_system_bzip2=1
 		-Duse_system_icu=1
 		-Duse_system_libevent=1
@@ -158,52 +157,52 @@
 
 	# The dependency on cups is optional, see bug #324105.
 	if use cups; then
-		myconf="${myconf} -Duse_cups=1"
+		myconf+=" -Duse_cups=1"
 	else
-		myconf="${myconf} -Duse_cups=0"
+		myconf+=" -Duse_cups=0"
 	fi
 
 	if use "gnome-keyring"; then
-		myconf="${myconf} -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
+		myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
 	else
 		# TODO: we should also disable code trying to dlopen
 		# gnome-keyring in that case.
-		myconf="${myconf} -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
+		myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
 	fi
 
 	# Enable sandbox.
-	myconf="${myconf}
-		-Dlinux_sandbox_path=$(get_chromium_home)/chrome_sandbox
-		-Dlinux_sandbox_chrome_path=$(get_chromium_home)/chrome"
+	myconf+="
+		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
+		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
 
 	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
 	# and the performance gain isn't worth it.
-	myconf="${myconf} -Dv8_use_snapshot=0"
+	myconf+=" -Dv8_use_snapshot=0"
 
 	# Disable tcmalloc memory allocator. It causes problems,
 	# for example bug #320419.
-	myconf="${myconf} -Dlinux_use_tcmalloc=0"
+	myconf+=" -Dlinux_use_tcmalloc=0"
 
 	# Use target arch detection logic from bug #296917.
 	local myarch="$ABI"
 	[[ $myarch = "" ]] && myarch="$ARCH"
 
 	if [[ $myarch = amd64 ]] ; then
-		myconf="${myconf} -Dtarget_arch=x64"
+		myconf+=" -Dtarget_arch=x64"
 	elif [[ $myarch = x86 ]] ; then
-		myconf="${myconf} -Dtarget_arch=ia32"
+		myconf+=" -Dtarget_arch=ia32"
 	elif [[ $myarch = arm ]] ; then
 		# TODO: check this again after
 		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
 		append-flags -fno-tree-sink
 
-		myconf="${myconf} -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
+		myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
 	else
 		die "Failed to determine target arch, got '$myarch'."
 	fi
 
 	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
-		myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
+		myconf+=" -Dno_strict_aliasing=1 -Dgcc_version=44"
 	fi
 
 	# Work around a likely GCC bug, see bug #331945.
@@ -214,9 +213,9 @@
 	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
 	# Depending on GCC version the warnings are different and we don't want
 	# the build to fail because of that.
-	myconf="${myconf} -Dwerror="
+	myconf+=" -Dwerror="
 
-	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
+	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die
 }
 
 src_compile() {
@@ -225,46 +224,43 @@
 		CXX="$(tc-getCXX)" \
 		AR="$(tc-getAR)" \
 		RANLIB="$(tc-getRANLIB)" \
-		|| die "compilation failed"
+		|| die
 }
 
 src_install() {
-	dodir "$(get_chromium_home)"
-
-	exeinto "$(get_chromium_home)"
+	exeinto "${CHROMIUM_HOME}"
 	pax-mark m out/Release/chrome
 	doexe out/Release/chrome
-	doexe out/Release/chrome_sandbox
-	fperms 4755 "$(get_chromium_home)/chrome_sandbox"
-	doexe out/Release/xdg-settings
-	doexe "${FILESDIR}"/chromium-launcher.sh
-
-	insinto "$(get_chromium_home)"
-	doins out/Release/chrome.pak || die "installing chrome.pak failed"
-	doins out/Release/resources.pak || die "installing resources.pak failed"
+	doexe out/Release/chrome_sandbox || die
+	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
+	doexe out/Release/xdg-settings || die
+	doexe "${FILESDIR}"/chromium-launcher.sh || die
+
+	insinto "${CHROMIUM_HOME}"
+	doins out/Release/chrome.pak || die
+	doins out/Release/resources.pak || die
 
-	doins -r out/Release/locales
-	doins -r out/Release/resources
+	doins -r out/Release/locales || die
+	doins -r out/Release/resources || die
 
 	# chrome.1 is for chromium --help
-	newman out/Release/chrome.1 chrome.1
-	newman out/Release/chrome.1 chromium.1
+	newman out/Release/chrome.1 chrome.1 || die
+	newman out/Release/chrome.1 chromium.1 || die
 
 	doexe out/Release/ffmpegsumo_nolink || die
 	doexe out/Release/libffmpegsumo.so || die
 
 	# Install icon and desktop entry.
-	newicon out/Release/product_logo_48.png ${PN}-browser.png
-	dosym "$(get_chromium_home)/chromium-launcher.sh" /usr/bin/chromium
+	newicon out/Release/product_logo_48.png ${PN}-browser.png || die
+	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
 	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
 		"MimeType=text/html;text/xml;application/xhtml+xml;"
-	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
-		|| die "desktop file sed failed"
+	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die
 
 	# Install GNOME default application entry (bug #303100).
 	if use gnome; then
-		dodir /usr/share/gnome-control-center/default-apps
+		dodir /usr/share/gnome-control-center/default-apps || die
 		insinto /usr/share/gnome-control-center/default-apps
-		doins "${FILESDIR}"/chromium.xml
+		doins "${FILESDIR}"/chromium.xml || die
 	fi
 }



1.2                  www-client/chromium/chromium-7.0.503.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild?r1=1.1&r2=1.2

Index: chromium-7.0.503.1-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- chromium-7.0.503.1-r1.ebuild	7 Sep 2010 17:19:25 -0000	1.1
+++ chromium-7.0.503.1-r1.ebuild	11 Sep 2010 16:10:20 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild,v 1.1 2010/09/07 17:19:25 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.503.1-r1.ebuild,v 1.2 2010/09/11 16:10:20 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -32,8 +32,7 @@
 	dev-lang/perl
 	>=dev-util/gperf-3.0.3
 	>=dev-util/pkgconfig-0.23
-	sys-devel/flex
-	virtual/perl-version"
+	sys-devel/flex"
 RDEPEND+="
 	|| (
 		x11-themes/gnome-icon-theme
@@ -45,10 +44,6 @@
 	x11-misc/xdg-utils
 	virtual/ttf-fonts"
 
-get_chromium_home() {
-	echo "/usr/$(get_libdir)/chromium-browser"
-}
-
 remove_bundled_lib() {
 	einfo "Removing bundled library $1 ..."
 	local out
@@ -59,6 +54,10 @@
 	fi
 }
 
+pkg_setup() {
+	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
+}
+
 src_prepare() {
 	# Add Gentoo plugin paths.
 	epatch "${FILESDIR}"/${PN}-plugins-path-r0.patch
@@ -92,9 +91,9 @@
 
 	# Make it possible to build chromium on non-sse2 systems.
 	if use sse2; then
-		myconf="${myconf} -Ddisable_sse2=0"
+		myconf+=" -Ddisable_sse2=0"
 	else
-		myconf="${myconf} -Ddisable_sse2=1"
+		myconf+=" -Ddisable_sse2=1"
 	fi
 
 	# Use system-provided libraries.
@@ -103,7 +102,7 @@
 	# TODO: use_system_sqlite (http://crbug.com/22208).
 	# TODO: use_system_hunspell (upstream changes needed).
 	# TODO: use_system_ssl when we have a recent enough system NSS.
-	myconf="${myconf}
+	myconf+="
 		-Duse_system_bzip2=1
 		-Duse_system_icu=1
 		-Duse_system_libevent=1
@@ -113,52 +112,52 @@
 
 	# The dependency on cups is optional, see bug #324105.
 	if use cups; then
-		myconf="${myconf} -Duse_cups=1"
+		myconf+=" -Duse_cups=1"
 	else
-		myconf="${myconf} -Duse_cups=0"
+		myconf+=" -Duse_cups=0"
 	fi
 
 	if use "gnome-keyring"; then
-		myconf="${myconf} -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
+		myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
 	else
 		# TODO: we should also disable code trying to dlopen
 		# gnome-keyring in that case.
-		myconf="${myconf} -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
+		myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
 	fi
 
 	# Enable sandbox.
-	myconf="${myconf}
-		-Dlinux_sandbox_path=$(get_chromium_home)/chrome_sandbox
-		-Dlinux_sandbox_chrome_path=$(get_chromium_home)/chrome"
+	myconf+="
+		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
+		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
 
 	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
 	# and the performance gain isn't worth it.
-	myconf="${myconf} -Dv8_use_snapshot=0"
+	myconf+=" -Dv8_use_snapshot=0"
 
 	# Disable tcmalloc memory allocator. It causes problems,
 	# for example bug #320419.
-	myconf="${myconf} -Dlinux_use_tcmalloc=0"
+	myconf+=" -Dlinux_use_tcmalloc=0"
 
 	# Use target arch detection logic from bug #296917.
 	local myarch="$ABI"
 	[[ $myarch = "" ]] && myarch="$ARCH"
 
 	if [[ $myarch = amd64 ]] ; then
-		myconf="${myconf} -Dtarget_arch=x64"
+		myconf+=" -Dtarget_arch=x64"
 	elif [[ $myarch = x86 ]] ; then
-		myconf="${myconf} -Dtarget_arch=ia32"
+		myconf+=" -Dtarget_arch=ia32"
 	elif [[ $myarch = arm ]] ; then
 		# TODO: check this again after
 		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
 		append-flags -fno-tree-sink
 
-		myconf="${myconf} -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
+		myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
 	else
 		die "Failed to determine target arch, got '$myarch'."
 	fi
 
 	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
-		myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
+		myconf+=" -Dno_strict_aliasing=1 -Dgcc_version=44"
 	fi
 
 	# Work around a likely GCC bug, see bug #331945.
@@ -169,9 +168,9 @@
 	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
 	# Depending on GCC version the warnings are different and we don't want
 	# the build to fail because of that.
-	myconf="${myconf} -Dwerror="
+	myconf+=" -Dwerror="
 
-	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
+	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die
 }
 
 src_compile() {
@@ -180,46 +179,43 @@
 		CXX="$(tc-getCXX)" \
 		AR="$(tc-getAR)" \
 		RANLIB="$(tc-getRANLIB)" \
-		|| die "compilation failed"
+		|| die
 }
 
 src_install() {
-	dodir "$(get_chromium_home)"
-
-	exeinto "$(get_chromium_home)"
+	exeinto "${CHROMIUM_HOME}"
 	pax-mark m out/Release/chrome
 	doexe out/Release/chrome
-	doexe out/Release/chrome_sandbox
-	fperms 4755 "$(get_chromium_home)/chrome_sandbox"
-	doexe out/Release/xdg-settings
-	doexe "${FILESDIR}"/chromium-launcher.sh
-
-	insinto "$(get_chromium_home)"
-	doins out/Release/chrome.pak || die "installing chrome.pak failed"
-	doins out/Release/resources.pak || die "installing resources.pak failed"
+	doexe out/Release/chrome_sandbox || die
+	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
+	doexe out/Release/xdg-settings || die
+	doexe "${FILESDIR}"/chromium-launcher.sh || die
+
+	insinto "${CHROMIUM_HOME}"
+	doins out/Release/chrome.pak || die
+	doins out/Release/resources.pak || die
 
-	doins -r out/Release/locales
-	doins -r out/Release/resources
+	doins -r out/Release/locales || die
+	doins -r out/Release/resources || die
 
 	# chrome.1 is for chromium --help
-	newman out/Release/chrome.1 chrome.1
-	newman out/Release/chrome.1 chromium.1
+	newman out/Release/chrome.1 chrome.1 || die
+	newman out/Release/chrome.1 chromium.1 || die
 
 	doexe out/Release/ffmpegsumo_nolink || die
 	doexe out/Release/libffmpegsumo.so || die
 
 	# Install icon and desktop entry.
-	newicon out/Release/product_logo_48.png ${PN}-browser.png
-	dosym "$(get_chromium_home)/chromium-launcher.sh" /usr/bin/chromium
+	newicon out/Release/product_logo_48.png ${PN}-browser.png || die
+	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
 	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
 		"MimeType=text/html;text/xml;application/xhtml+xml;"
-	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
-		|| die "desktop file sed failed"
+	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die
 
 	# Install GNOME default application entry (bug #303100).
 	if use gnome; then
-		dodir /usr/share/gnome-control-center/default-apps
+		dodir /usr/share/gnome-control-center/default-apps || die
 		insinto /usr/share/gnome-control-center/default-apps
-		doins "${FILESDIR}"/chromium.xml
+		doins "${FILESDIR}"/chromium.xml || die
 	fi
 }






^ permalink raw reply	[flat|nested] 2+ messages in thread
end of thread, other threads:[~2010-09-11 16:10 UTC | newest]

Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-09-11 16:10 [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-9999.ebuild chromium-7.0.503.1-r1.ebuild PaweA Hajdan (phajdan.jr)
  -- strict thread matches above, loose matches on Subject: below --
2010-09-07 17:19 PaweA Hajdan (phajdan.jr)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox