* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.8.3-r1.ebuild ChangeLog
@ 2010-08-10 21:23 Doug Goldstein (cardoe)
0 siblings, 0 replies; 4+ messages in thread
From: Doug Goldstein (cardoe) @ 2010-08-10 21:23 UTC (permalink / raw
To: gentoo-commits
cardoe 10/08/10 21:23:37
Modified: ChangeLog
Added: libvirt-0.8.3-r1.ebuild
Log:
Handful of upstream fixes for phyp overflows, documentation errors, qemu PCI device deletion. Local fixes for LXC tun/tap manipulation (pushed upstream).
(Portage version: 2.1.8.3/cvs/Linux x86_64)
Revision Changes Path
1.68 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.67&r2=1.68
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog 7 Aug 2010 02:43:29 -0000 1.67
+++ ChangeLog 10 Aug 2010 21:23:37 -0000 1.68
@@ -1,6 +1,13 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.67 2010/08/07 02:43:29 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.68 2010/08/10 21:23:37 cardoe Exp $
+
+*libvirt-0.8.3-r1 (10 Aug 2010)
+
+ 10 Aug 2010; Doug Goldstein <cardoe@gentoo.org> +libvirt-0.8.3-r1.ebuild:
+ Handful of upstream fixes for phyp overflows, documentation errors, qemu
+ PCI device deletion. Local fixes for LXC tun/tap manipulation (pushed
+ upstream).
07 Aug 2010; Diego E. Pettenò <flameeyes@gentoo.org>
libvirt-0.8.3.ebuild:
1.1 app-emulation/libvirt/libvirt-0.8.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.1&content-type=text/plain
Index: libvirt-0.8.3-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v 1.1 2010/08/10 21:23:37 cardoe Exp $
BACKPORTS=3
EAPI="2"
PYTHON_DEPEND="python? 2:2.4"
#RESTRICT_PYTHON_ABIS="3.*"
#SUPPORT_PYTHON_ABIS="1"
inherit eutils python autotools
DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz
${BACKPORTS:+mirror://gentoo/${P}-backports-${BACKPORTS}.tar.bz2}"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi caps debug iscsi +libvirtd lvm +lxc macvtap +network nfs nls \
numa openvz parted pcap phyp policykit python qemu sasl selinux
uml virtualbox xen udev"
# IUSE=one : bug #293416 & bug #299011
RDEPEND="sys-libs/readline
sys-libs/ncurses
>=net-misc/curl-7.18.0
>=dev-libs/libxml2-2.7.6
>=net-libs/gnutls-1.0.25
sys-fs/sysfsutils
sys-apps/util-linux
>=net-analyzer/netcat6-1.0-r2
avahi? ( >=net-dns/avahi-0.6[dbus] )
caps? ( sys-libs/libcap-ng )
iscsi? ( sys-block/open-iscsi )
libvirtd? ( net-misc/bridge-utils )
lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
macvtap? ( >=dev-libs/libnl-1.1 )
nfs? ( net-fs/nfs-utils )
numa? ( sys-process/numactl )
openvz? ( sys-kernel/openvz-sources )
parted? ( >=sys-apps/parted-1.8 )
pcap? ( >=net-libs/libpcap-1.0.0 )
phyp? ( net-libs/libssh2 )
policykit? ( >=sys-auth/polkit-0.9 )
qemu? ( || ( app-emulation/qemu-kvm >=app-emulation/qemu-0.10.0 ) )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( >=sys-libs/libselinux-2.0.85 )
virtualbox? ( || ( >=app-emulation/virtualbox-ose-2.2.0 >=app-emulation/virtualbox-bin-2.2.0 ) )
xen? ( app-emulation/xen-tools app-emulation/xen )
udev? ( >=sys-fs/udev-145 >=x11-libs/libpciaccess-0.10.9 )"
# one? ( dev-libs/xmlrpc-c )
DEPEND="${RDEPEND}
dev-util/pkgconfig
nls? ( sys-devel/gettext )"
pkg_setup() {
python_set_active_version 2
}
src_prepare() {
[[ -n ${BACKPORTS} ]] && \
EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
epatch
eautoreconf
}
src_configure() {
local myconf=""
myconf="${myconf} $(use_enable debug)"
## enable/disable daemon, otherwise client only utils
myconf="${myconf} $(use_with libvirtd)"
## enable/disable the daemon using avahi to find VMs
myconf="${myconf} $(use_with avahi)"
## hypervisors on the local host
myconf="${myconf} $(use_with xen) $(use_with xen xen-inotify)"
if ! use policykit && use xen; then
myconf="${myconf} --with-xen-proxy"
fi
myconf="${myconf} $(use_with openvz)"
myconf="${myconf} $(use_with lxc)"
if use virtualbox && has_version app-emulation/virtualbox-ose; then
myconf="${myconf} --with-vbox=/usr/lib/virtualbox-ose/"
else
myconf="${myconf} $(use_with virtualbox vbox)"
fi
myconf="${myconf} $(use_with uml)"
myconf="${myconf} $(use_with qemu)"
# doesn't belong with hypervisors but links to libvirtd for some reason
#myconf="${myconf} $(use_with one)"
## hypervisor protocols
myconf="${myconf} $(use_with phyp)"
myconf="${myconf} --with-esx"
## additional host drivers
myconf="${myconf} $(use_with network)"
myconf="${myconf} --with-storage-fs"
myconf="${myconf} $(use_with lvm storage-lvm)"
myconf="${myconf} $(use_with iscsi storage-iscsi)"
myconf="${myconf} $(use_with parted storage-disk)"
myconf="${myconf} $(use_with lvm storage-mpath)"
myconf="${myconf} $(use_with numa numactl)"
myconf="${myconf} $(use_with selinux)"
# udev for device support details
myconf="${myconf} $(use_with udev)"
# linux capability support so we don't need privileged accounts
myconf="${myconf} $(use_with caps capng)"
## auth stuff
myconf="${myconf} $(use_with policykit polkit)"
myconf="${myconf} $(use_with sasl)"
# network biits
myconf="${myconf} $(use_with pcap libpcap)"
myconf="${myconf} $(use_with macvtap)"
## other
myconf="${myconf} $(use_enable nls)"
myconf="${myconf} $(use_with python)"
## stuff we don't yet support
myconf="${myconf} --without-netcf"
# we use udev over hal
myconf="${myconf} --without-hal"
# this is a nasty trick to work around the problem in bug
# #275073. The reason why we don't solve this properly is that
# it'll require us to rebuild autotools (and we don't really want
# to do that right now). The proper solution has been sent
# upstream and should hopefully land in 0.7.7, in the mean time,
# mime the same functionality with this.
case ${CHOST} in
*cygwin* | *mingw* )
;;
*)
ac_cv_prog_WINDRES=no
;;
esac
econf \
${myconf} \
--disable-static \
--docdir=/usr/share/doc/${PF} \
--with-remote \
--localstatedir=/var \
--with-remote-pid-file=/var/run/libvirtd.pid
}
src_test() {
# Explicitly allow parallel build of tests
emake check || die "tests failed"
}
src_install() {
emake install \
DESTDIR="${D}" \
HTML_DIR=/usr/share/doc/${PF}/html \
DOCS_DIR=/usr/share/doc/${PF}/python \
EXAMPLE_DIR=/usr/share/doc/${PF}/python/examples \
|| die "emake install failed"
find "${D}" -name '*.la' -delete || die
use libvirtd || return 0
# From here, only libvirtd-related instructions, be warned!
newinitd "${FILESDIR}/libvirtd.init-r1" libvirtd || die
newconfd "${FILESDIR}/libvirtd.confd-r1" libvirtd || die
keepdir /var/lib/libvirt/images
}
pkg_preinst() {
# we only ever want to generate this once
if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
fi
# We really don't want to use or support old PolicyKit cause it
# screws with the new polkit integration
if has_version sys-auth/policykit; then
rm -rf "${D}"/usr/share/PolicyKit/policy/org.libvirt.unix.policy
fi
}
pkg_postinst() {
use python && python_mod_optimize $(python_get_sitedir)/libvirt.py
elog
if use policykit && has_version sys-auth/policykit; then
elog "You must have run the following at least once:"
elog
elog "$ polkit-auth --grant org.libvirt.unix.manage --user \"USERNAME\""
elog
elog "to grant USERNAME access to libvirt when using USE=policykit"
else
elog "To allow normal users to connect to libvirtd you must change the"
elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
fi
use libvirtd || return 0
# From here, only libvirtd-related instructions, be warned!
elog
elog "For the basic networking support (bridged and routed networks)"
elog "you don't need any extra software. For more complex network modes"
elog "including but not limited to NATed network, you'll need the"
elog "following packages":
elog
elog " net-dns/dnsmasq"
elog " net-firewall/iptables"
elog " net-firewall/ebtables"
elog
if has_version net-dns/dnsmasq; then
ewarn "If you have a DNS server setup on your machine, you will have"
ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
ewarn " bind-interfaces"
ewarn " interface or except-interface"
ewarn
ewarn "Otherwise you might have issues with your existing DNS server."
fi
}
pkg_postrm() {
use python && python_mod_cleanup $(python_get_sitedir)/libvirt.py
}
^ permalink raw reply [flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.8.3-r1.ebuild ChangeLog
@ 2010-08-12 8:50 Tiziano Mueller (dev-zero)
0 siblings, 0 replies; 4+ messages in thread
From: Tiziano Mueller (dev-zero) @ 2010-08-12 8:50 UTC (permalink / raw
To: gentoo-commits
dev-zero 10/08/12 08:50:59
Modified: libvirt-0.8.3-r1.ebuild ChangeLog
Log:
Allow qemu-kvm-spice as an alternative for the qemu dependency.
(Portage version: 2.2_rc67/cvs/Linux x86_64)
Revision Changes Path
1.2 app-emulation/libvirt/libvirt-0.8.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?r1=1.1&r2=1.2
Index: libvirt-0.8.3-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- libvirt-0.8.3-r1.ebuild 10 Aug 2010 21:23:37 -0000 1.1
+++ libvirt-0.8.3-r1.ebuild 12 Aug 2010 08:50:59 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v 1.1 2010/08/10 21:23:37 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v 1.2 2010/08/12 08:50:59 dev-zero Exp $
BACKPORTS=3
@@ -45,7 +45,7 @@
pcap? ( >=net-libs/libpcap-1.0.0 )
phyp? ( net-libs/libssh2 )
policykit? ( >=sys-auth/polkit-0.9 )
- qemu? ( || ( app-emulation/qemu-kvm >=app-emulation/qemu-0.10.0 ) )
+ qemu? ( || ( app-emulation/qemu-kvm >=app-emulation/qemu-0.10.0 app-emulation/qemu-kvm-spice ) )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( >=sys-libs/libselinux-2.0.85 )
virtualbox? ( || ( >=app-emulation/virtualbox-ose-2.2.0 >=app-emulation/virtualbox-bin-2.2.0 ) )
1.69 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.68&r2=1.69
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog 10 Aug 2010 21:23:37 -0000 1.68
+++ ChangeLog 12 Aug 2010 08:50:59 -0000 1.69
@@ -1,6 +1,10 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.68 2010/08/10 21:23:37 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.69 2010/08/12 08:50:59 dev-zero Exp $
+
+ 12 Aug 2010; Tiziano Müller <dev-zero@gentoo.org>
+ libvirt-0.8.3-r1.ebuild:
+ Allow qemu-kvm-spice as an alternative for the qemu dependency.
*libvirt-0.8.3-r1 (10 Aug 2010)
^ permalink raw reply [flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.8.3-r1.ebuild ChangeLog
@ 2010-08-13 10:59 Tiziano Mueller (dev-zero)
0 siblings, 0 replies; 4+ messages in thread
From: Tiziano Mueller (dev-zero) @ 2010-08-13 10:59 UTC (permalink / raw
To: gentoo-commits
dev-zero 10/08/13 10:59:09
Modified: libvirt-0.8.3-r1.ebuild ChangeLog
Log:
Changed elog comment concerning iptables to make sure people install a recent enough version.
(Portage version: 2.2_rc67/cvs/Linux x86_64)
Revision Changes Path
1.3 app-emulation/libvirt/libvirt-0.8.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?r1=1.2&r2=1.3
Index: libvirt-0.8.3-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- libvirt-0.8.3-r1.ebuild 12 Aug 2010 08:50:59 -0000 1.2
+++ libvirt-0.8.3-r1.ebuild 13 Aug 2010 10:59:09 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v 1.2 2010/08/12 08:50:59 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v 1.3 2010/08/13 10:59:09 dev-zero Exp $
BACKPORTS=3
@@ -219,7 +219,7 @@
elog "following packages":
elog
elog " net-dns/dnsmasq"
- elog " net-firewall/iptables"
+ elog " >=net-firewall/iptables-1.4.9"
elog " net-firewall/ebtables"
elog
if has_version net-dns/dnsmasq; then
1.70 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.69&r2=1.70
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog 12 Aug 2010 08:50:59 -0000 1.69
+++ ChangeLog 13 Aug 2010 10:59:09 -0000 1.70
@@ -1,6 +1,11 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.69 2010/08/12 08:50:59 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.70 2010/08/13 10:59:09 dev-zero Exp $
+
+ 13 Aug 2010; Tiziano Müller <dev-zero@gentoo.org>
+ libvirt-0.8.3-r1.ebuild:
+ Changed elog comment concerning iptables to make sure people install a
+ recent enough version.
12 Aug 2010; Tiziano Müller <dev-zero@gentoo.org>
libvirt-0.8.3-r1.ebuild:
^ permalink raw reply [flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.8.3-r1.ebuild ChangeLog
@ 2010-09-12 15:35 Jorge Manuel B. S. Vicetto (jmbsvicetto)
0 siblings, 0 replies; 4+ messages in thread
From: Jorge Manuel B. S. Vicetto (jmbsvicetto) @ 2010-09-12 15:35 UTC (permalink / raw
To: gentoo-commits
jmbsvicetto 10/09/12 15:35:41
Modified: libvirt-0.8.3-r1.ebuild ChangeLog
Log:
[app-emulation/libvirt-0.8.3-r1] Added missing dev-libs/libnl dep.
The dep seems to come from http://www.redhat.com/archives/libvir-list/2010-May/msg00830.html
(Portage version: 2.2_rc73/cvs/Linux x86_64)
Revision Changes Path
1.6 app-emulation/libvirt/libvirt-0.8.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild?r1=1.5&r2=1.6
Index: libvirt-0.8.3-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- libvirt-0.8.3-r1.ebuild 20 Aug 2010 17:01:37 -0000 1.5
+++ libvirt-0.8.3-r1.ebuild 12 Sep 2010 15:35:41 -0000 1.6
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v 1.5 2010/08/20 17:01:37 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3-r1.ebuild,v 1.6 2010/09/12 15:35:41 jmbsvicetto Exp $
BACKPORTS=3
@@ -28,6 +28,7 @@
sys-libs/ncurses
>=net-misc/curl-7.18.0
>=dev-libs/libxml2-2.7.6
+ >=dev-libs/libnl-1.1
>=net-libs/gnutls-1.0.25
sys-fs/sysfsutils
sys-apps/util-linux
1.74 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.73&r2=1.74
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog 20 Aug 2010 17:10:11 -0000 1.73
+++ ChangeLog 12 Sep 2010 15:35:41 -0000 1.74
@@ -1,6 +1,12 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.73 2010/08/20 17:10:11 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.74 2010/09/12 15:35:41 jmbsvicetto Exp $
+
+ 12 Sep 2010; Jorge Manuel B. S. Vicetto <jmbsvicetto@gentoo.org>
+ libvirt-0.8.3-r1.ebuild:
+ [app-emulation/libvirt-0.8.3-r1] Added missing dev-libs/libnl dep.
+ The dep seems to come from
+ http://www.redhat.com/archives/libvir-list/2010-May/msg00830.html
20 Aug 2010; Jeroen Roovers <jer@gentoo.org> metadata.xml:
Move from sys-apps/parted to sys-block/parted.
^ permalink raw reply [flat|nested] 4+ messages in thread
end of thread, other threads:[~2010-09-12 15:35 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-08-10 21:23 [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.8.3-r1.ebuild ChangeLog Doug Goldstein (cardoe)
-- strict thread matches above, loose matches on Subject: below --
2010-08-12 8:50 Tiziano Mueller (dev-zero)
2010-08-13 10:59 Tiziano Mueller (dev-zero)
2010-09-12 15:35 Jorge Manuel B. S. Vicetto (jmbsvicetto)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox