* [gentoo-commits] gentoo-x86 commit in app-editors/bluefish: ChangeLog bluefish-2.0.1.ebuild bluefish-1.3.8.ebuild
@ 2010-07-15 17:22 Daniel Pielmeier (billie)
0 siblings, 0 replies; only message in thread
From: Daniel Pielmeier (billie) @ 2010-07-15 17:22 UTC (permalink / raw
To: gentoo-commits
billie 10/07/15 17:22:49
Modified: ChangeLog
Added: bluefish-2.0.1.ebuild
Removed: bluefish-1.3.8.ebuild
Log:
Version bump. Fixes bug #311171. Remove old.
(Portage version: 2.1.8.3/cvs/Linux i686)
Revision Changes Path
1.71 app-editors/bluefish/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/ChangeLog?r1=1.70&r2=1.71
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog 15 Feb 2010 18:46:45 -0000 1.70
+++ ChangeLog 15 Jul 2010 17:22:49 -0000 1.71
@@ -1,6 +1,12 @@
# ChangeLog for app-editors/bluefish
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.70 2010/02/15 18:46:45 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.71 2010/07/15 17:22:49 billie Exp $
+
+*bluefish-2.0.1 (15 Jul 2010)
+
+ 15 Jul 2010; Daniel Pielmeier <billie@gentoo.org> -bluefish-1.3.8.ebuild,
+ +bluefish-2.0.1.ebuild:
+ Version bump. Fixes bug #311171. Remove old.
*bluefish-2.0.0 (15 Feb 2010)
1.1 app-editors/bluefish/bluefish-2.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/bluefish-2.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/bluefish-2.0.1.ebuild?rev=1.1&content-type=text/plain
Index: bluefish-2.0.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/bluefish-2.0.1.ebuild,v 1.1 2010/07/15 17:22:49 billie Exp $
EAPI=2
PYTHON_DEPEND=2
inherit autotools eutils fdo-mime python
MY_P=${P/_/-}
DESCRIPTION="A GTK HTML editor for the experienced web designer or programmer."
SRC_URI="http://www.bennewitz.com/bluefish/stable/source/${MY_P}.tar.bz2"
HOMEPAGE="http://bluefish.openoffice.nl/"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
IUSE="gucharmap nls python spell"
RDEPEND="
x11-libs/gtk+:2
spell? ( app-text/enchant[aspell] )"
DEPEND="${RDEPEND}
dev-libs/glib:2
dev-libs/libxml2
dev-util/pkgconfig
x11-libs/pango
gucharmap? ( gnome-extra/gucharmap )
nls? ( sys-devel/gettext dev-util/intltool )"
S=${WORKDIR}/${MY_P}
src_prepare () {
# Fixes automagic installation of charmap plugin
# Upstream bug: https://bugzilla.gnome.org/show_bug.cgi?id=570990
epatch "${FILESDIR}"/${PN}-2.0.0-gucharmap-automagic.patch
eautoreconf
}
src_configure() {
econf \
--disable-dependency-tracking \
--disable-update-databases \
--disable-xml-catalog-update \
$(use_enable nls) \
$(use_enable spell spell-check) \
$(use_enable gucharmap charmap) \
$(use_enable python)
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
einfo "Adding XML catalog entries..."
/usr/bin/xmlcatalog --noout \
--add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
--add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
--add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
/etc/xml/catalog \
|| ewarn "Failed to add XML catalog entries."
}
pkg_postrm() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
einfo "Removing XML catalog entries..."
/usr/bin/xmlcatalog --noout \
--del 'Bluefish/DTD/Bflang' \
--del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
--del 'http://bluefish.openoffice.nl/DTD' \
/etc/xml/catalog \
|| ewarn "Failed to remove XML catalog entries."
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-07-15 17:22 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-07-15 17:22 [gentoo-commits] gentoo-x86 commit in app-editors/bluefish: ChangeLog bluefish-2.0.1.ebuild bluefish-1.3.8.ebuild Daniel Pielmeier (billie)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox