[gentoo-commits] gentoo-x86 commit in x11-misc/xlockmore: ChangeLog xlockmore-5.31.ebuild

["Markos Chandras (hwoarang)" <hwoarang@gentoo.org>]

hwoarang    10/06/29 19:34:49

  Modified:             ChangeLog
  Added:                xlockmore-5.31.ebuild
  Log:
  Version bump to 5.31. Use patch to respect ldflags
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.83                 x11-misc/xlockmore/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	14 Feb 2010 15:43:49 -0000	1.82
+++ ChangeLog	29 Jun 2010 19:34:49 -0000	1.83
@@ -1,6 +1,13 @@
 # ChangeLog for x11-misc/xlockmore
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v 1.82 2010/02/14 15:43:49 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v 1.83 2010/06/29 19:34:49 hwoarang Exp $
+
+*xlockmore-5.31 (29 Jun 2010)
+
+  29 Jun 2010; Markos Chandras <hwoarang@gentoo.org> +xlockmore-5.31.ebuild,
+  +files/xlockmore-5.31-configure.in.patch,
+  +files/xlockmore-5.31-ldflags.patch:
+  Version bump to 5.31. Use patch to respect ldflags
 
   14 Feb 2010; Samuli Suominen <ssuominen@gentoo.org>
   xlockmore-5.29.1.ebuild, +files/xlockmore-5.29.1-configure.in.patch:



1.1                  x11-misc/xlockmore/xlockmore-5.31.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/xlockmore-5.31.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xlockmore/xlockmore-5.31.ebuild?rev=1.1&content-type=text/plain

Index: xlockmore-5.31.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/xlockmore-5.31.ebuild,v 1.1 2010/06/29 19:34:49 hwoarang Exp $

EAPI=2
inherit autotools eutils flag-o-matic pam

DESCRIPTION="Just another screensaver application for X"
HOMEPAGE="http://www.tux.org/~bagleyd/xlockmore.html"
SRC_URI="http://ftp.tux.org/pub/tux/bagleyd/${PN}/${P}/${P}.tar.bz2"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="crypt debug esd gtk motif nas opengl pam truetype xinerama xlockrc X"

RDEPEND="x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXpm
	x11-libs/libXt
	x11-libs/libXmu
	opengl? ( media-libs/mesa
		truetype? ( >=media-libs/ftgl-2.1.3_rc5 ) )
	truetype? ( media-libs/freetype:2 )
	pam? ( virtual/pam )
	nas? ( media-libs/nas )
	esd? ( media-sound/esound )
	motif? ( x11-libs/openmotif )
	gtk? ( x11-libs/gtk+:2 )
	xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	x11-proto/xineramaproto"

MAKEOPTS="${MAKEOPTS} -j1"

src_prepare() {
	epatch "${FILESDIR}"/${P}-configure.in.patch
	epatch "${FILESDIR}"/${P}-ldflags.patch
	eautoreconf
}

src_configure() {
	local myconf=""

	if use opengl && use truetype; then
			myconf="${myconf} --with-ftgl"
			append-flags -DFTGL213
		else
			myconf="${myconf} --without-ftgl"
	fi

	econf \
		--enable-vtlock \
		--enable-syslog \
		$(use_enable xlockrc) \
		$(use_enable pam) \
		--disable-use-mb \
		--enable-appdefaultdir=/usr/share/X11/app-defaults \
		$(use_with motif) \
		$(use_with debug editres) \
		$(use_with truetype ttf) \
		$(use_with truetype freetype) \
		$(use_with opengl) \
		$(use_with opengl mesa) \
		$(use_with xinerama) \
		$(use_with esd esound) \
		$(use_with nas) \
		$(use_with crypt) \
		$(use_with gtk gtk2) \
		--without-gtk \
		${myconf}
}

src_install() {
	einstall xapploaddir="${D}/usr/share/X11/app-defaults" \
		mandir="${D}/usr/share/man/man1" INSTPGMFLAGS="" \
		|| die "einstall failed"

	pamd_mimic_system xlock auth

	if use pam; then
		fperms 755 /usr/bin/xlock
	else
		fperms 4755 /usr/bin/xlock
	fi

	dohtml docs/xlock.html
	dodoc README docs/{3d.howto,cell_automata,HACKERS.GUIDE,Purify,Revisions,TODO}
}