[gentoo-commits] gentoo-x86 commit in x11-themes/gnome-themes: ChangeLog gnome-themes-2.30.2.ebuild gnome-themes-2.30.1-r1.ebuild

[gentoo-commits] gentoo-x86 commit in x11-themes/gnome-themes: ChangeLog gnome-themes-2.30.2.ebuild gnome-themes-2.30.1-r1.ebuild

[Pacho Ramos (pacho)]

pacho       10/06/23 11:09:11

  Modified:             ChangeLog
  Added:                gnome-themes-2.30.2.ebuild
  Removed:              gnome-themes-2.30.1-r1.ebuild
  Log:
  Version bump
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.227                x11-themes/gnome-themes/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/gnome-themes/ChangeLog?rev=1.227&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/gnome-themes/ChangeLog?rev=1.227&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/gnome-themes/ChangeLog?r1=1.226&r2=1.227

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-themes/gnome-themes/ChangeLog,v
retrieving revision 1.226
retrieving revision 1.227
diff -u -r1.226 -r1.227
--- ChangeLog	13 Jun 2010 16:22:59 -0000	1.226
+++ ChangeLog	23 Jun 2010 11:09:11 -0000	1.227
@@ -1,6 +1,14 @@
 # ChangeLog for x11-themes/gnome-themes
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-themes/ChangeLog,v 1.226 2010/06/13 16:22:59 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-themes/ChangeLog,v 1.227 2010/06/23 11:09:11 pacho Exp $
+
+*gnome-themes-2.30.2 (23 Jun 2010)
+
+  23 Jun 2010; Pacho Ramos <pacho@gentoo.org>
+  -gnome-themes-2.30.1-r1.ebuild,
+  -files/gnome-themes-2.30.1-evolution-workaround.patch,
+  +gnome-themes-2.30.2.ebuild:
+  Version bump with updated translations and fixes, remove old.
 
 *gnome-themes-2.30.1-r1 (13 Jun 2010)
 



1.1                  x11-themes/gnome-themes/gnome-themes-2.30.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/gnome-themes/gnome-themes-2.30.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-themes/gnome-themes/gnome-themes-2.30.2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-themes-2.30.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-themes/gnome-themes/gnome-themes-2.30.2.ebuild,v 1.1 2010/06/23 11:09:11 pacho Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit eutils gnome2

DESCRIPTION="A set of GNOME themes, with sets for users with limited or low vision"
HOMEPAGE="http://www.gnome.org/"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
IUSE="accessibility"

RDEPEND=">=x11-libs/gtk+-2
	 >=x11-themes/gtk-engines-2.15.3"
DEPEND="${RDEPEND}
	>=x11-misc/icon-naming-utils-0.8.7
	>=dev-util/pkgconfig-0.19
	>=dev-util/intltool-0.35"
# dev-perl/XML-LibXML is bug 266136

DOCS="AUTHORS ChangeLog NEWS README"

# This ebuild does not install any binaries
RESTRICT="binchecks strip"

G2CONF="${G2CONF}
		$(use_enable accessibility all-themes)
		--disable-test-themes
		--enable-icon-mapping"

src_prepare() {
	# Fix bashisms, bug #256337
	epatch "${FILESDIR}/${PN}-2.24.3-bashism.patch"

	# Do not build/install accessibility themes, bug #274515
	if ! use accessibility; then
		sed 's:HighContrast.*\\:\\:g' -i \
			desktop-themes/Makefile.am desktop-themes/Makefile.in \
			gtk-themes/Makefile.am gtk-themes/Makefile.in \
			icon-themes/Makefile.am icon-themes/Makefile.in \
			|| die "sed 1 failed"
	fi

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed 2 failed"
}