[gentoo-commits] gentoo-x86 commit in media-gfx/gthumb: gthumb-2.11.4.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-gfx/gthumb: gthumb-2.11.4.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       10/07/03 15:21:54

  Modified:             ChangeLog
  Added:                gthumb-2.11.4.ebuild
  Log:
  Version bump with tons of fixes and some new features.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.110                media-gfx/gthumb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gthumb/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gthumb/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gthumb/ChangeLog?r1=1.109&r2=1.110

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/gthumb/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog	15 May 2010 17:05:22 -0000	1.109
+++ ChangeLog	3 Jul 2010 15:21:54 -0000	1.110
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/gthumb
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gthumb/ChangeLog,v 1.109 2010/05/15 17:05:22 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gthumb/ChangeLog,v 1.110 2010/07/03 15:21:54 pacho Exp $
+
+*gthumb-2.11.4 (03 Jul 2010)
+
+  03 Jul 2010; Pacho Ramos <pacho@gentoo.org> +gthumb-2.11.4.ebuild:
+  Version bump with tons of fixes and some new features.
 
   15 May 2010; Raúl Porcel <armin76@gentoo.org> gthumb-2.10.11.ebuild,
   gthumb-2.11.2.1.ebuild:



1.1                  media-gfx/gthumb/gthumb-2.11.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gthumb/gthumb-2.11.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gthumb/gthumb-2.11.4.ebuild?rev=1.1&content-type=text/plain

Index: gthumb-2.11.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/gthumb/gthumb-2.11.4.ebuild,v 1.1 2010/07/03 15:21:54 pacho Exp $

EAPI="3"

inherit autotools eutils gnome2

DESCRIPTION="Image viewer and browser for Gnome"
HOMEPAGE="http://gthumb.sourceforge.net"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cdr exif gnome-keyring gstreamer http raw slideshow tiff test"

# clutter
RDEPEND=">=dev-libs/glib-2.16:2
	>=x11-libs/gtk+-2.18:2
	>=gnome-base/gconf-2.6
	>=dev-libs/libunique-1
	>=media-libs/jpeg-8:0
	cdr? ( >=app-cdr/brasero-2.28 )
	exif? ( >=media-gfx/exiv2-0.18 )
	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28 )
	gstreamer? (
		>=media-libs/gstreamer-0.10
		>=media-libs/gst-plugins-base-0.10 )
	http? (
		>=net-libs/libsoup-2.26:2.4
		>=net-libs/libsoup-gnome-2.26:2.4 )
	slideshow? (
		>=media-libs/clutter-1:1.0
		>=media-libs/clutter-gtk-0.10:1.0 )
	tiff? ( media-libs/tiff )
	raw? ( >=media-libs/libopenraw-0.0.8 )
	!raw? ( media-gfx/dcraw )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	app-text/scrollkeeper
	>=dev-util/intltool-0.35
	app-text/gnome-doc-utils
	test? ( ~app-text/docbook-xml-dtd-4.1.2 )"

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--disable-clutter
		$(use_enable cdr brasero)
		$(use_enable exif exiv2)
		$(use_enable gstreamer)
		$(use_enable gnome-keyring)
		$(use_enable http libsoup)
		$(use_enable raw libopenraw)
		$(use_enable slideshow clutter)
		$(use_enable test test-suite)
		$(use_enable tiff)"
}

src_prepare() {
	gnome2_src_prepare

	# Do not require unstable libunique
	epatch "${FILESDIR}/${PN}-2.11.2.1-configure.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf
}

src_install() {
	gnome2_src_install

	# gthumb does not need *.la files
	find "${D}" -name "*.la" -delete || die "*.la files removal failed"
}