From: "Gilles Dartiguelongue (eva)" <eva@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in app-misc/tracker: tracker-0.8.15.ebuild ChangeLog tracker-9999.ebuild
Date: Fri, 30 Jul 2010 06:31:52 +0000 (UTC) [thread overview]
Message-ID: <20100730063153.2D34A2CE15@corvid.gentoo.org> (raw)
eva 10/07/30 06:31:52
Modified: ChangeLog tracker-9999.ebuild
Added: tracker-0.8.15.ebuild
Log:
Version bump, closes: #329647.
(Portage version: 2.2_rc67/cvs/Linux x86_64)
Revision Changes Path
1.76 app-misc/tracker/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/ChangeLog?r1=1.75&r2=1.76
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog 6 Jul 2010 15:19:29 -0000 1.75
+++ ChangeLog 30 Jul 2010 06:31:52 -0000 1.76
@@ -1,6 +1,12 @@
# ChangeLog for app-misc/tracker
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.75 2010/07/06 15:19:29 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.76 2010/07/30 06:31:52 eva Exp $
+
+*tracker-0.8.15 (30 Jul 2010)
+
+ 30 Jul 2010; Gilles Dartiguelongue <eva@gentoo.org>
+ +tracker-0.8.15.ebuild, tracker-9999.ebuild:
+ Version bump, closes: #329647.
06 Jul 2010; Samuli Suominen <ssuominen@gentoo.org> tracker-0.8.9.ebuild:
Keyword ~ppc64 wrt #296794
1.20 app-misc/tracker/tracker-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-9999.ebuild?r1=1.19&r2=1.20
Index: tracker-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- tracker-9999.ebuild 14 May 2010 18:02:28 -0000 1.19
+++ tracker-9999.ebuild 30 Jul 2010 06:31:52 -0000 1.20
@@ -1,6 +1,6 @@
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.19 2010/05/14 18:02:28 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.20 2010/07/30 06:31:52 eva Exp $
EAPI="2"
G2CONF_DEBUG="no"
@@ -24,7 +24,7 @@
>=app-i18n/enca-1.9
>=dev-db/sqlite-3.6.16[threadsafe]
>=dev-libs/dbus-glib-0.82-r1
- >=dev-libs/glib-2.20
+ >=dev-libs/glib-2.24
|| (
>=media-gfx/imagemagick-5.2.1[png,jpeg=]
media-gfx/graphicsmagick[imagemagick,png,jpeg=] )
1.1 app-misc/tracker/tracker-0.8.15.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.8.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/tracker/tracker-0.8.15.ebuild?rev=1.1&content-type=text/plain
Index: tracker-0.8.15.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.8.15.ebuild,v 1.1 2010/07/30 06:31:52 eva Exp $
EAPI="2"
G2CONF_DEBUG="no"
inherit eutils gnome2 linux-info
DESCRIPTION="A tagging metadata database, search tool and indexer"
HOMEPAGE="http://www.tracker-project.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc64 ~sparc ~x86"
# USE="doc" is managed by eclass.
IUSE="applet doc eds exif flac gnome-keyring gsf gstreamer gtk hal iptc +jpeg kmail laptop mp3 nautilus pdf playlist rss strigi test +tiff +vorbis xine +xml xmp"
# Automagic, gconf, uuid, and probably more
# TODO: quill support
RDEPEND="
>=app-i18n/enca-1.9
>=dev-db/sqlite-3.6.16[threadsafe]
>=dev-libs/dbus-glib-0.82-r1
>=dev-libs/glib-2.24
|| (
>=media-gfx/imagemagick-5.2.1[png,jpeg=]
media-gfx/graphicsmagick[imagemagick,png,jpeg=] )
>=media-libs/libpng-1.2
>=x11-libs/pango-1
sys-apps/util-linux
applet? (
gnome-base/gnome-panel
>=x11-libs/libnotify-0.4.3
>=x11-libs/gtk+-2.18 )
eds? (
>=mail-client/evolution-2.25.5
>=gnome-extra/evolution-data-server-2.25.5 )
exif? ( >=media-libs/libexif-0.6 )
flac? ( >=media-libs/flac-1.2.1 )
gnome-keyring? ( >=gnome-base/gnome-keyring-2.26 )
gsf? ( >=gnome-extra/libgsf-1.13 )
gstreamer? ( >=media-libs/gstreamer-0.10.12 )
!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
gtk? (
>=dev-libs/libgee-0.3
>=x11-libs/gtk+-2.18 )
iptc? ( media-libs/libiptcdata )
jpeg? ( media-libs/jpeg:0 )
laptop? (
hal? ( >=sys-apps/hal-0.5 )
!hal? ( >=sys-apps/devicekit-power-007 ) )
mp3? ( >=media-libs/id3lib-3.8.3 )
nautilus? (
gnome-base/nautilus
>=x11-libs/gtk+-2.18 )
pdf? (
>=x11-libs/cairo-1
>=app-text/poppler-0.12.3-r3[cairo,utils]
>=x11-libs/gtk+-2.12 )
playlist? ( dev-libs/totem-pl-parser )
rss? ( net-libs/libgrss )
strigi? ( >=app-misc/strigi-0.7 )
tiff? ( media-libs/tiff )
vorbis? ( >=media-libs/libvorbis-0.22 )
xine? ( >=media-libs/xine-lib-1 )
xml? ( >=dev-libs/libxml2-2.6 )
xmp? ( >=media-libs/exempi-2.1 )"
DEPEND="${RDEPEND}
>=dev-util/intltool-0.35
>=sys-devel/gettext-0.14
>=dev-util/pkgconfig-0.20
applet? ( dev-lang/vala )
gtk? (
dev-lang/vala
>=dev-libs/libgee-0.3 )
doc? (
>=dev-util/gtk-doc-1.8
media-gfx/graphviz )"
DOCS="AUTHORS ChangeLog NEWS README"
function inotify_enabled() {
if linux_config_exists; then
if ! linux_chkconfig_present INOTIFY_USER; then
ewarn "You should enable the INOTIFY support in your kernel."
ewarn "Check the 'Inotify support for userland' under the 'File systems'"
ewarn "option. It is marked as CONFIG_INOTIFY_USER in the config"
die 'missing CONFIG_INOTIFY'
fi
else
einfo "Could not check for INOTIFY support in your kernel."
fi
}
pkg_setup() {
linux-info_pkg_setup
inotify_enabled
if use gstreamer ; then
G2CONF="${G2CONF}
--enable-video-extractor=gstreamer
--enable-gstreamer-tagreadbin"
# --enable-gstreamer-helix (real media)
elif use xine ; then
G2CONF="${G2CONF} --enable-video-extractor=xine"
else
G2CONF="${G2CONF} --enable-video-extractor=external"
fi
# hal and dk-p are used for AC power detection
if use laptop; then
G2CONF="${G2CONF} $(use_enable hal) $(use_enable !hal devkit-power)"
else
G2CONF="${G2CONF} --disable-hal --disable-devkit-power"
fi
if use nautilus; then
G2CONF="${G2CONF} --enable-nautilus-extension=yes"
else
G2CONF="${G2CONF} --enable-nautilus-extension=no"
fi
G2CONF="${G2CONF}
--disable-unac
--disable-functional-tests
--with-enca
$(use_enable applet tracker-status-icon)
$(use_enable applet tracker-search-bar)
$(use_enable eds miner-evolution)
$(use_enable exif libexif)
$(use_enable flac libflac)
$(use_enable gnome-keyring)
$(use_enable gsf libgsf)
$(use_enable gtk tracker-explorer)
$(use_enable gtk tracker-preferences)
$(use_enable gtk tracker-search-tool)
$(use_enable iptc libiptcdata)
$(use_enable jpeg libjpeg)
$(use_enable kmail miner-kmail)
$(use_enable mp3 id3lib)
$(use_enable pdf poppler-glib)
$(use_enable playlist)
$(use_enable rss miner-rss)
$(use_enable strigi libstreamanalyzer)
$(use_enable test unit-tests)
$(use_enable test functional-tests)
$(use_enable tiff libtiff)
$(use_enable vorbis libvorbis)
$(use_enable xml libxml2)
$(use_enable xmp exempi)"
# FIXME: useless without quill (extract mp3 albumart...)
# $(use_enable gtk gdkpixbuf)
}
src_prepare() {
# Fix build failures with USE=strigi
epatch "${FILESDIR}/${PN}-0.8.0-strigi.patch"
# FIXME: report broken tests
sed -e '/\/libtracker-common\/tracker-dbus\/request-client-lookup/,+1 s:^\(.*\)$:/*\1*/:' \
-i tests/libtracker-common/tracker-dbus-test.c || die
sed -e '/\/libtracker-miner\/tracker-password-provider\/setting/,+1 s:^\(.*\)$:/*\1*/:' \
-e '/\/libtracker-miner\/tracker-password-provider\/getting/,+1 s:^\(.*\)$:/*\1*/:' \
-i tests/libtracker-miner/tracker-password-provider-test.c || die
sed -e '/\/libtracker-db\/tracker-db-journal\/init-and-shutdown/,+1 s:^\(.*\)$:/*\1*/:' \
-i tests/libtracker-db/tracker-db-journal.c || die
}
src_test() {
export XDG_CONFIG_HOME="${T}"
unset DBUS_SESSION_BUS_ADDRESS
emake check || die "tests failed"
}
next reply other threads:[~2010-07-30 6:32 UTC|newest]
Thread overview: 2+ messages / expand[flat|nested] mbox.gz Atom feed top
2010-07-30 6:31 Gilles Dartiguelongue (eva) [this message]
-- strict thread matches above, loose matches on Subject: below --
2010-08-21 15:26 [gentoo-commits] gentoo-x86 commit in app-misc/tracker: tracker-0.8.15.ebuild ChangeLog tracker-9999.ebuild Samuli Suominen (ssuominen)
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20100730063153.2D34A2CE15@corvid.gentoo.org \
--to=eva@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox