[gentoo-commits] gentoo-x86 commit in dev-ml/gd4o: gd4o-1.0_alpha5.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-ml/gd4o: gd4o-1.0_alpha5.ebuild metadata.xml ChangeLog

[Alexis Ballier (aballier)]

aballier    10/08/08 08:23:54

  Added:                gd4o-1.0_alpha5.ebuild metadata.xml ChangeLog
  Log:
  Initial import, ebuild by me
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-ml/gd4o/gd4o-1.0_alpha5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/gd4o/gd4o-1.0_alpha5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/gd4o/gd4o-1.0_alpha5.ebuild?rev=1.1&content-type=text/plain

Index: gd4o-1.0_alpha5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/gd4o/gd4o-1.0_alpha5.ebuild,v 1.1 2010/08/08 08:23:53 aballier Exp $

EAPI=3

inherit toolchain-funcs findlib

MY_P="${P/_alpha/a}"

DESCRIPTION="OCaml interface to the GD graphics library"
HOMEPAGE="http://sourceforge.net/projects/gd4o/"
SRC_URI="mirror://sourceforge/gd4o/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc +ocamlopt"

DEPEND=">=dev-lang/ocaml-3.10.2[ocamlopt?]
	media-libs/gd
	media-libs/jpeg
	sys-libs/zlib
	media-libs/libpng
	media-libs/freetype:2"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	sed -i 's/CFLAGS =/CFLAGS += -fPIC/' Makefile || die
}

src_compile() {
	emake CC="$(tc-getCC)" || die
	if use ocamlopt ; then
		emake CC="$(tc-getCC)" opt || die
	fi
	if use doc ; then
		emake docs || die
	fi
}

src_test() {
	emake test || die
	if use ocamlopt ; then
		emake test.opt || die
	fi
}

src_install() {
	findlib_src_install
	dodoc BUGS CHANGES README* TODO doc/manual.txt
	use doc && dohtml -r doc
}



1.1                  dev-ml/gd4o/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/gd4o/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/gd4o/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>ml</herd>
</pkgmetadata>



1.1                  dev-ml/gd4o/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/gd4o/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/gd4o/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-ml/gd4o
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/gd4o/ChangeLog,v 1.1 2010/08/08 08:23:53 aballier Exp $

*gd4o-1.0_alpha5 (08 Aug 2010)

  08 Aug 2010; Alexis Ballier <aballier@gentoo.org> +gd4o-1.0_alpha5.ebuild,
  +metadata.xml:
  Initial import, ebuild by me