[gentoo-commits] gentoo-x86 commit in kde-base/kdm: ChangeLog kdm-4.4.4-r1.ebuild kdm-4.4.4.ebuild

[gentoo-commits] gentoo-x86 commit in kde-base/kdm: ChangeLog kdm-4.4.4-r1.ebuild kdm-4.4.4.ebuild

[Maciej Mrozowski (reavertm)]

reavertm    10/06/23 21:56:39

  Modified:             ChangeLog
  Added:                kdm-4.4.4-r1.ebuild
  Removed:              kdm-4.4.4.ebuild
  Log:
  Apply kdm timeout patch from bug 278473, add TerminateServer=true to kdmrc (workaround for nvidia), set FaceDir (kdm doesn't respect it yet), properly slot DataDir
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.220                kde-base/kdm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdm/ChangeLog?rev=1.220&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdm/ChangeLog?rev=1.220&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdm/ChangeLog?r1=1.219&r2=1.220

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v
retrieving revision 1.219
retrieving revision 1.220
diff -u -r1.219 -r1.220
--- ChangeLog	21 Jun 2010 16:30:52 -0000	1.219
+++ ChangeLog	23 Jun 2010 21:56:39 -0000	1.220
@@ -1,6 +1,15 @@
 # ChangeLog for kde-base/kdm
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v 1.219 2010/06/21 16:30:52 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/ChangeLog,v 1.220 2010/06/23 21:56:39 reavertm Exp $
+
+*kdm-4.4.4-r1 (23 Jun 2010)
+
+  23 Jun 2010; Maciej Mrozowski <reavertm@gentoo.org>
+  +files/kdm-4.3.5-xdm-restart.patch, -kdm-4.4.4.ebuild,
+  +kdm-4.4.4-r1.ebuild:
+  Apply kdm timeout patch from bug 278473, add TerminateServer=true to kdmrc
+  (workaround for nvidia), set FaceDir (kdm doesn't respect it yet),
+  properly slot DataDir
 
   21 Jun 2010; Tomáš Chvátal <scarabeus@gentoo.org> kdm-4.3.5.ebuild,
   kdm-4.3.5-r1.ebuild, kdm-4.4.4.ebuild:



1.1                  kde-base/kdm/kdm-4.4.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdm/kdm-4.4.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kdm/kdm-4.4.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: kdm-4.4.4-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kdm/kdm-4.4.4-r1.ebuild,v 1.1 2010/06/23 21:56:39 reavertm Exp $

EAPI="3"

KMNAME="kdebase-workspace"
inherit kde4-meta flag-o-matic

DESCRIPTION="KDE login manager, similar to xdm and gdm"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="consolekit debug +handbook kerberos pam"

DEPEND="
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXtst
	consolekit? (
		>=sys-apps/dbus-1.0.2
		sys-auth/consolekit
	)
	kerberos? ( virtual/krb5 )
	pam? (
		$(add_kdebase_dep kcheckpass)
		virtual/pam
	)
"
RDEPEND="${DEPEND}
	$(add_kdebase_dep kdepasswd)
	>=x11-apps/xinit-1.0.5-r2
	x11-apps/xmessage
"

KMEXTRACTONLY="
	kcontrol/kdm/
"
KMEXTRA="
	libs/kdm/
"

PATCHES=(
	"${FILESDIR}/kdebase-4.0.2-pam-optional.patch"
	"${FILESDIR}/${PN}-4-gentoo-xinitrc.d.patch"
	"${FILESDIR}/${PN}-4.3.5-xdm-restart.patch"
)

pkg_setup() {
	kde4-meta_pkg_setup

	KDM_HOME=/var/lib/kdm-${SLOT}
}

src_configure() {
	# genkdmconf breaks with -O3
	# last checked in 4.2.95
	replace-flags -O3 -O2

	mycmakeargs=(
		$(cmake-utils_use kerberos KDE4_KRB5AUTH)
		$(cmake-utils_use_with pam)
		$(cmake-utils_use_with consolekit CkConnector)
	)

	kde4-meta_src_configure
}

src_install() {
	export GENKDMCONF_FLAGS="--no-old --no-backup"

	kde4-meta_src_install

	# Customize the kdmrc configuration:
	# - SessionDirs set to /usr/share/xsessions
	# - increase server timeout to 30s
	# - TerminateServer=true to workaround X server regen bug, bug 278473
	# - DataDir set to /var/lib/kdm-${SLOT}
	# - FaceDir set to /var/lib/kdm-${SLOT}/faces
	sed -e "s|^.*SessionsDirs=.*$|#&\nSessionsDirs=${EPREFIX}/usr/share/xsessions|" \
		-e "/#ServerTimeout=/s/^.*$/ServerTimeout=30/" \
		-e "/#TerminateServer=/s/^.*$/TerminateServer=true/" \
		-e "s|^.*DataDir=.*$|#&\nDataDir=${EPREFIX}${KDM_HOME}|" \
		-e "s|^.*FaceDir=.*$|#&\nFaceDir=${EPREFIX}${KDM_HOME}/faces|" \
		-i "${ED}"/${KDEDIR}/share/config/kdm/kdmrc \
		|| die "Failed to set ServerTimeout and SessionsDirs correctly in kdmrc."

	# Don't install empty dir
	rmdir "${ED}${KDEDIR}"/share/config/kdm/sessions

	# Set up kdm work directory
	keepdir "${KDM_HOME}"
}

pkg_postinst() {
	kde4-meta_pkg_postinst

	# Set the default kdm face icon if it's not already set by the system admin
	# because this is user-overrideable in that way, it's not in src_install
	if [[ ! -e "${EROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon" ]]; then
		mkdir -p "${EROOT}${KDEDIR}/share/apps/kdm/faces"
		cp "${EROOT}${KDEDIR}/share/apps/kdm/pics/users/default1.png" \
			"${EROOT}${KDEDIR}/share/apps/kdm/faces/.default.face.icon"
	fi
	if [[ ! -e "${EROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon" ]]; then
		mkdir -p "${EROOT}${KDEDIR}/share/apps/kdm/faces"
		cp "${EROOT}${KDEDIR}/share/apps/kdm/pics/users/root1.png" \
			"${EROOT}${KDEDIR}/share/apps/kdm/faces/root.face.icon"
	fi

	if use consolekit; then
		echo
		elog "You have compiled 'kdm' with consolekit support. If you want to use kdm,"
		elog "make sure consolekit daemon is running and started at login time"
		elog
		elog "rc-update add consolekit default && /etc/init.d/consolekit start"
		echo
	fi
}