* [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-5.0.375.127.ebuild
@ 2010-08-19 21:53 PaweA Hajdan (phajdan.jr)
0 siblings, 0 replies; 3+ messages in thread
From: PaweA Hajdan (phajdan.jr) @ 2010-08-19 21:53 UTC (permalink / raw
To: gentoo-commits
phajdan.jr 10/08/19 21:53:51
Modified: ChangeLog
Added: chromium-5.0.375.127.ebuild
Log:
Version bump for stable channel release.
(Portage version: 2.1.8.3/cvs/Linux i686)
Revision Changes Path
1.163 www-client/chromium/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.163&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.163&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.162&r2=1.163
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.162
retrieving revision 1.163
diff -u -r1.162 -r1.163
--- ChangeLog 19 Aug 2010 20:03:17 -0000 1.162
+++ ChangeLog 19 Aug 2010 21:53:51 -0000 1.163
@@ -1,6 +1,12 @@
# ChangeLog for www-client/chromium
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.162 2010/08/19 20:03:17 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.163 2010/08/19 21:53:51 phajdan.jr Exp $
+
+*chromium-5.0.375.127 (19 Aug 2010)
+
+ 19 Aug 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+ +chromium-5.0.375.127.ebuild:
+ Version bump for stable channel release.
19 Aug 2010; Alex Alexander <wired@gentoo.org> chromium-6.0.495.0.ebuild,
+files/chromium-6.0.495.0-gcc-4.5.patch:
1.1 www-client/chromium/chromium-5.0.375.127.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?rev=1.1&content-type=text/plain
Index: chromium-5.0.375.127.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild,v 1.1 2010/08/19 21:53:51 phajdan.jr Exp $
EAPI="2"
inherit eutils flag-o-matic multilib pax-utils toolchain-funcs
DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="+plugins-symlink"
RDEPEND="app-arch/bzip2
>=dev-libs/libevent-1.4.13
dev-libs/libxml2
dev-libs/libxslt
>=dev-libs/nss-3.12.3
>=gnome-base/gconf-2.24.0
>=media-libs/alsa-lib-1.0.19
media-libs/jpeg:0
media-libs/libpng
media-video/ffmpeg[threads]
sys-libs/zlib
>=x11-libs/gtk+-2.14.7
x11-libs/libXScrnSaver"
# dev-db/sqlite:3
DEPEND="${RDEPEND}
dev-lang/perl
>=dev-util/gperf-3.0.3
>=dev-util/pkgconfig-0.23
sys-devel/flex"
RDEPEND+="
|| (
x11-themes/gnome-icon-theme
x11-themes/oxygen-molecule
x11-themes/tango-icon-theme
x11-themes/xfce4-icon-theme
)
x11-apps/xmessage
x11-misc/xdg-utils
virtual/ttf-fonts"
src_prepare() {
# Prevent automatic -march=pentium4 -msse2 enabling on x86, http://crbug.com/9007
epatch "${FILESDIR}"/${PN}-drop_sse2-r0.patch
# Allow supporting more media types.
epatch "${FILESDIR}"/${PN}-20100122-ubuntu-html5-video-mimetypes.patch
# Fix build failure with libpng-1.4, bug 310959.
epatch "${FILESDIR}"/${PN}-libpng-1.4.patch
}
src_configure() {
export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser
# Workaround for bug #318969.
# TODO: remove when http://crbug.com/43778 is fixed.
append-flags -D__STDC_CONSTANT_MACROS
# Fails to build on arm if we don't do this
use arm && append-flags -fno-tree-sink
# Configuration options (system libraries)
local myconf="-Duse_system_zlib=1 -Duse_system_bzip2=1 -Duse_system_ffmpeg=1 -Duse_system_libevent=1 -Duse_system_libjpeg=1 -Duse_system_libpng=1 -Duse_system_libxml=1 -Duse_system_libxslt=1"
# -Duse_system_sqlite=1 : http://crbug.com/22208
# Others still bundled: icu (not possible?), hunspell (changes required for sandbox support)
# Sandbox paths
myconf="${myconf} -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
# and the performance gain isn't worth it.
myconf="${myconf} -Dv8_use_snapshot=0"
# Disable tcmalloc memory allocator. It causes problems,
# for example bug #320419.
myconf="${myconf} -Dlinux_use_tcmalloc=0"
# Disable gpu rendering, it is incompatible with nvidia-drivers,
# bug #319331.
myconf="${myconf} -Denable_gpu=0"
# Use target arch detection logic from bug #296917.
local myarch="$ABI"
[[ $myarch = "" ]] && myarch="$ARCH"
if [[ $myarch = amd64 ]] ; then
myconf="${myconf} -Dtarget_arch=x64"
elif [[ $myarch = x86 ]] ; then
myconf="${myconf} -Dtarget_arch=ia32"
elif [[ $myarch = arm ]] ; then
myconf="${myconf} -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
else
die "Failed to determine target arch, got '$myarch'."
fi
if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
fi
# Make sure that -Werror doesn't get added to CFLAGS by the build system.
# Depending on GCC version the warnings are different and we don't want
# the build to fail because of that.
myconf="${myconf} -Dwerror="
build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
}
src_compile() {
emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
rootdir="${S}" \
CC="$(tc-getCC)" \
CXX="$(tc-getCXX)" \
AR="$(tc-getAR)" \
RANLIB="$(tc-getRANLIB)" \
|| die "compilation failed"
}
src_install() {
# Chromium does not have "install" target in the build system.
export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser
dodir ${CHROMIUM_HOME}
exeinto ${CHROMIUM_HOME}
pax-mark m out/Release/chrome
doexe out/Release/chrome
doexe out/Release/chrome_sandbox
fperms 4755 ${CHROMIUM_HOME}/chrome_sandbox
doexe out/Release/xdg-settings
doexe "${FILESDIR}"/chromium-launcher.sh
insinto ${CHROMIUM_HOME}
doins out/Release/chrome.pak
doins -r out/Release/locales
doins -r out/Release/resources
# chrome.1 is for chromium --help
newman out/Release/chrome.1 chrome.1
newman out/Release/chrome.1 chromium.1
# Chromium looks for these in its folder
# See media_posix.cc and base_paths_linux.cc
dosym /usr/$(get_libdir)/libavcodec.so.52 ${CHROMIUM_HOME}
dosym /usr/$(get_libdir)/libavformat.so.52 ${CHROMIUM_HOME}
dosym /usr/$(get_libdir)/libavutil.so.50 ${CHROMIUM_HOME}
# Plugins symlink, optional wrt bug #301911
if use plugins-symlink; then
dosym /usr/$(get_libdir)/nsbrowser/plugins ${CHROMIUM_HOME}/plugins
fi
# Icon and desktop entry
newicon out/Release/product_logo_48.png ${PN}-browser.png
dosym ${CHROMIUM_HOME}/chromium-launcher.sh /usr/bin/chromium
make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser"
sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
|| die "desktop file sed failed"
# Gnome default application entry
dodir /usr/share/gnome-control-center/default-apps
insinto /usr/share/gnome-control-center/default-apps
doins "${FILESDIR}"/chromium.xml
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-5.0.375.127.ebuild
@ 2010-08-20 7:54 Christian Faulhammer (fauli)
0 siblings, 0 replies; 3+ messages in thread
From: Christian Faulhammer (fauli) @ 2010-08-20 7:54 UTC (permalink / raw
To: gentoo-commits
fauli 10/08/20 07:54:06
Modified: ChangeLog chromium-5.0.375.127.ebuild
Log:
stable x86, security bug 333559
(Portage version: 2.1.8.3/cvs/Linux i686)
Revision Changes Path
1.164 www-client/chromium/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.164&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.164&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.163&r2=1.164
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.163
retrieving revision 1.164
diff -u -r1.163 -r1.164
--- ChangeLog 19 Aug 2010 21:53:51 -0000 1.163
+++ ChangeLog 20 Aug 2010 07:54:06 -0000 1.164
@@ -1,6 +1,10 @@
# ChangeLog for www-client/chromium
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.163 2010/08/19 21:53:51 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.164 2010/08/20 07:54:06 fauli Exp $
+
+ 20 Aug 2010; Christian Faulhammer <fauli@gentoo.org>
+ chromium-5.0.375.127.ebuild:
+ stable x86, security bug 333559
*chromium-5.0.375.127 (19 Aug 2010)
1.2 www-client/chromium/chromium-5.0.375.127.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?r1=1.1&r2=1.2
Index: chromium-5.0.375.127.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- chromium-5.0.375.127.ebuild 19 Aug 2010 21:53:51 -0000 1.1
+++ chromium-5.0.375.127.ebuild 20 Aug 2010 07:54:06 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild,v 1.1 2010/08/19 21:53:51 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild,v 1.2 2010/08/20 07:54:06 fauli Exp $
EAPI="2"
@@ -12,7 +12,7 @@
LICENSE="BSD"
SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
+KEYWORDS="~amd64 ~arm x86"
IUSE="+plugins-symlink"
RDEPEND="app-arch/bzip2
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-5.0.375.127.ebuild
@ 2010-08-20 8:35 Markos Chandras (hwoarang)
0 siblings, 0 replies; 3+ messages in thread
From: Markos Chandras (hwoarang) @ 2010-08-20 8:35 UTC (permalink / raw
To: gentoo-commits
hwoarang 10/08/20 08:35:45
Modified: ChangeLog chromium-5.0.375.127.ebuild
Log:
Stable on amd64 wrt bug #333559
(Portage version: 2.2_rc67/cvs/Linux x86_64)
Revision Changes Path
1.165 www-client/chromium/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.165&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.165&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.164&r2=1.165
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.164
retrieving revision 1.165
diff -u -r1.164 -r1.165
--- ChangeLog 20 Aug 2010 07:54:06 -0000 1.164
+++ ChangeLog 20 Aug 2010 08:35:45 -0000 1.165
@@ -1,6 +1,10 @@
# ChangeLog for www-client/chromium
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.164 2010/08/20 07:54:06 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.165 2010/08/20 08:35:45 hwoarang Exp $
+
+ 20 Aug 2010; Markos Chandras <hwoarang@gentoo.org>
+ chromium-5.0.375.127.ebuild:
+ Stable on amd64 wrt bug #333559
20 Aug 2010; Christian Faulhammer <fauli@gentoo.org>
chromium-5.0.375.127.ebuild:
1.3 www-client/chromium/chromium-5.0.375.127.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild?r1=1.2&r2=1.3
Index: chromium-5.0.375.127.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- chromium-5.0.375.127.ebuild 20 Aug 2010 07:54:06 -0000 1.2
+++ chromium-5.0.375.127.ebuild 20 Aug 2010 08:35:45 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild,v 1.2 2010/08/20 07:54:06 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.127.ebuild,v 1.3 2010/08/20 08:35:45 hwoarang Exp $
EAPI="2"
@@ -12,7 +12,7 @@
LICENSE="BSD"
SLOT="0"
-KEYWORDS="~amd64 ~arm x86"
+KEYWORDS="amd64 ~arm x86"
IUSE="+plugins-symlink"
RDEPEND="app-arch/bzip2
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2010-08-20 8:35 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-08-20 8:35 [gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-5.0.375.127.ebuild Markos Chandras (hwoarang)
-- strict thread matches above, loose matches on Subject: below --
2010-08-20 7:54 Christian Faulhammer (fauli)
2010-08-19 21:53 PaweA Hajdan (phajdan.jr)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox