* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: ChangeLog libvirt-0.8.3.ebuild
@ 2010-08-06 1:48 Diego Petteno (flameeyes)
0 siblings, 0 replies; 3+ messages in thread
From: Diego Petteno (flameeyes) @ 2010-08-06 1:48 UTC (permalink / raw
To: gentoo-commits
flameeyes 10/08/06 01:48:06
Modified: ChangeLog libvirt-0.8.3.ebuild
Log:
Fix build with USE=-libvirtd (sent upstream); add a debug USE flag; remove tests restriction (they work now).
(Portage version: 2.2_rc67/cvs/Linux x86_64)
Revision Changes Path
1.66 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.65&r2=1.66
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog 5 Aug 2010 19:58:59 -0000 1.65
+++ ChangeLog 6 Aug 2010 01:48:05 -0000 1.66
@@ -1,6 +1,11 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.65 2010/08/05 19:58:59 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.66 2010/08/06 01:48:05 flameeyes Exp $
+
+ 06 Aug 2010; Diego E. Pettenò <flameeyes@gentoo.org>
+ libvirt-0.8.3.ebuild:
+ Fix build with USE=-libvirtd (sent upstream); add a debug USE flag; remove
+ tests restriction (they work now).
*libvirt-0.8.3 (05 Aug 2010)
1.2 app-emulation/libvirt/libvirt-0.8.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?r1=1.1&r2=1.2
Index: libvirt-0.8.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- libvirt-0.8.3.ebuild 5 Aug 2010 19:58:59 -0000 1.1
+++ libvirt-0.8.3.ebuild 6 Aug 2010 01:48:06 -0000 1.2
@@ -1,8 +1,8 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild,v 1.1 2010/08/05 19:58:59 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild,v 1.2 2010/08/06 01:48:06 flameeyes Exp $
-BACKPORTS=1
+BACKPORTS=2
EAPI="2"
@@ -20,13 +20,10 @@
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi caps iscsi +libvirtd lvm +lxc macvtap +network nfs nls numa openvz \
- parted pcap phyp policykit python qemu sasl selinux uml virtualbox xen udev"
+ parted pcap phyp policykit python qemu sasl selinux uml virtualbox xen udev \
+ debug"
# IUSE=one : bug #293416 & bug# 299011
-# Some tests are simply broken in the released tarball, ignore them
-# for now.
-RESTRICT=test
-
RDEPEND="sys-libs/readline
sys-libs/ncurses
>=net-misc/curl-7.18.0
@@ -72,6 +69,8 @@
src_configure() {
local myconf=""
+ myconf="${myconf} $(use_enable debug)"
+
## enable/disable daemon, otherwise client only utils
myconf="${myconf} $(use_with libvirtd)"
^ permalink raw reply [flat|nested] 3+ messages in thread* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: ChangeLog libvirt-0.8.3.ebuild
@ 2010-08-07 2:43 Diego Petteno (flameeyes)
0 siblings, 0 replies; 3+ messages in thread
From: Diego Petteno (flameeyes) @ 2010-08-07 2:43 UTC (permalink / raw
To: gentoo-commits
flameeyes 10/08/07 02:43:30
Modified: ChangeLog libvirt-0.8.3.ebuild
Log:
Don't install the init script if we're not building the daemon; also don't add logs about networking in that case.
(Portage version: 2.2_rc67/cvs/Linux x86_64)
Revision Changes Path
1.67 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.66&r2=1.67
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog 6 Aug 2010 01:48:05 -0000 1.66
+++ ChangeLog 7 Aug 2010 02:43:29 -0000 1.67
@@ -1,6 +1,11 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.66 2010/08/06 01:48:05 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.67 2010/08/07 02:43:29 flameeyes Exp $
+
+ 07 Aug 2010; Diego E. Pettenò <flameeyes@gentoo.org>
+ libvirt-0.8.3.ebuild:
+ Don't install the init script if we're not building the daemon; also don't
+ add logs about networking in that case.
06 Aug 2010; Diego E. Pettenò <flameeyes@gentoo.org>
libvirt-0.8.3.ebuild:
1.3 app-emulation/libvirt/libvirt-0.8.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?r1=1.2&r2=1.3
Index: libvirt-0.8.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- libvirt-0.8.3.ebuild 6 Aug 2010 01:48:06 -0000 1.2
+++ libvirt-0.8.3.ebuild 7 Aug 2010 02:43:29 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild,v 1.2 2010/08/06 01:48:06 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild,v 1.3 2010/08/07 02:43:29 flameeyes Exp $
BACKPORTS=2
@@ -168,12 +168,15 @@
EXAMPLE_DIR=/usr/share/doc/${PF}/python/examples \
|| die "emake install failed"
+ find "${D}" -name '*.la' -delete || die
+
+ use libvirtd || return 0
+ # From here, only libvirtd-related instructions, be warned!
+
newinitd "${FILESDIR}/libvirtd.init-r1" libvirtd || die
newconfd "${FILESDIR}/libvirtd.confd-r1" libvirtd || die
keepdir /var/lib/libvirt/images
-
- find "${D}" -name '*.la' -delete || die
}
pkg_preinst() {
@@ -203,6 +206,10 @@
elog "To allow normal users to connect to libvirtd you must change the"
elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
fi
+
+ use libvirtd || return 0
+ # From here, only libvirtd-related instructions, be warned!
+
elog
elog "For the basic networking support (bridged and routed networks)"
elog "you don't need any extra software. For more complex network modes"
^ permalink raw reply [flat|nested] 3+ messages in thread* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: ChangeLog libvirt-0.8.3.ebuild
@ 2010-08-05 19:59 Doug Goldstein (cardoe)
0 siblings, 0 replies; 3+ messages in thread
From: Doug Goldstein (cardoe) @ 2010-08-05 19:59 UTC (permalink / raw
To: gentoo-commits
cardoe 10/08/05 19:59:00
Modified: ChangeLog
Added: libvirt-0.8.3.ebuild
Log:
Version bump. Add some patches that I submitted upstream to fix #322107
(Portage version: 2.1.8.3/cvs/Linux x86_64)
Revision Changes Path
1.65 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.64&r2=1.65
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog 5 Aug 2010 19:33:14 -0000 1.64
+++ ChangeLog 5 Aug 2010 19:58:59 -0000 1.65
@@ -1,6 +1,11 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.64 2010/08/05 19:33:14 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.65 2010/08/05 19:58:59 cardoe Exp $
+
+*libvirt-0.8.3 (05 Aug 2010)
+
+ 05 Aug 2010; Doug Goldstein <cardoe@gentoo.org> +libvirt-0.8.3.ebuild:
+ Version bump. Add some patches that I submitted upstream to fix #322107
05 Aug 2010; Doug Goldstein <cardoe@gentoo.org> files/libvirtd.init-r1:
Fix issue with init script when no virtual machines are running
1.1 app-emulation/libvirt/libvirt-0.8.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild?rev=1.1&content-type=text/plain
Index: libvirt-0.8.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.3.ebuild,v 1.1 2010/08/05 19:58:59 cardoe Exp $
BACKPORTS=1
EAPI="2"
PYTHON_DEPEND="python? 2:2.4"
#RESTRICT_PYTHON_ABIS="3.*"
#SUPPORT_PYTHON_ABIS="1"
inherit eutils python
DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz
${BACKPORTS:+mirror://gentoo/${P}-backports-${BACKPORTS}.tar.bz2}"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi caps iscsi +libvirtd lvm +lxc macvtap +network nfs nls numa openvz \
parted pcap phyp policykit python qemu sasl selinux uml virtualbox xen udev"
# IUSE=one : bug #293416 & bug# 299011
# Some tests are simply broken in the released tarball, ignore them
# for now.
RESTRICT=test
RDEPEND="sys-libs/readline
sys-libs/ncurses
>=net-misc/curl-7.18.0
>=dev-libs/libxml2-2.7.6
>=net-libs/gnutls-1.0.25
sys-fs/sysfsutils
sys-apps/util-linux
>=net-analyzer/netcat6-1.0-r2
avahi? ( >=net-dns/avahi-0.6[dbus] )
caps? ( sys-libs/libcap-ng )
iscsi? ( sys-block/open-iscsi )
libvirtd? ( net-misc/bridge-utils )
lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
macvtap? ( >=dev-libs/libnl-1.1 )
nfs? ( net-fs/nfs-utils )
numa? ( sys-process/numactl )
openvz? ( sys-kernel/openvz-sources )
parted? ( >=sys-apps/parted-1.8 )
pcap? ( >=net-libs/libpcap-1.0.0 )
phyp? ( net-libs/libssh2 )
policykit? ( >=sys-auth/polkit-0.9 )
qemu? ( || ( app-emulation/qemu-kvm >=app-emulation/qemu-0.10.0 ) )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( >=sys-libs/libselinux-2.0.85 )
virtualbox? ( || ( >=app-emulation/virtualbox-ose-2.2.0 >=app-emulation/virtualbox-bin-2.2.0 ) )
xen? ( app-emulation/xen-tools app-emulation/xen )
udev? ( >=sys-fs/udev-145 >=x11-libs/libpciaccess-0.10.9 )"
# one? ( dev-libs/xmlrpc-c )
DEPEND="${RDEPEND}
dev-util/pkgconfig
nls? ( sys-devel/gettext )"
pkg_setup() {
python_set_active_version 2
}
src_prepare() {
[[ -n ${BACKPORTS} ]] && \
EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
epatch
}
src_configure() {
local myconf=""
## enable/disable daemon, otherwise client only utils
myconf="${myconf} $(use_with libvirtd)"
## enable/disable the daemon using avahi to find VMs
myconf="${myconf} $(use_with avahi)"
## hypervisors on the local host
myconf="${myconf} $(use_with xen) $(use_with xen xen-inotify)"
if ! use policykit && use xen; then
myconf="${myconf} --with-xen-proxy"
fi
myconf="${myconf} $(use_with openvz)"
myconf="${myconf} $(use_with lxc)"
if use virtualbox && has_version app-emulation/virtualbox-ose; then
myconf="${myconf} --with-vbox=/usr/lib/virtualbox-ose/"
else
myconf="${myconf} $(use_with virtualbox vbox)"
fi
myconf="${myconf} $(use_with uml)"
myconf="${myconf} $(use_with qemu)"
# doesn't belong with hypervisors but links to libvirtd for some reason
#myconf="${myconf} $(use_with one)"
## hypervisor protocols
myconf="${myconf} $(use_with phyp)"
myconf="${myconf} --with-esx"
## additional host drivers
myconf="${myconf} $(use_with network)"
myconf="${myconf} --with-storage-fs"
myconf="${myconf} $(use_with lvm storage-lvm)"
myconf="${myconf} $(use_with iscsi storage-iscsi)"
myconf="${myconf} $(use_with parted storage-disk)"
myconf="${myconf} $(use_with lvm storage-mpath)"
myconf="${myconf} $(use_with numa numactl)"
myconf="${myconf} $(use_with selinux)"
# udev for device support details
myconf="${myconf} $(use_with udev)"
# linux capability support so we don't need privileged accounts
myconf="${myconf} $(use_with caps capng)"
## auth stuff
myconf="${myconf} $(use_with policykit polkit)"
myconf="${myconf} $(use_with sasl)"
# network biits
myconf="${myconf} $(use_with pcap libpcap)"
myconf="${myconf} $(use_with macvtap)"
## other
myconf="${myconf} $(use_enable nls)"
myconf="${myconf} $(use_with python)"
## stuff we don't yet support
myconf="${myconf} --without-netcf"
# we use udev over hal
myconf="${myconf} --without-hal"
# this is a nasty trick to work around the problem in bug
# #275073. The reason why we don't solve this properly is that
# it'll require us to rebuild autotools (and we don't really want
# to do that right now). The proper solution has been sent
# upstream and should hopefully land in 0.7.7, in the mean time,
# mime the same functionality with this.
case ${CHOST} in
*cygwin* | *mingw* )
;;
*)
ac_cv_prog_WINDRES=no
;;
esac
econf \
${myconf} \
--disable-static \
--docdir=/usr/share/doc/${PF} \
--with-remote \
--localstatedir=/var \
--with-remote-pid-file=/var/run/libvirtd.pid
}
src_test() {
# Explicitly allow parallel build of tests
emake check || die "tests failed"
}
src_install() {
emake install \
DESTDIR="${D}" \
HTML_DIR=/usr/share/doc/${PF}/html \
DOCS_DIR=/usr/share/doc/${PF}/python \
EXAMPLE_DIR=/usr/share/doc/${PF}/python/examples \
|| die "emake install failed"
newinitd "${FILESDIR}/libvirtd.init-r1" libvirtd || die
newconfd "${FILESDIR}/libvirtd.confd-r1" libvirtd || die
keepdir /var/lib/libvirt/images
find "${D}" -name '*.la' -delete || die
}
pkg_preinst() {
# we only ever want to generate this once
if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
fi
# We really don't want to use or support old PolicyKit cause it
# screws with the new polkit integration
if has_version sys-auth/policykit; then
rm -rf "${D}"/usr/share/PolicyKit/policy/org.libvirt.unix.policy
fi
}
pkg_postinst() {
use python && python_mod_optimize $(python_get_sitedir)/libvirt.py
elog
if use policykit && has_version sys-auth/policykit; then
elog "You must have run the following at least once:"
elog
elog "$ polkit-auth --grant org.libvirt.unix.manage --user \"USERNAME\""
elog
elog "to grant USERNAME access to libvirt when using USE=policykit"
else
elog "To allow normal users to connect to libvirtd you must change the"
elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
fi
elog
elog "For the basic networking support (bridged and routed networks)"
elog "you don't need any extra software. For more complex network modes"
elog "including but not limited to NATed network, you'll need the"
elog "following packages":
elog
elog " net-dns/dnsmasq"
elog " net-firewall/iptables"
elog " net-firewall/ebtables"
elog
if has_version net-dns/dnsmasq; then
ewarn "If you have a DNS server setup on your machine, you will have"
ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
ewarn " bind-interfaces"
ewarn " interface or except-interface"
ewarn
ewarn "Otherwise you might have issues with your existing DNS server."
fi
}
pkg_postrm() {
use python && python_mod_cleanup $(python_get_sitedir)/libvirt.py
}
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2010-08-07 2:43 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-08-06 1:48 [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: ChangeLog libvirt-0.8.3.ebuild Diego Petteno (flameeyes)
-- strict thread matches above, loose matches on Subject: below --
2010-08-07 2:43 Diego Petteno (flameeyes)
2010-08-05 19:59 Doug Goldstein (cardoe)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox