[gentoo-commits] gentoo-x86 commit in app-forensics/aide: metadata.xml ChangeLog aide-0.14.2.ebuild aide-0.13.1-r4.ebuild aide-0.14.ebuild

[gentoo-commits] gentoo-x86 commit in app-forensics/aide: metadata.xml ChangeLog aide-0.14.2.ebuild aide-0.13.1-r4.ebuild aide-0.14.ebuild

[Matsuu Takuto (matsuu)]

matsuu      10/07/08 16:39:23

  Modified:             metadata.xml ChangeLog
  Added:                aide-0.14.2.ebuild
  Removed:              aide-0.13.1-r4.ebuild aide-0.14.ebuild
  Log:
  Version bumped. Added prelink USE flag.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  app-forensics/aide/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-forensics/aide/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	9 Jun 2010 16:14:41 -0000	1.4
+++ metadata.xml	8 Jul 2010 16:39:23 -0000	1.5
@@ -7,5 +7,6 @@
 	</maintainer>
 <use>
 	<flag name='audit'>Enable support for <pkg>sys-process/audit</pkg></flag>
+	<flag name='prelink'>Enable support for <pkg>sys-devel/prelink</pkg></flag>
 </use>
 </pkgmetadata>



1.50                 app-forensics/aide/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-forensics/aide/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	17 Jun 2010 20:05:56 -0000	1.49
+++ ChangeLog	8 Jul 2010 16:39:23 -0000	1.50
@@ -1,6 +1,12 @@
 # ChangeLog for app-forensics/aide
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-forensics/aide/ChangeLog,v 1.49 2010/06/17 20:05:56 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-forensics/aide/ChangeLog,v 1.50 2010/07/08 16:39:23 matsuu Exp $
+
+*aide-0.14.2 (08 Jul 2010)
+
+  08 Jul 2010; MATSUU Takuto <matsuu@gentoo.org> -aide-0.13.1-r4.ebuild,
+  -aide-0.14.ebuild, +aide-0.14.2.ebuild, metadata.xml:
+  Version bumped. Added prelink USE flag. Removed old versions
 
   17 Jun 2010; Patrick Lauer <patrick@gentoo.org> aide-0.13.1.ebuild,
   aide-0.13.1-r3.ebuild, aide-0.13.1-r4.ebuild, aide-0.13.1-r5.ebuild,



1.1                  app-forensics/aide/aide-0.14.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/aide-0.14.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/aide/aide-0.14.2.ebuild?rev=1.1&content-type=text/plain

Index: aide-0.14.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/aide/aide-0.14.2.ebuild,v 1.1 2010/07/08 16:39:23 matsuu Exp $

EAPI="3"

inherit autotools confutils eutils

DESCRIPTION="AIDE (Advanced Intrusion Detection Environment) is a replacement for Tripwire"
HOMEPAGE="http://aide.sourceforge.net/"
SRC_URI="mirror://sourceforge/aide/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="acl audit curl mhash nls postgres prelink selinux static xattr zlib"

DEPEND="acl? ( virtual/acl )
	audit? ( sys-process/audit )
	curl? ( net-misc/curl )
	mhash? ( >=app-crypt/mhash-0.9.2 )
	!mhash? ( dev-libs/libgcrypt )
	nls? ( virtual/libintl )
	postgres? ( dev-db/postgresql-base )
	prelink? ( sys-devel/prelink )
	selinux? ( sys-libs/libselinux )
	xattr? ( sys-apps/attr )
	zlib? ( sys-libs/zlib )"

RDEPEND="!static? ( ${DEPEND} )"

DEPEND="${DEPEND}
	nls? ( sys-devel/gettext )
	sys-devel/bison
	sys-devel/flex"

pkg_config() {
	confutils_use_conflict mhash postgres
	confutils_use_conflict curl static
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.14-gentoo.patch"

	# fix as-need issue, bug #271326
	epatch "${FILESDIR}/${PN}-0.14-as-needed.patch"

	# fix configure issue, bug #323187
	epatch "${FILESDIR}/${PN}-0.14-configure.patch"

	eautoreconf
}

src_configure() {
	econf \
		$(use_with acl posix-acl) \
		$(use_with audit) \
		$(use_with curl) \
		$(use_with !mhash gcrypt) \
		$(use_with mhash mhash) \
		$(use_with nls locale) \
		$(use_with postgres psql) \
		$(use_with prelink) \
		$(use_with selinux) \
		$(use_enable static) \
		$(use_with xattr) \
		$(use_with zlib) \
		--sysconfdir="${EPREFIX}/etc/aide" || die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install install-man || die "emake install failed"

	keepdir /var/lib/aide || die
	fowners root:0 /var/lib/aide || die
	fperms 0755 /var/lib/aide || die

	keepdir /var/log/aide || die

	insinto /etc/aide
	doins "${FILESDIR}"/aide.conf || die

	dosbin "${FILESDIR}"/aideinit || die

	dodoc AUTHORS ChangeLog NEWS README Todo "${FILESDIR}"/aide.cron || die
	dohtml doc/manual.html || die
}

pkg_postinst() {
	elog
	elog "A sample configuration file has been installed as"
	elog "/etc/aide/aide.conf.  Please edit to meet your needs."
	elog "Read the aide.conf(5) manual page for more information."
	elog "A helper script, aideinit, has been installed and can"
	elog "be used to make AIDE management easier. Please run"
	elog "aideinit --help for more information"
	elog

	if use postgres; then
		elog "Due to a bad assumption by aide, you must issue the following"
		elog "command after the database initialization (aide --init ...):"
		elog
		elog 'psql -c "update pg_index set indisunique=false from pg_class \\ '
		elog "  where pg_class.relname='TABLE_pkey' and \ "
		elog '  pg_class.oid=pg_index.indexrelid" -h HOSTNAME -p PORT DBASE USER'
		elog
		elog "where TABLE, HOSTNAME, PORT, DBASE, and USER are the same as"
		elog "your aide.conf."
		elog
	fi
}